/* Linker script for normal executables with BSS in hugepages */
OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64",
"elf64-x86-64")
OUTPUT_ARCH(i386:x86-64)
ENTRY(_start)
SEARCH_DIR("/usr/x86_64-linux-gnu/lib64"); SEARCH_DIR("/usr/local/lib64"); SEARCH_DIR("/lib64"); SEARCH_DIR("/usr/lib64"); SEARCH_DIR("/usr/x86_64-linux-gnu/lib"); SEARCH_DIR("/usr/local/lib"); SEARCH_DIR("/lib"); SEARCH_DIR("/usr/lib");
INPUT(-lhugetlbfs);
/* Do we need any of these for elf?
__DYNAMIC = 0; */
PHDRS
{
headers PT_PHDR PHDRS ;
interp PT_INTERP ;
text PT_LOAD FILEHDR PHDRS ;
data PT_LOAD ;
htlb PT_LOAD FLAGS (0x00100007);
dynamic PT_DYNAMIC ;
note PT_NOTE ;
gnu_stack PT_GNU_STACK ;
/* this is the value of PT_GNU_EH_FRAME as defined in
usr/include/elf.h but binutils does not recognize that identifier
as it does other PT_ constants. */
eh_frame_hdr 1685382480 FLAGS (0x00000004);
}
SECTIONS
{
/* Read-only sections, merged into text segment: */
__executable_start = 0x400000; . = 0x400000 + SIZEOF_HEADERS;
.interp : { *(.interp) } :text :interp
.note.SuSE : { *(.note.SuSE) } :text :note
.note.ABI-tag : { *(.note.ABI-tag) } :text :note
.note.gnu.build-id : { *(.note.gnu.build-id) } :text :note
.hash : { *(.hash) } :text
.dynsym : { *(.dynsym) } :text
.dynstr : { *(.dynstr) } :text
.gnu.version : { *(.gnu.version) } :text
.gnu.version_d : { *(.gnu.version_d) } :text
.gnu.version_r : { *(.gnu.version_r) } :text
.rel.init : { *(.rel.init) } :text
.rela.init : { *(.rela.init) } :text
.rel.text : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) } :text
.rela.text : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) } :text
.rel.fini : { *(.rel.fini) } :text
.rela.fini : { *(.rela.fini) } :text
.rel.rodata : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) } :text
.rela.rodata : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) } :text
.rel.data.rel.ro : { *(.rel.data.rel.ro*) } :text
.rela.data.rel.ro : { *(.rel.data.rel.ro*) } :text
.rel.data : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) } :text
.rela.data : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) } :text
.rel.tdata : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) } :text
.rela.tdata : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) } :text
.rel.tbss : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) } :text
.rela.tbss : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) } :text
.rel.ctors : { *(.rel.ctors) } :text
.rela.ctors : { *(.rela.ctors) } :text
.rel.dtors : { *(.rel.dtors) } :text
.rela.dtors : { *(.rela.dtors) } :text
.rel.got : { *(.rel.got) } :text
.rela.got : { *(.rela.got) } :text
.rel.bss : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) } :text
.rela.bss : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) } :text
.rel.plt : { *(.rel.plt) } :text
.rela.plt : { *(.rela.plt) } :text
.init :
{
KEEP (*(.init))
} :text =0x90909090
.plt : { *(.plt)} :text
.text :
{
*(.text .stub .text.* .gnu.linkonce.t.*)
KEEP (*(.text.*personality*))
/* .gnu.warning sections are handled specially by elf32.em. */
*(.gnu.warning)
} :text =0x90909090
.fini :
{
KEEP (*(.fini))
} :text =0x90909090
PROVIDE (__etext = .);
PROVIDE (_etext = .);
PROVIDE (etext = .);
.rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) } :text
.rodata1 : { *(.rodata1) } :text
.eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
.eh_frame : ONLY_IF_RO { KEEP (*(.eh_frame)) } :text
.gcc_except_table : ONLY_IF_RO { KEEP (*(.gcc_except_table)) *(.gcc_except_table.*) } :text
/* Adjust the address for the data segment. We want to adjust up to
the same address within the page on the next page up. */
. = ALIGN (0x100000) - ((0x100000 - .) & (0x100000 - 1)); . = DATA_SEGMENT_ALIGN (0x100000, 0x1000);
/* Exception handling */
.eh_frame : ONLY_IF_RW { KEEP (*(.eh_frame)) } :data
.gcc_except_table : ONLY_IF_RW { KEEP (*(.gcc_except_table)) *(.gcc_except_table.*) } :data
/* Thread Local Storage sections */
.tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) } :data
.tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) } :data
/* Ensure the __preinit_array_start label is properly aligned. We
could instead move the label definition inside the section, but
the linker would then create the section even if it turns out to
be empty, which isn't pretty. */
. = ALIGN(64 / 8);
PROVIDE (__preinit_array_start = .);
.preinit_array : { KEEP (*(.preinit_array)) } :data
PROVIDE (__preinit_array_end = .);
PROVIDE (__init_array_start = .);
.init_array : { KEEP (*(.init_array)) } :data
PROVIDE (__init_array_end = .);
PROVIDE (__fini_array_start = .);
.fini_array : { KEEP (*(.fini_array)) } :data
PROVIDE (__fini_array_end = .);
.ctors :
{
/* gcc uses crtbegin.o to find the start of
the constructors, so we make sure it is
first. Because this is a wildcard, it
doesn't matter if the user does not
actually link against crtbegin.o; the
linker won't look for a file to match a
wildcard. The wildcard also means that it
doesn't matter which directory crtbegin.o
is in. */
KEEP (*crtbegin*.o(.ctors))
/* We don't want to include the .ctor section from
from the crtend.o file until after the sorted ctors.
The .ctor section from the crtend file contains the
end of ctors marker and it must be last */
KEEP (*(EXCLUDE_FILE (*crtend*.o ) .ctors))
KEEP (*(SORT(.ctors.*)))
KEEP (*(.ctors))
} :data
.dtors :
{
KEEP (*crtbegin*.o(.dtors))
KEEP (*(EXCLUDE_FILE (*crtend*.o ) .dtors))
KEEP (*(SORT(.dtors.*)))
KEEP (*(.dtors))
} :data
.jcr : { KEEP (*(.jcr)) } :data
.data.rel.ro : { *(.data.rel.ro.local) *(.data.rel.ro*) } :data
.dynamic : { *(.dynamic) } :dynamic :data
.got : { *(.got) } :data
. = DATA_SEGMENT_RELRO_END (24, .);
.got.plt : { *(.got.plt) } :data
.data :
{
*(.data .data.* .gnu.linkonce.d.*)
KEEP (*(.gnu.linkonce.d.*personality*))
SORT(CONSTRUCTORS)
} :data
.data1 : { *(.data1) } :data
_edata = .;
PROVIDE (edata = .);
__bss_start = .;
. = ALIGN(64 / 8);
. = DATA_SEGMENT_END (.);
/* Hugepage area */
. = ALIGN(0x1000000); /* Align to 16MB (2MB hugepage size, plus some slack in case of larger hugepages in future */
__bss_start = .;
.bss :
{
*(.dynbss)
*(.bss .bss.* .gnu.linkonce.b.*)
*(COMMON)
} :htlb
_end = .;
PROVIDE (end = .);
/* Stabs debugging sections. */
.stab 0 : { *(.stab) }
.stabstr 0 : { *(.stabstr) }
.stab.excl 0 : { *(.stab.excl) }
.stab.exclstr 0 : { *(.stab.exclstr) }
.stab.index 0 : { *(.stab.index) }
.stab.indexstr 0 : { *(.stab.indexstr) }
.comment 0 : { *(.comment) }
/* DWARF debug sections.
Symbols in the DWARF debugging sections are relative to the beginning
of the section so we begin them at 0. */
/* DWARF 1 */
.debug 0 : { *(.debug) }
.line 0 : { *(.line) }
/* GNU DWARF 1 extensions */
.debug_srcinfo 0 : { *(.debug_srcinfo) }
.debug_sfnames 0 : { *(.debug_sfnames) }
/* DWARF 1.1 and DWARF 2 */
.debug_aranges 0 : { *(.debug_aranges) }
.debug_pubnames 0 : { *(.debug_pubnames) }
/* DWARF 2 */
.debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
.debug_abbrev 0 : { *(.debug_abbrev) }
.debug_line 0 : { *(.debug_line) }
.debug_frame 0 : { *(.debug_frame) }
.debug_str 0 : { *(.debug_str) }
.debug_loc 0 : { *(.debug_loc) }
.debug_macinfo 0 : { *(.debug_macinfo) }
/* SGI/MIPS DWARF 2 extensions */
.debug_weaknames 0 : { *(.debug_weaknames) }
.debug_funcnames 0 : { *(.debug_funcnames) }
.debug_typenames 0 : { *(.debug_typenames) }
.debug_varnames 0 : { *(.debug_varnames) }
/DISCARD/ : { *(.note.GNU-stack) }
}