package JSON;

use strict;

use Carp ();

use Exporter;

BEGIN { @JSON::ISA = 'Exporter' }

@JSON::EXPORT = qw(from_json to_json jsonToObj objToJson encode_json decode_json);

BEGIN {

    $JSON::VERSION = '2.97001';

    $JSON::DEBUG   = 0 unless (defined $JSON::DEBUG);

    $JSON::DEBUG   = $ENV{ PERL_JSON_DEBUG } if exists $ENV{ PERL_JSON_DEBUG };

}

my %RequiredVersion = (

    'JSON::PP' => '2.27203',

    'JSON::XS' => '2.34',

);

# XS and PP common methods

my @PublicMethods = qw/

    ascii latin1 utf8 pretty indent space_before space_after relaxed canonical allow_nonref 

    allow_blessed convert_blessed filter_json_object filter_json_single_key_object 

    shrink max_depth max_size encode decode decode_prefix allow_unknown

/;

my @Properties = qw/

    ascii latin1 utf8 indent space_before space_after relaxed canonical allow_nonref

    allow_blessed convert_blessed shrink max_depth max_size allow_unknown

/;

my @XSOnlyMethods = qw/allow_tags/; # Currently nothing

my @PPOnlyMethods = qw/

    indent_length sort_by

    allow_singlequote allow_bignum loose allow_barekey escape_slash as_nonblessed

/; # JSON::PP specific

# used in _load_xs and _load_pp ($INSTALL_ONLY is not used currently)

my $_INSTALL_DONT_DIE  = 1; # When _load_xs fails to load XS, don't die.

my $_ALLOW_UNSUPPORTED = 0;

my $_UNIV_CONV_BLESSED = 0;

# Check the environment variable to decide worker module. 

unless ($JSON::Backend) {

    $JSON::DEBUG and  Carp::carp("Check used worker module...");

    my $backend = exists $ENV{PERL_JSON_BACKEND} ? $ENV{PERL_JSON_BACKEND} : 1;

    if ($backend eq '1') {

        $backend = 'JSON::XS,JSON::PP';

    }

    elsif ($backend eq '0') {

        $backend = 'JSON::PP';

    }

    elsif ($backend eq '2') {

        $backend = 'JSON::XS';

    }

    $backend =~ s/\s+//g;

    my @backend_modules = split /,/, $backend;

    while(my $module = shift @backend_modules) {

        if ($module =~ /JSON::XS/) {

            _load_xs($module, @backend_modules ? $_INSTALL_DONT_DIE : 0);

        }

        elsif ($module =~ /JSON::PP/) {

            _load_pp($module);

        }

        elsif ($module =~ /JSON::backportPP/) {

            _load_pp($module);

        }

        else {

            Carp::croak "The value of environmental variable 'PERL_JSON_BACKEND' is invalid.";

        }

        last if $JSON::Backend;

    }

}

sub import {

    my $pkg = shift;

    my @what_to_export;

    my $no_export;

    for my $tag (@_) {

        if ($tag eq '-support_by_pp') {

            if (!$_ALLOW_UNSUPPORTED++) {

                JSON::Backend::XS

                    ->support_by_pp(@PPOnlyMethods) if ($JSON::Backend->is_xs);

            }

            next;

        }

        elsif ($tag eq '-no_export') {

            $no_export++, next;

        }

        elsif ( $tag eq '-convert_blessed_universally' ) {

            my $org_encode = $JSON::Backend->can('encode');

            eval q|

                require B;

                local $^W;

                no strict 'refs';

                *{"${JSON::Backend}\::encode"} = sub {

                    # only works with Perl 5.18+

                    local *UNIVERSAL::TO_JSON = sub {

                        my $b_obj = B::svref_2object( $_[0] );

                        return    $b_obj->isa('B::HV') ? { %{ $_[0] } }

                                : $b_obj->isa('B::AV') ? [ @{ $_[0] } ]

                                : undef

                                ;

                    };

                    $org_encode->(@_);

                };

            | if ( !$_UNIV_CONV_BLESSED++ );

            next;

        }

        push @what_to_export, $tag;

    }

    return if ($no_export);

    __PACKAGE__->export_to_level(1, $pkg, @what_to_export);

}

# OBSOLETED

sub jsonToObj {

    my $alternative = 'from_json';

    if (defined $_[0] and UNIVERSAL::isa($_[0], 'JSON')) {

        shift @_; $alternative = 'decode';

    }

    Carp::carp "'jsonToObj' will be obsoleted. Please use '$alternative' instead.";

    return JSON::from_json(@_);

};

sub objToJson {

    my $alternative = 'to_json';

    if (defined $_[0] and UNIVERSAL::isa($_[0], 'JSON')) {

        shift @_; $alternative = 'encode';

    }

    Carp::carp "'objToJson' will be obsoleted. Please use '$alternative' instead.";

    JSON::to_json(@_);

};

# INTERFACES

sub to_json ($@) {

    if (

        ref($_[0]) eq 'JSON'

        or (@_ > 2 and $_[0] eq 'JSON')

    ) {

        Carp::croak "to_json should not be called as a method.";

    }

    my $json = JSON->new;

    if (@_ == 2 and ref $_[1] eq 'HASH') {

        my $opt  = $_[1];

        for my $method (keys %$opt) {

            $json->$method( $opt->{$method} );

        }

    }

    $json->encode($_[0]);

}

sub from_json ($@) {

    if ( ref($_[0]) eq 'JSON' or $_[0] eq 'JSON' ) {

        Carp::croak "from_json should not be called as a method.";

    }

    my $json = JSON->new;

    if (@_ == 2 and ref $_[1] eq 'HASH') {

        my $opt  = $_[1];

        for my $method (keys %$opt) {

            $json->$method( $opt->{$method} );

        }

    }

    return $json->decode( $_[0] );

}

sub true  { $JSON::true  }

sub false { $JSON::false }

sub null  { undef; }

sub require_xs_version { $RequiredVersion{'JSON::XS'}; }

sub backend {

    my $proto = shift;

    $JSON::Backend;

}

#*module = *backend;

sub is_xs {

    return $_[0]->backend->is_xs;

}

sub is_pp {

    return $_[0]->backend->is_pp;

}

sub pureperl_only_methods { @PPOnlyMethods; }

sub property {

    my ($self, $name, $value) = @_;

    if (@_ == 1) {

        my %props;

        for $name (@Properties) {

            my $method = 'get_' . $name;

            if ($name eq 'max_size') {

                my $value = $self->$method();

                $props{$name} = $value == 1 ? 0 : $value;

                next;

            }

            $props{$name} = $self->$method();

        }

        return \%props;

    }

    elsif (@_ > 3) {

        Carp::croak('property() can take only the option within 2 arguments.');

    }

    elsif (@_ == 2) {

        if ( my $method = $self->can('get_' . $name) ) {

            if ($name eq 'max_size') {

                my $value = $self->$method();

                return $value == 1 ? 0 : $value;

            }

            $self->$method();

        }

    }

    else {

        $self->$name($value);

    }

}

# INTERNAL

sub __load_xs {

    my ($module, $opt) = @_;

    $JSON::DEBUG and Carp::carp "Load $module.";

    my $required_version = $RequiredVersion{$module} || '';

    eval qq|

        use $module $required_version ();

    |;

    if ($@) {

        if (defined $opt and $opt & $_INSTALL_DONT_DIE) {

            $JSON::DEBUG and Carp::carp "Can't load $module...($@)";

            return 0;

        }

        Carp::croak $@;

    }

    $JSON::BackendModuleXS = $module;

    return 1;

}

sub _load_xs {

    my ($module, $opt) = @_;

    __load_xs($module, $opt) or return;

    my $data = join("", <DATA>); # this code is from Jcode 2.xx.

    close(DATA);

    eval $data;

    JSON::Backend::XS->init($module);

    return 1;

};

sub __load_pp {

    my ($module, $opt) = @_;

    $JSON::DEBUG and Carp::carp "Load $module.";

    my $required_version = $RequiredVersion{$module} || '';

    eval qq| use $module $required_version () |;

    if ($@) {

        if ( $module eq 'JSON::PP' ) {

            $JSON::DEBUG and Carp::carp "Can't load $module ($@), so try to load JSON::backportPP";

            $module = 'JSON::backportPP';

            local $^W; # if PP installed but invalid version, backportPP redefines methods.

            eval qq| require $module |;

        }

        Carp::croak $@ if $@;

    }

    $JSON::BackendModulePP = $module;

    return 1;

}

sub _load_pp {

    my ($module, $opt) = @_;

    __load_pp($module, $opt);

    JSON::Backend::PP->init($module);

};

#

# Helper classes for Backend Module (PP)

#

package JSON::Backend::PP;

sub init {

    my ($class, $module) = @_;

    # name may vary, but the module should (always) be a JSON::PP

    local $^W;

    no strict qw(refs); # this routine may be called after JSON::Backend::XS init was called.

    *{"JSON::decode_json"} = \&{"JSON::PP::decode_json"};

    *{"JSON::encode_json"} = \&{"JSON::PP::encode_json"};

    *{"JSON::is_bool"} = \&{"JSON::PP::is_bool"};

    $JSON::true  = ${"JSON::PP::true"};

    $JSON::false = ${"JSON::PP::false"};

    push @JSON::Backend::PP::ISA, 'JSON::PP';

    push @JSON::ISA, $class;

    $JSON::Backend = $class;

    $JSON::BackendModule = $module;

    ${"$class\::VERSION"} = $module->VERSION;

    for my $method (@XSOnlyMethods) {

        *{"JSON::$method"} = sub {

            Carp::carp("$method is not supported in $module.");

            $_[0];

        };

    }

    return 1;

}

sub is_xs { 0 };

sub is_pp { 1 };

#

# To save memory, the below lines are read only when XS backend is used.

#

package JSON;

1;

__DATA__

#

# Helper classes for Backend Module (XS)

#

package JSON::Backend::XS;

sub init {

    my ($class, $module) = @_;

    local $^W;

    no strict qw(refs);

    *{"JSON::decode_json"} = \&{"$module\::decode_json"};

    *{"JSON::encode_json"} = \&{"$module\::encode_json"};

    *{"JSON::is_bool"} = \&{"$module\::is_bool"};

    $JSON::true  = ${"$module\::true"};

    $JSON::false = ${"$module\::false"};

    push @JSON::Backend::XS::ISA, $module;

    push @JSON::ISA, $class;

    $JSON::Backend = $class;

    $JSON::BackendModule = $module;

    ${"$class\::VERSION"} = $module->VERSION;

    if ( $module->VERSION < 3 ) {

        eval 'package JSON::PP::Boolean';

        push @{"$module\::Boolean::ISA"}, qw(JSON::PP::Boolean);

    }

    for my $method (@PPOnlyMethods) {

        *{"JSON::$method"} = sub {

            Carp::carp("$method is not supported in $module.");

            $_[0];

        };

    }

    return 1;

}

sub is_xs { 1 };

sub is_pp { 0 };

sub support_by_pp {

    my ($class, @methods) = @_;

    JSON::__load_pp('JSON::PP');

    local $^W;

    no strict qw(refs);

    for my $method (@methods) {

        my $pp_method = JSON::PP->can($method) or next;

        *{"JSON::$method"} = sub {

            if (!$_[0]->isa('JSON::PP')) {

                my $xs_self = $_[0];

                my $pp_self = JSON::PP->new;

                for (@Properties) {

                     my $getter = "get_$_";

                    $pp_self->$_($xs_self->$getter);

                }

                $_[0] = $pp_self;

            }

            $pp_method->(@_);

        };

    }

    $JSON::DEBUG and Carp::carp("set -support_by_pp mode.");

}

1;

__END__

=head1 NAME

JSON - JSON (JavaScript Object Notation) encoder/decoder

=head1 SYNOPSIS

 use JSON; # imports encode_json, decode_json, to_json and from_json.

 # simple and fast interfaces (expect/generate UTF-8)

 $utf8_encoded_json_text = encode_json $perl_hash_or_arrayref;

 $perl_hash_or_arrayref  = decode_json $utf8_encoded_json_text;

 # OO-interface

 $json = JSON->new->allow_nonref;

 $json_text   = $json->encode( $perl_scalar );

 $perl_scalar = $json->decode( $json_text );

 $pretty_printed = $json->pretty->encode( $perl_scalar ); # pretty-printing

=head1 VERSION

    2.97001

=head1 DESCRIPTION

This module is a thin wrapper for L<JSON::XS>-compatible modules with a few

additional features. All the backend modules convert a Perl data structure

to a JSON text as of RFC4627 (which we know is obsolete but we still stick

to; see below for an option to support part of RFC7159) and vice versa.

This module uses L<JSON::XS> by default, and when JSON::XS is not available,

this module falls back on L<JSON::PP>, which is in the Perl core since 5.14.

If JSON::PP is not available either, this module then falls back on

JSON::backportPP (which is actually JSON::PP in a different .pm file)

bundled in the same distribution as this module. You can also explicitly

specify to use L<Cpanel::JSON::XS>, a fork of JSON::XS by Reini Urban.

All these backend modules have slight incompatibilities between them,

including extra features that other modules don't support, but as long as you

use only common features (most important ones are described below), migration

from backend to backend should be reasonably easy. For details, see each

backend module you use.

=head1 CHOOSING BACKEND

This module respects an environmental variable called C<PERL_JSON_BACKEND>

when it decides a backend module to use. If this environmental variable is

not set, it tries to load JSON::XS, and if JSON::XS is not available, it

falls back on JSON::PP, and then JSON::backportPP if JSON::PP is not available

either.

If you always don't want it to fall back on pure perl modules, set the

variable like this (C<export> may be C<setenv>, C<set> and the likes,

depending on your environment):

  > export PERL_JSON_BACKEND=JSON::XS

If you prefer Cpanel::JSON::XS to JSON::XS, then:

  > export PERL_JSON_BACKEND=Cpanel::JSON::XS,JSON::XS,JSON::PP

You may also want to set this variable at the top of your test files, in order

not to be bothered with incompatibilities between backends (you need to wrap

this in C<BEGIN>, and set before actually C<use>-ing JSON module, as it decides

its backend as soon as it's loaded):

  BEGIN { $ENV{PERL_JSON_BACKEND}='JSON::backportPP'; }

  use JSON;

=head1 USING OPTIONAL FEATURES

There are a few options you can set when you C<use> this module:

=over

=item -support_by_pp

   BEGIN { $ENV{PERL_JSON_BACKEND} = 'JSON::XS' }

   use JSON -support_by_pp;

   my $json = JSON->new;

   # escape_slash is for JSON::PP only.

   $json->allow_nonref->escape_slash->encode("/");

With this option, this module loads its pure perl backend along with

its XS backend (if available), and lets the XS backend to watch if you set

a flag only JSON::PP supports. When you do, the internal JSON::XS object

is replaced with a newly created JSON::PP object with the setting copied

from the XS object, so that you can use JSON::PP flags (and its slower

C<decode>/C<encode> methods) from then on. In other words, this is not

something that allows you to hook JSON::XS to change its behavior while

keeping its speed. JSON::XS and JSON::PP objects are quite different

(JSON::XS object is a blessed scalar reference, while JSON::PP object is

a blessed hash reference), and can't share their internals.

To avoid needless overhead (by copying settings), you are advised not

to use this option and just to use JSON::PP explicitly when you need

JSON::PP features.

=item -convert_blessed_universally

   use JSON -convert_blessed_universally;

   my $json = JSON->new->allow_nonref->convert_blessed;

   my $object = bless {foo => 'bar'}, 'Foo';

   $json->encode($object); # => {"foo":"bar"}

JSON::XS-compatible backend modules don't encode blessed objects by

default (except for their boolean values, which are typically blessed

JSON::PP::Boolean objects). If you need to encode a data structure

that may contain objects, you usually need to look into the structure

and replace objects with alternative non-blessed values, or enable

C<convert_blessed> and provide a C<TO_JSON> method for each object's

(base) class that may be found in the structure, in order to let the

methods replace the objects with whatever scalar values the methods

return.

If you need to serialise data structures that may contain arbitrary

objects, it's probably better to use other serialisers (such as

L<Sereal> or L<Storable> for example), but if you do want to use

this module for that purpose, C<-convert_blessed_universally> option

may help, which tweaks C<encode> method of the backend to install

C<UNIVERSAL::TO_JSON> method (locally) before encoding, so that

all the objects that don't have their own C<TO_JSON> method can

fall back on the method in the C<UNIVERSAL> namespace. Note that you

still need to enable C<convert_blessed> flag to actually encode

objects in a data structure, and C<UNIVERSAL::TO_JSON> method

installed by this option only converts blessed hash/array references

into their unblessed clone (including private keys/values that are

not supposed to be exposed). Other blessed references will be

converted into null.

This feature is experimental and may be removed in the future.

=item -no_export

When you don't want to import functional interfaces from a module, you

usually supply C<()> to its C<use> statement.

    use JSON (); # no functional interfaces

If you don't want to import functional interfaces, but you also want to

use any of the above options, add C<-no_export> to the option list.

   # no functional interfaces, while JSON::PP support is enabled.

   use JSON -support_by_pp, -no_export;

=back

=head1 FUNCTIONAL INTERFACE

This section is taken from JSON::XS. C<encode_json> and C<decode_json>

are exported by default.

This module also exports C<to_json> and C<from_json> for backward

compatibility. These are slower, and may expect/generate different stuff

from what C<encode_json> and C<decode_json> do, depending on their

options. It's better just to use Object-Oriented interfaces than using

these two functions.

=head2 encode_json

    $json_text = encode_json $perl_scalar

Converts the given Perl data structure to a UTF-8 encoded, binary string

(that is, the string contains octets only). Croaks on error.

This function call is functionally identical to:

    $json_text = JSON->new->utf8->encode($perl_scalar)

Except being faster.

=head2 decode_json

    $perl_scalar = decode_json $json_text

The opposite of C<encode_json>: expects an UTF-8 (binary) string and tries

to parse that as an UTF-8 encoded JSON text, returning the resulting

reference. Croaks on error.

This function call is functionally identical to:

    $perl_scalar = JSON->new->utf8->decode($json_text)

Except being faster.

=head2 to_json

   $json_text = to_json($perl_scalar[, $optional_hashref])

Converts the given Perl data structure to a Unicode string by default.

Croaks on error.

Basically, this function call is functionally identical to:

   $json_text = JSON->new->encode($perl_scalar)

Except being slower.

You can pass an optional hash reference to modify its behavior, but

that may change what C<to_json> expects/generates (see

C<ENCODING/CODESET FLAG NOTES> for details).

   $json_text = to_json($perl_scalar, {utf8 => 1, pretty => 1})

   # => JSON->new->utf8(1)->pretty(1)->encode($perl_scalar)

=head2 from_json

   $perl_scalar = from_json($json_text[, $optional_hashref])

The opposite of C<to_json>: expects a Unicode string and tries

to parse it, returning the resulting reference. Croaks on error.

Basically, this function call is functionally identical to:

    $perl_scalar = JSON->new->decode($json_text)

You can pass an optional hash reference to modify its behavior, but

that may change what C<from_json> expects/generates (see

C<ENCODING/CODESET FLAG NOTES> for details).

    $perl_scalar = from_json($json_text, {utf8 => 1})

    # => JSON->new->utf8(1)->decode($json_text)

=head2 JSON::is_bool

    $is_boolean = JSON::is_bool($scalar)

Returns true if the passed scalar represents either JSON::true or

JSON::false, two constants that act like C<1> and C<0> respectively

and are also used to represent JSON C<true> and C<false> in Perl strings.

See L<MAPPING>, below, for more information on how JSON values are mapped to

Perl.

=head1 COMMON OBJECT-ORIENTED INTERFACE

This section is also taken from JSON::XS.

The object oriented interface lets you configure your own encoding or

decoding style, within the limits of supported formats.

=head2 new

    $json = JSON->new

Creates a new JSON::XS-compatible backend object that can be used to de/encode JSON

strings. All boolean flags described below are by default I<disabled>.

The mutators for flags all return the backend object again and thus calls can

be chained:

   my $json = JSON->new->utf8->space_after->encode({a => [1,2]})

   => {"a": [1, 2]}

=head2 ascii

    $json = $json->ascii([$enable])

    $enabled = $json->get_ascii

If C<$enable> is true (or missing), then the C<encode> method will not

generate characters outside the code range C<0..127> (which is ASCII). Any

Unicode characters outside that range will be escaped using either a

single \uXXXX (BMP characters) or a double \uHHHH\uLLLLL escape sequence,

as per RFC4627. The resulting encoded JSON text can be treated as a native

Unicode string, an ascii-encoded, latin1-encoded or UTF-8 encoded string,

or any other superset of ASCII.

If C<$enable> is false, then the C<encode> method will not escape Unicode

characters unless required by the JSON syntax or other flags. This results

in a faster and more compact format.

See also the section I<ENCODING/CODESET FLAG NOTES> later in this document.

The main use for this flag is to produce JSON texts that can be

transmitted over a 7-bit channel, as the encoded JSON texts will not

contain any 8 bit characters.

  JSON->new->ascii(1)->encode([chr 0x10401])

  => ["\ud801\udc01"]

=head2 latin1

    $json = $json->latin1([$enable])

    $enabled = $json->get_latin1

If C<$enable> is true (or missing), then the C<encode> method will encode

the resulting JSON text as latin1 (or iso-8859-1), escaping any characters

outside the code range C<0..255>. The resulting string can be treated as a

latin1-encoded JSON text or a native Unicode string. The C<decode> method

will not be affected in any way by this flag, as C<decode> by default

expects Unicode, which is a strict superset of latin1.

If C<$enable> is false, then the C<encode> method will not escape Unicode

characters unless required by the JSON syntax or other flags.

See also the section I<ENCODING/CODESET FLAG NOTES> later in this document.

The main use for this flag is efficiently encoding binary data as JSON

text, as most octets will not be escaped, resulting in a smaller encoded

size. The disadvantage is that the resulting JSON text is encoded

in latin1 (and must correctly be treated as such when storing and

transferring), a rare encoding for JSON. It is therefore most useful when

you want to store data structures known to contain binary data efficiently

in files or databases, not when talking to other JSON encoders/decoders.

  JSON->new->latin1->encode (["\x{89}\x{abc}"]

  => ["\x{89}\\u0abc"]    # (perl syntax, U+abc escaped, U+89 not)

=head2 utf8

    $json = $json->utf8([$enable])

    $enabled = $json->get_utf8

If C<$enable> is true (or missing), then the C<encode> method will encode

the JSON result into UTF-8, as required by many protocols, while the

C<decode> method expects to be handled an UTF-8-encoded string.  Please

note that UTF-8-encoded strings do not contain any characters outside the

range C<0..255>, they are thus useful for bytewise/binary I/O. In future

versions, enabling this option might enable autodetection of the UTF-16

and UTF-32 encoding families, as described in RFC4627.

If C<$enable> is false, then the C<encode> method will return the JSON

string as a (non-encoded) Unicode string, while C<decode> expects thus a

Unicode string.  Any decoding or encoding (e.g. to UTF-8 or UTF-16) needs

to be done yourself, e.g. using the Encode module.

See also the section I<ENCODING/CODESET FLAG NOTES> later in this document.

Example, output UTF-16BE-encoded JSON:

  use Encode;

  $jsontext = encode "UTF-16BE", JSON->new->encode ($object);

Example, decode UTF-32LE-encoded JSON:

  use Encode;

  $object = JSON->new->decode (decode "UTF-32LE", $jsontext);

=head2 pretty

    $json = $json->pretty([$enable])

This enables (or disables) all of the C<indent>, C<space_before> and

C<space_after> (and in the future possibly more) flags in one call to

generate the most readable (or most compact) form possible.

=head2 indent

    $json = $json->indent([$enable])

    $enabled = $json->get_indent

If C<$enable> is true (or missing), then the C<encode> method will use a multiline

format as output, putting every array member or object/hash key-value pair

into its own line, indenting them properly.

If C<$enable> is false, no newlines or indenting will be produced, and the

resulting JSON text is guaranteed not to contain any C<newlines>.

This setting has no effect when decoding JSON texts.

=head2 space_before

    $json = $json->space_before([$enable])

    $enabled = $json->get_space_before

If C<$enable> is true (or missing), then the C<encode> method will add an extra

optional space before the C<:> separating keys from values in JSON objects.

If C<$enable> is false, then the C<encode> method will not add any extra

space at those places.

This setting has no effect when decoding JSON texts. You will also

most likely combine this setting with C<space_after>.

Example, space_before enabled, space_after and indent disabled:

   {"key" :"value"}

=head2 space_after

    $json = $json->space_after([$enable])

    $enabled = $json->get_space_after

If C<$enable> is true (or missing), then the C<encode> method will add an extra

optional space after the C<:> separating keys from values in JSON objects

and extra whitespace after the C<,> separating key-value pairs and array

members.

If C<$enable> is false, then the C<encode> method will not add any extra

space at those places.

This setting has no effect when decoding JSON texts.

Example, space_before and indent disabled, space_after enabled:

   {"key": "value"}

=head2 relaxed

    $json = $json->relaxed([$enable])

    $enabled = $json->get_relaxed

If C<$enable> is true (or missing), then C<decode> will accept some

extensions to normal JSON syntax (see below). C<encode> will not be

affected in anyway. I

JSON texts as if they were valid!>. I suggest only to use this option to

parse application-specific files written by humans (configuration files,

resource files etc.)

If C<$enable> is false (the default), then C<decode> will only accept

valid JSON texts.

Currently accepted extensions are:

=over 4

=item * list items can have an end-comma

JSON I<separates> array elements and key-value pairs with commas. This

can be annoying if you write JSON texts manually and want to be able to

quickly append elements, so this extension accepts comma at the end of

such items not just between them:

   [

      1,

      2, <- this comma not normally allowed