|
Packit Service |
93dc7a |
/* Vector optimized 32/64 bit S/390 version of strpbrk.
|
|
Packit Service |
93dc7a |
Copyright (C) 2015-2018 Free Software Foundation, Inc.
|
|
Packit Service |
93dc7a |
This file is part of the GNU C Library.
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
The GNU C Library is free software; you can redistribute it and/or
|
|
Packit Service |
93dc7a |
modify it under the terms of the GNU Lesser General Public
|
|
Packit Service |
93dc7a |
License as published by the Free Software Foundation; either
|
|
Packit Service |
93dc7a |
version 2.1 of the License, or (at your option) any later version.
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
The GNU C Library is distributed in the hope that it will be useful,
|
|
Packit Service |
93dc7a |
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
Packit Service |
93dc7a |
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Packit Service |
93dc7a |
Lesser General Public License for more details.
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
You should have received a copy of the GNU Lesser General Public
|
|
Packit Service |
93dc7a |
License along with the GNU C Library; if not, see
|
|
Packit Service |
93dc7a |
<http://www.gnu.org/licenses/>. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
66f556 |
#include <ifunc-strpbrk.h>
|
|
Packit Service |
66f556 |
|
|
Packit Service |
66f556 |
#if HAVE_STRPBRK_Z13
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
# include "sysdep.h"
|
|
Packit Service |
93dc7a |
# include "asm-syntax.h"
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.text
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/* char *strpbrk (const char *s, const char * accept)
|
|
Packit Service |
93dc7a |
The strpbrk() function locates the first occurrence in the string s
|
|
Packit Service |
93dc7a |
of any of the characters in the string accept and returns a pointer
|
|
Packit Service |
93dc7a |
to that character or NULL if not found.
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
This method checks the length of accept string. If it fits entirely
|
|
Packit Service |
93dc7a |
in one vector register, a fast algorithm is used, which does not need
|
|
Packit Service |
93dc7a |
to check multiple parts of accept-string. Otherwise a slower full
|
|
Packit Service |
93dc7a |
check of accept-string is used.
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
register overview:
|
|
Packit Service |
93dc7a |
r3: pointer to start of accept-string
|
|
Packit Service |
93dc7a |
r2: pointer to start of search-string
|
|
Packit Service |
93dc7a |
r0: loaded byte count of vlbb search-string (32bit unsigned)
|
|
Packit Service |
93dc7a |
r4: found byte index (32bit unsigned)
|
|
Packit Service |
93dc7a |
r1: current return len (64bit unsigned)
|
|
Packit Service |
93dc7a |
v16: search-string
|
|
Packit Service |
93dc7a |
v17: accept-string
|
|
Packit Service |
93dc7a |
v18: temp-vreg
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
ONLY FOR SLOW:
|
|
Packit Service |
93dc7a |
v19: first accept-string
|
|
Packit Service |
93dc7a |
v20: zero for preparing acc-vector
|
|
Packit Service |
93dc7a |
v21: global mask; 1 indicates a match between
|
|
Packit Service |
93dc7a |
search-string-vreg and any accept-character
|
|
Packit Service |
93dc7a |
v22: current mask; 1 indicates a match between
|
|
Packit Service |
93dc7a |
search-string-vreg and any accept-character in current acc-vreg
|
|
Packit Service |
93dc7a |
v24: one for result-checking of former string-part
|
|
Packit Service |
93dc7a |
v30, v31: for re-/storing registers r6, r8, r9
|
|
Packit Service |
93dc7a |
r5: current len of accept-string
|
|
Packit Service |
93dc7a |
r6: zero-index in search-string or 16 if no zero
|
|
Packit Service |
93dc7a |
or min(zero-index, loaded byte count)
|
|
Packit Service |
93dc7a |
r8: >0, if former accept-string-part contains a zero,
|
|
Packit Service |
93dc7a |
otherwise =0;
|
|
Packit Service |
93dc7a |
r9: loaded byte count of vlbb accept-string
|
|
Packit Service |
93dc7a |
*/
|
|
Packit Service |
66f556 |
ENTRY(STRPBRK_Z13)
|
|
Packit Service |
93dc7a |
.machine "z13"
|
|
Packit Service |
93dc7a |
.machinemode "zarch_nohighgprs"
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/*
|
|
Packit Service |
93dc7a |
Check if accept-string fits in one vreg:
|
|
Packit Service |
93dc7a |
----------------------------------------
|
|
Packit Service |
93dc7a |
*/
|
|
Packit Service |
93dc7a |
vlbb %v17,0(%r3),6 /* Load accept. */
|
|
Packit Service |
93dc7a |
lghi %r1,0 /* Zero out current len. */
|
|
Packit Service |
93dc7a |
vlgvb %r0,%v17,0 /* Get first element. */
|
|
Packit Service |
93dc7a |
clije %r0,0,.Lfast_end_null /* Return null if accept is empty. */
|
|
Packit Service |
93dc7a |
lcbb %r0,0(%r3),6
|
|
Packit Service |
93dc7a |
jo .Lcheck_onbb /* Special case if accept lays
|
|
Packit Service |
93dc7a |
on block-boundary. */
|
|
Packit Service |
93dc7a |
.Lcheck_notonbb:
|
|
Packit Service |
93dc7a |
vistrbs %v17,%v17 /* Fill with zeros after first zero. */
|
|
Packit Service |
93dc7a |
je .Lfast /* Zero found -> accept fits in one vreg. */
|
|
Packit Service |
93dc7a |
j .Lslow /* No zero -> accept exceeds one vreg */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lcheck_onbb:
|
|
Packit Service |
93dc7a |
/* Accept lays on block-boundary. */
|
|
Packit Service |
93dc7a |
vfenezb %v18,%v17,%v17 /* Search zero in loaded accept bytes. */
|
|
Packit Service |
93dc7a |
vlgvb %r4,%v18,7 /* Get index of zero or 16 if not found. */
|
|
Packit Service |
93dc7a |
clrjl %r4,%r0,.Lcheck_notonbb /* Zero index < loaded bytes count ->
|
|
Packit Service |
93dc7a |
Accept fits in one vreg;
|
|
Packit Service |
93dc7a |
Fill with zeros and proceed
|
|
Packit Service |
93dc7a |
with FAST. */
|
|
Packit Service |
93dc7a |
vl %v17,0(%r3) /* Load accept, which exceeds loaded bytes. */
|
|
Packit Service |
93dc7a |
j .Lcheck_notonbb /* Check if accept fits in one vreg. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/*
|
|
Packit Service |
93dc7a |
Search s for accept in one vreg
|
|
Packit Service |
93dc7a |
-------------------------------
|
|
Packit Service |
93dc7a |
*/
|
|
Packit Service |
93dc7a |
.Lfast:
|
|
Packit Service |
93dc7a |
/* Complete accept-string in v17 and remaining bytes are zero. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
vlbb %v16,0(%r2),6 /* Load s until next 4k-byte boundary. */
|
|
Packit Service |
93dc7a |
lcbb %r0,0(%r2),6 /* Get bytes to 4k-byte boundary or 16. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
vfaezbs %v18,%v16,%v17,0 /* Find first element in v16 unequal to any
|
|
Packit Service |
93dc7a |
in v17 or first zero element. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
vlgvb %r4,%v18,7 /* Load byte index of found element. */
|
|
Packit Service |
93dc7a |
/* If found index is within loaded bytes, return with found
|
|
Packit Service |
93dc7a |
element index (=equal count). */
|
|
Packit Service |
93dc7a |
clrjl %r4,%r0,.Lfast_loop_found2
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/* Align s to 16 byte. */
|
|
Packit Service |
93dc7a |
risbgn %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */
|
|
Packit Service |
93dc7a |
lghi %r1,16 /* current_len = 16. */
|
|
Packit Service |
93dc7a |
slr %r1,%r4 /* Compute bytes to 16bytes boundary. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/* Process s in 16byte aligned loop. */
|
|
Packit Service |
93dc7a |
.Lfast_loop:
|
|
Packit Service |
93dc7a |
vl %v16,0(%r1,%r2) /* Load search-string. */
|
|
Packit Service |
93dc7a |
vfaezbs %v18,%v16,%v17,0 /* Find first element in v16 equal to any
|
|
Packit Service |
93dc7a |
in v17 or first zero element. */
|
|
Packit Service |
93dc7a |
jno .Lfast_loop_found
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
vl %v16,16(%r1,%r2)
|
|
Packit Service |
93dc7a |
vfaezbs %v18,%v16,%v17,0
|
|
Packit Service |
93dc7a |
jno .Lfast_loop_found16
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
vl %v16,32(%r1,%r2)
|
|
Packit Service |
93dc7a |
vfaezbs %v18,%v16,%v17,0
|
|
Packit Service |
93dc7a |
jno .Lfast_loop_found32
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
vl %v16,48(%r1,%r2)
|
|
Packit Service |
93dc7a |
vfaezbs %v18,%v16,%v17,0
|
|
Packit Service |
93dc7a |
jno .Lfast_loop_found48
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
aghi %r1,64
|
|
Packit Service |
93dc7a |
j .Lfast_loop /* Loop if no element was unequal to accept
|
|
Packit Service |
93dc7a |
and not zero. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/* Found equal or zero element. */
|
|
Packit Service |
93dc7a |
.Lfast_loop_found48:
|
|
Packit Service |
93dc7a |
aghi %r1,16
|
|
Packit Service |
93dc7a |
.Lfast_loop_found32:
|
|
Packit Service |
93dc7a |
aghi %r1,16
|
|
Packit Service |
93dc7a |
.Lfast_loop_found16:
|
|
Packit Service |
93dc7a |
aghi %r1,16
|
|
Packit Service |
93dc7a |
.Lfast_loop_found:
|
|
Packit Service |
93dc7a |
vlgvb %r4,%v18,7 /* Load byte index of found element. */
|
|
Packit Service |
93dc7a |
.Lfast_loop_found2:
|
|
Packit Service |
93dc7a |
vlgvb %r0,%v16,0(%r4) /* Get found element. */
|
|
Packit Service |
93dc7a |
clije %r0,0,.Lfast_end_null /* Return null if no accept-char found */
|
|
Packit Service |
93dc7a |
algfr %r1,%r4 /* Add found index of char to current len. */
|
|
Packit Service |
93dc7a |
la %r2,0(%r1,%r2) /* And return pointer to first equal char. */
|
|
Packit Service |
93dc7a |
br %r14
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lfast_end_null:
|
|
Packit Service |
93dc7a |
lghi %r2,0 /* Return null if no character is equal. */
|
|
Packit Service |
93dc7a |
br %r14
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/*
|
|
Packit Service |
93dc7a |
Search s for accept in multiple vregs
|
|
Packit Service |
93dc7a |
-------------------------------------
|
|
Packit Service |
93dc7a |
*/
|
|
Packit Service |
93dc7a |
.Lslow:
|
|
Packit Service |
93dc7a |
/* Save registers. */
|
|
Packit Service |
93dc7a |
vlvgg %v30,%r6,0
|
|
Packit Service |
93dc7a |
vlvgp %v31,%r8,%r9
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/* accept in v17 without zero. */
|
|
Packit Service |
93dc7a |
vlr %v19,%v17 /* Save first acc-part for a fast reload. */
|
|
Packit Service |
93dc7a |
vzero %v20 /* Zero for preparing acc-vector. */
|
|
Packit Service |
93dc7a |
vone %v24 /* One for checking result of former string. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/* Align s to 16 byte. */
|
|
Packit Service |
93dc7a |
risbg %r4,%r2,60,128+63,0 /* Test if s is aligned and
|
|
Packit Service |
93dc7a |
%r4 = bits 60-63 'and' 15. */
|
|
Packit Service |
93dc7a |
je .Lslow_loop_str /* If s is aligned, loop aligned. */
|
|
Packit Service |
93dc7a |
lghi %r0,15
|
|
Packit Service |
93dc7a |
slr %r0,%r4 /* Compute highest index to load (15-x). */
|
|
Packit Service |
93dc7a |
vll %v16,%r0,0(%r2) /* Load up to 16 byte boundary (vll needs
|
|
Packit Service |
93dc7a |
highest index, remaining bytes are 0). */
|
|
Packit Service |
93dc7a |
ahi %r0,1 /* Work with loaded byte count. */
|
|
Packit Service |
93dc7a |
vzero %v21 /* Zero out global mask. */
|
|
Packit Service |
93dc7a |
lghi %r5,0 /* Set current len of accept-string to zero. */
|
|
Packit Service |
93dc7a |
vfenezb %v18,%v16,%v16 /* Find zero in current string-part. */
|
|
Packit Service |
93dc7a |
lghi %r8,0 /* There is no zero in first accept-part. */
|
|
Packit Service |
93dc7a |
vlgvb %r6,%v18,7 /* Load byte index of zero or 16 if no zero. */
|
|
Packit Service |
93dc7a |
clije %r6,0,.Lslow_end_null /* If first element is zero
|
|
Packit Service |
93dc7a |
(end of string) -> return null */
|
|
Packit Service |
93dc7a |
clr %r0,%r6 /* cc==1 if loaded byte count < zero-index. */
|
|
Packit Service |
93dc7a |
locrl %r6,%r0 /* Load on cc==1; zero-index = lbc. */
|
|
Packit Service |
93dc7a |
j .Lslow_loop_acc
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
/* Process s in 16byte aligned loop. */
|
|
Packit Service |
93dc7a |
.Lslow_next_str:
|
|
Packit Service |
93dc7a |
/* Check results of former processed str-part. */
|
|
Packit Service |
93dc7a |
vfeeb %v18,%v21,%v24 /* Find first equal match in global mask
|
|
Packit Service |
93dc7a |
(ones in element). */
|
|
Packit Service |
93dc7a |
vlgvb %r4,%v18,7 /* Get index of first one (=equal)
|
|
Packit Service |
93dc7a |
or 16 if no match. */
|
|
Packit Service |
93dc7a |
/* Equal-index < min(zero-index, loaded byte count)
|
|
Packit Service |
93dc7a |
-> return pointer to equal element. */
|
|
Packit Service |
93dc7a |
clrjl %r4,%r6,.Lslow_index_found
|
|
Packit Service |
93dc7a |
/* Zero-index < loaded byte count
|
|
Packit Service |
93dc7a |
-> former str-part was last str-part
|
|
Packit Service |
93dc7a |
-> return null */
|
|
Packit Service |
93dc7a |
clrjl %r6,%r0,.Lslow_end_null
|
|
Packit Service |
93dc7a |
/* All elements are zero (=no match) -> proceed with next str-part. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
vlr %v17,%v19 /* Load first part of accept (no zero). */
|
|
Packit Service |
93dc7a |
algfr %r1,%r0 /* Add loaded byte count to current len. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_loop_str:
|
|
Packit Service |
93dc7a |
vl %v16,0(%r1,%r2) /* Load search-string */
|
|
Packit Service |
93dc7a |
lghi %r0,16 /* Loaded byte count is 16. */
|
|
Packit Service |
93dc7a |
vzero %v21 /* Zero out global mask. */
|
|
Packit Service |
93dc7a |
lghi %r5,0 /* Set current len of accept to zero. */
|
|
Packit Service |
93dc7a |
vfenezb %v18,%v16,%v16 /* Find zero in current string-part. */
|
|
Packit Service |
93dc7a |
lghi %r8,0 /* There is no zero in first accept-part. */
|
|
Packit Service |
93dc7a |
vlgvb %r6,%v18,7 /* Load byte index of zero or 16 if no zero. */
|
|
Packit Service |
93dc7a |
clije %r6,0,.Lslow_end_null /* If first element is zero
|
|
Packit Service |
93dc7a |
(end of string) -> return null. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_loop_acc:
|
|
Packit Service |
93dc7a |
vfaeb %v22,%v16,%v17,4 /* Create matching-mask (1 in mask ->
|
|
Packit Service |
93dc7a |
Character matches any accepted character in
|
|
Packit Service |
93dc7a |
this accept-string-part) IN=0, RT=1. */
|
|
Packit Service |
93dc7a |
vlgvb %r4,%v22,0 /* Get result of first element. */
|
|
Packit Service |
93dc7a |
/* First element is equal to any accepted characters
|
|
Packit Service |
93dc7a |
(all other parts of accept cannot lead to a match before this one)
|
|
Packit Service |
93dc7a |
-> current len is pointing to first element
|
|
Packit Service |
93dc7a |
-> return found */
|
|
Packit Service |
93dc7a |
clijh %r4,0,.Lslow_end_found
|
|
Packit Service |
93dc7a |
vo %v21,%v21,%v22 /* Global-mask = global-|matching-mask. */
|
|
Packit Service |
93dc7a |
/* Proceed with next acc until end of acc is reached. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_next_acc:
|
|
Packit Service |
93dc7a |
clijh %r8,0,.Lslow_next_str /* There was a zero in the last acc-part
|
|
Packit Service |
93dc7a |
-> add index to current_len and
|
|
Packit Service |
93dc7a |
end. */
|
|
Packit Service |
93dc7a |
vlbb %v17,16(%r5,%r3),6 /* Load next accept part. */
|
|
Packit Service |
93dc7a |
aghi %r5,16 /* Increment current len of accept-string. */
|
|
Packit Service |
93dc7a |
lcbb %r9,0(%r5,%r3),6 /* Get loaded byte count of accept-string. */
|
|
Packit Service |
93dc7a |
jo .Lslow_next_acc_onbb /* Jump away ifaccept-string is
|
|
Packit Service |
93dc7a |
on block-boundary. */
|
|
Packit Service |
93dc7a |
.Lslow_next_acc_notonbb:
|
|
Packit Service |
93dc7a |
vistrbs %v17,%v17 /* Fill with zeros after first zero. */
|
|
Packit Service |
93dc7a |
jo .Lslow_loop_acc /* No zero found -> no preparation needed. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_next_acc_prepare_zero:
|
|
Packit Service |
93dc7a |
/* Zero in accept-part: fill zeros with first-accept-character. */
|
|
Packit Service |
93dc7a |
vlgvb %r8,%v17,0 /* Load first element of acc-part. */
|
|
Packit Service |
93dc7a |
clije %r8,0,.Lslow_next_str /* Proceed with next string-part,
|
|
Packit Service |
93dc7a |
if first char in this part of accept
|
|
Packit Service |
93dc7a |
is a zero. */
|
|
Packit Service |
93dc7a |
/* r8>0 -> zero found in this acc-part. */
|
|
Packit Service |
93dc7a |
vrepb %v18,%v17,0 /* Replicate first char accross all chars. */
|
|
Packit Service |
93dc7a |
vceqb %v22,%v20,%v17 /* Create a mask (v22) of null chars
|
|
Packit Service |
93dc7a |
by comparing with 0 (v20). */
|
|
Packit Service |
93dc7a |
vsel %v17,%v18,%v17,%v22 /* Replace null chars with first char. */
|
|
Packit Service |
93dc7a |
j .Lslow_loop_acc /* Accept part is prepared -> process. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_next_acc_onbb:
|
|
Packit Service |
93dc7a |
vfenezb %v18,%v17,%v17 /* Find zero in loaded bytes of accept part. */
|
|
Packit Service |
93dc7a |
vlgvb %r8,%v18,7 /* Load byte index of zero. */
|
|
Packit Service |
93dc7a |
clrjl %r8,%r9,.Lslow_next_acc_notonbb /* Found a zero in loaded bytes
|
|
Packit Service |
93dc7a |
-> Prepare vreg. */
|
|
Packit Service |
93dc7a |
vl %v17,0(%r5,%r3) /* Load over boundary ... */
|
|
Packit Service |
93dc7a |
lghi %r8,0 /* r8=0 -> no zero in this part of acc,
|
|
Packit Service |
93dc7a |
check for zero is in jump-target. */
|
|
Packit Service |
93dc7a |
j .Lslow_next_acc_notonbb /* ... and search for zero in
|
|
Packit Service |
93dc7a |
fully loaded vreg again. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_end_null:
|
|
Packit Service |
93dc7a |
lghi %r1,0 /* Return null if no character is equal. */
|
|
Packit Service |
93dc7a |
j .Lslow_end
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_loop_found:
|
|
Packit Service |
93dc7a |
vlgvb %r4,%v18,7 /* Load byte index of found element. */
|
|
Packit Service |
93dc7a |
vlgvb %r0,%v16,0(%r4) /* Get found element. */
|
|
Packit Service |
93dc7a |
clije %r0,0,.Lslow_end_null /* Return null if no acc-char found. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_index_found:
|
|
Packit Service |
93dc7a |
algfr %r1,%r4 /* Add found index of char to current len. */
|
|
Packit Service |
93dc7a |
.Lslow_end_found:
|
|
Packit Service |
93dc7a |
la %r1,0(%r1,%r2) /* And return pointer to first equal char. */
|
|
Packit Service |
93dc7a |
|
|
Packit Service |
93dc7a |
.Lslow_end:
|
|
Packit Service |
93dc7a |
/* Restore registers. */
|
|
Packit Service |
93dc7a |
vlgvg %r6,%v30,0
|
|
Packit Service |
93dc7a |
vlgvg %r8,%v31,0
|
|
Packit Service |
93dc7a |
vlgvg %r9,%v31,1
|
|
Packit Service |
93dc7a |
lgr %r2,%r1
|
|
Packit Service |
93dc7a |
br %r14
|
|
Packit Service |
66f556 |
END(STRPBRK_Z13)
|
|
Packit Service |
66f556 |
|
|
Packit Service |
66f556 |
# if ! HAVE_STRPBRK_IFUNC
|
|
Packit Service |
66f556 |
strong_alias (STRPBRK_Z13, strpbrk)
|
|
Packit Service |
66f556 |
# endif
|
|
Packit Service |
66f556 |
|
|
Packit Service |
66f556 |
# if ! HAVE_STRPBRK_C && defined SHARED && IS_IN (libc)
|
|
Packit Service |
66f556 |
strong_alias (STRPBRK_Z13, __GI_strpbrk)
|
|
Packit Service |
66f556 |
# endif
|
|
Packit Service |
66f556 |
|
|
Packit Service |
66f556 |
#endif /* HAVE_STRPBRK_Z13 */
|