dnl Copyright (C) 1999 Bjoern Beutel

dnl Process this file with autoconf to produce a configure script.

AC_INIT

AC_CONFIG_SRCDIR(malaga.c)

dnl Set the compiler flags if we are using GCC.
AC_PROG_CC
case "$GCC" in
yes) 
  GCCFLAGS="-Wall -Wstrict-prototypes -Wmissing-prototypes"
  ;;
*)
  GCCFLAGS=""
esac

AC_PROG_INSTALL
AC_PROG_LIBTOOL

dnl Check for Posix or Win32 system.
AC_MSG_CHECKING(for Win32)
case "$host" in
*-*-mingw*)
  SYS_CFLAGS="-DWIN32 -mms-bitfields"
  use_win32=yes
  ;;
*)
  SYS_CFLAGS="-DPOSIX"
  use_win32=no
esac
AC_MSG_RESULT($use_win32)

dnl Check for "readline" library
AC_ARG_WITH(readline,
	    AS_HELP_STRING(--with-readline,
              [Support fancy command line editing @<:@default=yes@:>@]), 
            use_readline=$withval, use_readline=yes)
if test $use_readline = yes
then
  AC_CHECK_LIB(readline,readline,,use_readline=no,-lcurses)
  AC_CHECK_HEADER(readline/readline.h,,use_readline=no)
fi
if test $use_readline = yes 
then
  READLINE_LIBS="-lreadline -lcurses"
  READLINE_CFLAGS="-DREADLINE"
else
  READLINE_LIBS=""
  READLINE_CFLAGS=""
fi

dnl Check for GTK+, version 2.8 or later, when malshow is enabled.
AC_ARG_ENABLE(malshow,
              AS_HELP_STRING(--enable-malshow,
                             [Create the GUI "malshow" @<:@default=yes@:>@]), 
              use_malshow=$enableval, use_malshow=yes)
if test $use_malshow = yes
then
  AC_MSG_CHECKING(for GTK+ 2.8 or later)
  if ! $SHELL -c 'pkg-config --atleast-version=2.8 gtk+-2.0' >/dev/null 2>/dev/null
  then 
    use_malshow=no
  fi
  AC_MSG_RESULT($use_malshow)
  if test $use_malshow = no
  then
    echo 1>&2 "*** No GTK+, version 2.8 or later, found. Disabling malshow."
    echo 1>&2 "*** You may get GTK+ from <http://www.gtk.org>."
  fi
fi
if test $use_malshow = yes
then
  GTK_LIBS=`pkg-config gtk+-2.0 --libs`
  GTK_CFLAGS=`pkg-config gtk+-2.0 --cflags`
  MALSHOW="malshow"
else
  GTK_LIBS=""
  GTK_CFLAGS=""
  MALSHOW=""
fi

dnl Check for GLib, version 2
AC_MSG_CHECKING(for GLib)
if $SHELL -c 'pkg-config glib-2.0' >/dev/null 2>/dev/null
then
  have_glib=yes
else
  have_glib=no
fi
AC_MSG_RESULT($have_glib)
if test $have_glib = yes
then 
  GLIB_LIBS=`pkg-config glib-2.0 --libs`
  GLIB_CFLAGS=`pkg-config glib-2.0 --cflags`
else
  echo 1>&2 "*** No GLib, version 2.0 or later, found. Please install it."
  echo 1>&2 "*** You may get GLib from <http://www.gtk.org>."
  exit 1
fi

AC_SUBST(GCCFLAGS)
AC_SUBST(MALSHOW)
AC_SUBST(GTK_LIBS)
AC_SUBST(GTK_CFLAGS)
AC_SUBST(GLIB_LIBS)
AC_SUBST(GLIB_CFLAGS)
AC_SUBST(READLINE_LIBS)
AC_SUBST(READLINE_CFLAGS)
AC_SUBST(SYS_CFLAGS)
AC_SUBST(INSTALL)
AC_SUBST(INSTALL_PROGRAM)
AC_SUBST(INSTALL_DATA)
AC_CONFIG_FILES(Makefile)
AC_OUTPUT

dnl End of file.