#!perl

BEGIN {

    unless ($ENV{AUTHOR_TESTING}) {

        require Test::More;

        Test::More::plan(skip_all =>

                         'these tests are for testing by the author');

    }

}

use strict;

use warnings;

use Test::More tests => 3997;

###############################################################################

# Read and load configuration file and backend library.

use Config::Tiny ();

my $config_file = 't/author-lib.ini';

my $config = Config::Tiny -> read('t/author-lib.ini')

  or die Config::Tiny -> errstr();

# Read the library to test.

our $LIB = $config->{_}->{lib};

die "No library defined in file '$config_file'"

  unless defined $LIB;

die "Invalid library name '$LIB' in file '$config_file'"

  unless $LIB =~ /^[A-Za-z]\w*(::\w+)*\z/;

# Read the reference type(s) the library uses.

our $REF = $config->{_}->{ref};

die "No reference type defined in file '$config_file'"

  unless defined $REF;

die "Invalid reference type '$REF' in file '$config_file'"

  unless $REF =~ /^[A-Za-z]\w*(::\w+)*\z/;

# Load the library.

eval "require $LIB";

die $@ if $@;

###############################################################################

can_ok($LIB, '_div');

my $scalar_util_ok = eval { require Scalar::Util; };

Scalar::Util -> import('refaddr') if $scalar_util_ok;

diag "Skipping some tests since Scalar::Util is not installed."

  unless $scalar_util_ok;

my @data;

# Small numbers.

for (my $x = 0; $x <= 24 ; ++ $x) {

    for (my $y = 1; $y <= 24 ; ++ $y) {

        push @data, [ $x, $y, int($x / $y), $x % $y ];

    }

}

# Add data in data file.

(my $datafile = $0) =~ s/\.t/.dat/;

open DATAFILE, $datafile or die "$datafile: can't open file for reading: $!";

while (<DATAFILE>) {

    s/\s+\z//;

    next if /^#/ || ! /\S/;

    push @data, [ split /:/ ];

}

close DATAFILE or die "$datafile: can't close file after reading: $!";

# List context.

for (my $i = 0 ; $i <= $#data ; ++ $i) {

    my ($in0, $in1, $out0, $out1) = @{ $data[$i] };

    my ($x, $y, @got);

    my $test = qq|\$x = $LIB->_new("$in0"); |

             . qq|\$y = $LIB->_new("$in1"); |

             . qq|\@got = $LIB->_div(\$x, \$y);|;

    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};

    eval $test;

    is($@, "", "'$test' gives emtpy \$\@");

    subtest "_div() in list context: $test", sub {

        plan tests => $scalar_util_ok ? 13 : 11;

        cmp_ok(scalar @got, '==', 2,

               "'$test' gives two output args");

        is(ref($got[0]), $REF,

           "'$test' first output arg is a $REF");

        is($LIB->_check($got[0]), 0,

           "'$test' first output arg is valid");

        is($LIB->_str($got[0]), $out0,

           "'$test' first output arg has the right value");

        isnt(refaddr($got[0]), refaddr($y),

             "'$test' first output arg is not the second input arg")

          if $scalar_util_ok;

      SKIP: {

            skip "$LIB doesn't use real objects", 1

              if $LIB eq 'Math::BigInt::FastCalc';

            is(ref($got[1]), $REF,

               "'$test' second output arg is a $REF");

        }

        is($LIB->_check($got[1]), 0,

           "'$test' second output arg is valid");

        is($LIB->_str($got[1]), $out1,

           "'$test' second output arg has the right value");

        isnt(refaddr($got[1]), refaddr($y),

             "'$test' second output arg is not the second input arg");

        is(ref($x), $REF,

           "'$test' first input arg is still a $REF");

        ok($LIB->_str($x) eq $out0 || $LIB->_str($x) eq $in0,

           "'$test' first input arg has the correct value");

        is(ref($y), $REF,

           "'$test' second input arg is still a $REF");

        is($LIB->_str($y), $in1,

           "'$test' second input arg is unmodified");

    };

}

# Scalar context.

for (my $i = 0 ; $i <= $#data ; ++ $i) {

    my ($in0, $in1, $out0, $out1) = @{ $data[$i] };

    my ($x, $y, $got);

    my $test = qq|\$x = $LIB->_new("$in0"); |

             . qq|\$y = $LIB->_new("$in1"); |

             . qq|\$got = $LIB->_div(\$x, \$y);|;

    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};

    eval $test;

    is($@, "", "'$test' gives emtpy \$\@");

    subtest "_div() in scalar context: $test", sub {

        plan tests => $scalar_util_ok ? 8 : 7;

        is(ref($got), $REF,

           "'$test' output arg is a $REF");

        is($LIB->_check($got), 0,

           "'$test' output is valid");

        is($LIB->_str($got), $out0,

           "'$test' output arg has the right value");

        isnt(refaddr($got), refaddr($y),

             "'$test' output arg is not the second input arg")

          if $scalar_util_ok;

        is(ref($x), $REF,

           "'$test' first input arg is still a $REF");

        ok($LIB->_str($x) eq $out0 || $LIB->_str($x) eq $in0,

           "'$test' first input arg has the correct value");

        is(ref($y), $REF,

           "'$test' second input arg is still a $REF");

        is($LIB->_str($y), $in1,

           "'$test' second input arg is unmodified");

    };

}