Tento rozbalovací seznam vypíše do terminálu, co jste si vybrali, když provedete změnu.
class MyWindow : Gtk.ApplicationWindow {
string[] file = {"Select", "New", "Open", "Save"};
string[] stock_item = {"","gtk-new", "gtk-open", "gtk-save"};
enum Column {
FILE,
STOCK_ITEM
}
/* Konstruktor */
internal MyWindow (MyApplication app) {
Object (application: app, title: "Welcome to GNOME");
this.set_default_size (200, -1);
this.border_width = 10;
Gtk.ListStore liststore = new Gtk.ListStore (2, typeof (string), typeof (string));
for (int i = 0; i < file.length; i++){
Gtk.TreeIter iter;
liststore.append (out iter);
liststore.set (iter, Column.FILE, file[i]);
liststore.set (iter, Column.STOCK_ITEM, stock_item[i]);
}
Gtk.ComboBox combobox = new Gtk.ComboBox.with_model (liststore);
/* CellRenderers vykreslující data */
Gtk.CellRendererText cell = new Gtk.CellRendererText ();
Gtk.CellRendererPixbuf cell_pb = new Gtk.CellRendererPixbuf ();
/* Zabalí buňku do začátku rozbalovacího seznamu, nepřiděluje více
* místa, než je zapotřebí.
* První je obrázek, potom text.
* Uvědomte si, že nezáleží na pořadí, ve jakém jsou v modelu,
* vizualizace je dána pořadím vykreslovačů buněk
*/
combobox.pack_start (cell_pb, false);
combobox.pack_start (cell, false);
/* Přiřadí vlastnost cellrenderer sloupci v modelu použítém
* rozbalovacím seznamem
*/
combobox.set_attributes (cell_pb, "stock_id", Column.STOCK_ITEM);
combobox.set_attributes (cell, "text", Column.FILE);
/* Nastaví první položku v seznamu jako vybranou (aktivní) */
combobox.set_active (0);
/* Napojí signál "changed" rozbalovacího seznamu na
* obsluhu signálu (neboli funkci zpětného volání)
*/
combobox.changed.connect (this.item_changed);
/* Přidá rozbalovací seznam do tohoto okna */
this.add (combobox);
combobox.show ();
}
void item_changed (Gtk.ComboBox combo) {
if (combo.get_active () !=0) {
print ("You chose " + file [combo.get_active ()] +"\n");
}
}
}
class MyApplication : Gtk.Application {
protected override void activate () {
new MyWindow (this).show ();
}
}
int main (string[] args) {
return new MyApplication ().run (args);
}
V této ukázce se používá následující:
GtkComboBox
GtkListStore
GtkCellRendererText
GtkCellRendererPixbuf
Standardní položky