Προβολέας εικόνων (Vala)

Δημιουργία έργου με το Anjuta

Πριν ξεκινήσετε να προγραμματίζετε, πρέπει να δημιουργήσετε ένα καινούργιο έργο στο Anjuta. Έτσι θα δημιουργηθούν όλα τα απαραίτητα αρχεία που χρειάζονται για την εκτέλεση του κώδικα αργότερα. Επίσης θα ήταν χρήσιμο να τα κρατάτε όλα μαζί.

Ξεκινήστε το Anjuta και πατήστε δημιουργία νέου έργου ή αρχείονέοέργο για να ανοίξετε τον οδηγό του έργου.

Από την καρτέλα Vala επιλέξτε GTK+ (απλό), πατήστε συνέχεια και συμπληρώστε τις λεπτομέρειές σας στην επόμενη σελίδα. Χρησιμοποιήστε το image-viewer ως όνομα του έργου και του καταλόγου.

Βεβαιωθείτε ότι το χρήση του GtkBuilder για διεπαφή χρήστη είναι ασημείωτο επειδή θα δημιουργήσουμε την UI χειροκίνητα σε αυτό το μάθημα.

Θα μάθετε πώς να χρησιμοποιήσετε τον κατασκευαστή διεπαφής στο μάθημα ρυθμιστής κιθάρας.

Πατήστε συνέχεια, έπειτα εφαρμογή και το έργο θα δημιουργηθεί για εσάς. Ανοίξτε το src/image_viewer.vala από τις καρτέλες έργο ή αρχείο. Θα δείτε αυτόν τον κώδικα:


using GLib;
using Gtk;

public class Main : Object
{

	public Main ()
	{
		Window window = new Window();
		window.set_title ("Hello World");
		window.show_all();
		window.destroy.connect(on_destroy);
	}

	public void on_destroy (Widget window)
	{
		Gtk.main_quit();
	}

	static int main (string[] args)
	{
		Gtk.init (ref args);
		var app = new Main ();

		Gtk.main ();

		return 0;
	}
}

Κατασκευάστε τον κώδικα για πρώτη φορά

Ο κώδικας φορτώνει ένα (κενό) παράθυρο από το αρχείο περιγραφής διεπαφής χρήστη και το εμφανίζει. Περισσότερες πληροφορίες υπάρχουν πιο κάτω· προσπεράστε αυτή τη λίστα αν καταλαβαίνετε τα βασικά:

Οι δύο γραμμές using στην κορυφή εισάγουν τους χώρους ονομάτων, έτσι ώστε να μην έχουμε να ονομαστούν ρητά.

Ο κατασκευαστής της κλάσης Main δημιουργεί ένα νέο (κενό) παράθυρο και συνδέει ένα σήμα για έξοδο από την εφαρμογή, όταν το παράθυρο κλείσει.

Σύνδεση σημάτων είναι πώς καθορίζετε τι συμβαίνει όταν πατάτε ένα κουμπί, ή όταν συμβεί κάποιο άλλο συμβάν. Εδώ, καλείται η συνάρτηση destroy (και τερματίζει την εφαρμογή) όταν κλείνετε το παράθυρο.

Η συνάρτηση static main τρέχει από προεπιλογή όταν ξεκινάτε μια εφαρμογή Vala. Καλεί λίγες συναρτήσεις που δημιουργούν την κλάση Main, ρυθμίζουν και μετά τρέχουν την εφαρμογή. Η συνάρτηση Gtk.main ξεκινά την GTK κύριος βρόχος, που τρέχει τη διεπαφή χρήστη και ξεκινά ακρόαση των συμβάντων (όπως κλικ και πατήματα πλήκτρου).

Αυτός ο κώδικας είναι έτοιμος να χρησιμοποιηθεί, οπότε μπορείτε να τον μεταγλωττίσετε με κλικ κατασκευήκατασκευή έργου (ή πιέζοντας ShiftF7).

Αλλαγή της ρύθμισης σε προεπιλογή και τότε πάτημα εκτέλεση για ρύθμιση του καταλόγου κατασκευής. Χρειάζεται να το κάνετε μόνο μια φορά, για την πρώτη κατασκευή.

Δημιουργία της διεπαφής χρήστη

Τώρα θα δώσουμε ζωή σε ένα άδειο παράθυρο. Το GTK οργανώνει τη διεπαφή χρήστη με το Gtk.Container που μπορούν να περιέχουν άλλα γραφικά στοιχεία και ακόμα άλλους περιέκτες. Εδώ θα χρησιμοποιήσουμε τον απλούστερο διαθέσιμο περιέκτη, ένα Gtk.Box.

Προσθέστε τις επόμενες γραμμές στην κορυφή της κλάσης Main:


private Window window;
private Image image;

Τώρα αντικαταστήστε τον τρέχοντα κατασκευαστή με τον παρακάτω:



public Main () {

	window = new Window ();
	window.set_title ("Image Viewer in Vala");

	//Ρύθμιση της διεπαφής χρήστη
	var box = new Box (Orientation.VERTICAL, 5);
	var button = new Button.with_label ("Open image");
	image = new Image ();

	box.pack_start (image, true, true, 0);
	box.pack_start (button, false, false, 0);
	window.add (box);

	// Εμφάνιση ανοικτού διαλόγου κατά το άνοιγμα αρχείου
	button.clicked.connect (on_open_image);

	window.show_all ();
	window.destroy.connect (main_quit);
}

Οι πρώτες δύο γραμμές είναι μέρη του GUI που θα χρειαστούν πρόσβαση από περισσότερες από μία μεθόδους. Τις δηλώνουμε εδώ έτσι ώστε να είναι προσβάσιμες μέσα από την κλάση αντί μόνο από τη μέθοδο όπου δημιουργούνται.

Οι πρώτες γραμμές του κατασκευαστή δημιουργούν το άδειο παράθυρο. Οι επόμενες γραμμές δημιουργούν τα γραφικά στοιχεία που θέλουμε να χρησιμοποιήσουμε: ένα κουμπί για άνοιγμα μιας εικόνας, το ίδιο το γραφικό στοιχείο προβολής της εικόνας και το πλαίσιο που θα χρησιμοποιήσουμε ως περιέκτη.

Οι κλήσεις στο pack_start προσθέτουν τα δύο γραφικά στοιχεία στο πλαίσιο και ορίζουν τη συμπεριφορά τους. Η εικόνα θα επεκταθεί σε κάθε διαθέσιμο χώρο ενώ το κουμπί θα είναι απλά τόσο μεγάλο όσο χρειάζεται. Θα παρατηρήσετε ότι δεν ορίζουμε ρητά μεγέθη στα γραφικά στοιχεία. Στο GTK αυτό συνήθως δεν χρειάζεται επειδή είναι πιο απλό να έχετε μια διάταξη που φαίνεται καλή με διαφορετικά μεγέθη παραθύρων. Στη συνέχεια, το πλαίσιο προστίθεται στο παράθυρο.

Χρειάζεται να ορίσουμε τι συμβαίνει όταν ο χρήστης πατά το κουμπί. Το GTK χρησιμοποιεί την έννοια των σημάτων.

Όταν το κουμπί πατιέται προκαλεί το σήμα clicked, που μπορούμε να συνδέσουμε με κάποια ενέργεια (ορισμένη σε μια μέθοδο επανάκλησης).

Αυτό γίνεται χρησιμοποιώντας τη μέθοδο connect του σήματος του κουμπιού clicked, που σε αυτήν την περίπτωση λέει στο GTK να καλέσει την μέθοδο επανάκλησης (αόριστη ακόμα) on_image_open όταν το κουμπί πατιέται. Θα ορίσουμε την επανάκληση στην επόμενη ενότητα.

Στην επανάκληση, χρειαζόμαστε να προσπελάσουμε τα γραφικά στοιχεία window και image, γι' αυτό τα ορίζουμε ως ιδιωτικά μέλη στην κορυφή των κλάσεων μας.

Η τελευταία κλήση connect βεβαιώνεται ότι η εφαρμογή εξέρχεται όταν το παράθυρο κλείνει. Ο δημιουργούμενος κώδικας από το Anjuta κάλεσε μια μέθοδο επανάκλησης on_destroy που κάλεσε Gtk.main_quit, αλλά η σύνδεση του σήματος μας στο main_quit άμεσα είναι ευκολότερη. Μπορείτε να διαγράψετε τη μέθοδο on_destroy.

Εμφάνιση της εικόνας

Θα ορίσουμε τώρα τον χειριστή σήματος για το σήμα clicked για το κουμπί που αναφέραμε πριν. Προσθέστε αυτόν τον κώδικα μετά τον κατασκευαστή:


public void on_open_image (Button self) {
	var filter = new FileFilter ();
	var dialog = new FileChooserDialog ("Open image",
	                                    window,
	                                    FileChooserAction.OPEN,
	                                    Stock.OK,     ResponseType.ACCEPT,
	                                    Stock.CANCEL, ResponseType.CANCEL);
	filter.add_pixbuf_formats ();
	dialog.add_filter (filter);

	switch (dialog.run ())
	{
		case ResponseType.ACCEPT:
			var filename = dialog.get_filename ();
			image.set_from_file (filename);
			break;
		default:
			break;
	}
	dialog.destroy ();
}

Αυτό είναι λίγο πιο περίπλοκο, γιαυτό ας το χωρίσουμε:

Ένας χειριστής σήματος είναι ένας τύπος της μεθόδου επανάκλησης που καλείται όταν ένα σήμα εκπέμπεται. Εδώ οι όροι χρησιμοποιούνται εναλλακτικά.

Το πρώτο όρισμα της μεθόδου επανάκλησης είναι πάντοτε το γραφικό στοιχείο που έστειλε το σήμα. Μερικές φορές άλλα ορίσματα που συνδέονται με το σήμα έρχονται μετά από αυτό, αλλά πατημένο δεν έχει κανένα.

Σε αυτήν την περίπτωση το button έστειλε το σήμα clicked, που συνδέεται με τη μέθοδο επανάκλησης on_open_image:


        button.clicked.connect (on_open_image);

Η μέθοδος on_open_image παίρνει το κουμπί που εξέπεμψε το σήμα ως όρισμα:


        public void on_open_image (Button self)

Η επόμενη ενδιαφέρουσα γραμμή είναι όταν ο διάλογος επιλογής του αρχείου δημιουργείται. Το FileChooserDialog του κατασκευαστή παίρνει τον τίτλο του διαλόγου, το ανιόν παράθυρο του διαλόγου και πολλές επιλογές όπως ο αριθμός των κουμπιών και οι αντίστοιχες τιμές τους.

Σημειώστε όταν χρησιμοποιούμε τα ονόματα κουμπιών αποθέματος από το Gtk, αντί να γράψουμε χειροκίνητα "ακύρωση" ή "άνοιγμα". Το πλεονέκτημα της χρήσης των ονομάτων αποθέματος είναι ότι οι ετικέτες των κουμπιών θα έχουν ήδη μεταφραστεί στη γλώσσα του χρήστη.

Οι επόμενες δύο γραμμές περιορίζουν το διάλογο άνοιγμα να εμφανίζει μόνο αρχεία που μπορούν να ανοιχθούν από το GtkImage. Το GtkImage είναι ένα γραφικό στοιχείο που εμφανίζει μια εικόνα. Ένα αντικείμενο φίλτρου δημιουργείται πρώτα· έπειτα προσθέτουμε όλα τα είδη των αρχείων που υποστηρίζονται από Gdk.Pixbuf(το οποίο περιλαμβάνει τις περισσότερες μορφές εικόνων όπως PNG και JPEG) στο φίλτρο. Τέλος, ορίζουμε αυτό το φίλτρο να είναι το φίλτρο του διαλόγου άνοιγμα.

Το dialog.run εμφανίζει το διάλογο άνοιγμα. Ο διάλογος θα περιμένει να επιλέξει ο χρήστης μια εικόνα· όταν γίνει το dialog.run θα επιστρέψει την τιμή ResponseType ResponseType.ACCEPT (θα μπορούσε να επιστρέψει το ResponseType.CANCEL εάν ο χρήστης πατούσε ακύρωση). Η πρόταση switch το ελέγχει.

Αν υποθέσουμε ότι ο χρήστης πάτησε το άνοιγμα, οι επόμενες γραμμές παίρνουν το όνομα του αρχείου της επιλεγμένης εικόνας από τον χρήστη και λέει στο γραφικό στοιχείο GtkImage να φορτώσει και να εμφανίσει την επιλεγμένη εικόνα.

Στην τελευταία γραμμή αυτής της μεθόδου, καταστρέφουμε τον διάλογο άνοιγμα γιατί δεν τον χρειαζόμαστε πια.

Η αυτόματη καταστροφή κρύβει το διάλογο.

Κατασκευή και εκτέλεση της εφαρμογής

Όλος ο κώδικας πρέπει να είναι έτοιμος τώρα. Κλικ κατασκευήκατασκευή έργου για ανακατασκευή των πάντων και έπειτα τρέξιμοεκτέλεση για έναρξη της εφαρμογής.

Εάν δεν το έχετε ήδη κάνει, επιλέξτε την εφαρμογή src/image-viewer στον διάλογο που εμφανίζεται. Τελικά, πατήστε τρέξιμο και απολαύστε το!

Υλοποίηση αναφοράς

Αν αντιμετωπίσετε πρόβλημα με το μάθημα, συγκρίνετε τον κώδικά σας με αυτόν τον κώδικα αναφοράς.

Επόμενα βήματα

Εδώ είναι κάποιες ιδέες για το πώς μπορείτε να επεκτείνετε αυτή την απλή παρουσίαση:

Εγκαταστήστε την έτσι ώστε όταν το παράθυρο ανοίγει να είναι συγκεκριμένου μεγέθους για εκκίνηση. Για παράδειγμα, 200 Χ 200 εικονοστοιχεία.

Βάλτε τον χρήστη να επιλέξει ένα κατάλογο αντί για αρχείο και δώστε ελέγχους να γυρίζουν όλες τις εικόνες σε έναν κατάλογο.

Εφαρμόστε τυχαία φίλτρα και εφέ στην εικόνα όταν αυτή φορτωθεί και επιτρέψτε στον χρήστη να αποθηκεύσει την επεξεργασμένη εικόνα.

Το GEGL παρέχει ισχυρές δυνατότητες επεξεργασίας εικόνας.

Επιτρέψτε στον χρήστη να φορτώνει εικόνες από μερισμό δικτύου, από σαρωτές και από άλλες περίπλοκες πηγές.

You can use GIO to handle network file transfers and the like, and GNOME Scan to handle scanning.