|
Packit |
6c4009 |
/* Vector optimized 32/64 bit S/390 version of strncat.
|
|
Packit |
6c4009 |
Copyright (C) 2015-2018 Free Software Foundation, Inc.
|
|
Packit |
6c4009 |
This file is part of the GNU C Library.
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
The GNU C Library is free software; you can redistribute it and/or
|
|
Packit |
6c4009 |
modify it under the terms of the GNU Lesser General Public
|
|
Packit |
6c4009 |
License as published by the Free Software Foundation; either
|
|
Packit |
6c4009 |
version 2.1 of the License, or (at your option) any later version.
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
The GNU C Library is distributed in the hope that it will be useful,
|
|
Packit |
6c4009 |
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
Packit |
6c4009 |
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Packit |
6c4009 |
Lesser General Public License for more details.
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
You should have received a copy of the GNU Lesser General Public
|
|
Packit |
6c4009 |
License along with the GNU C Library; if not, see
|
|
Packit |
6c4009 |
<http://www.gnu.org/licenses/>. */
|
|
Packit |
6c4009 |
|
|
Packit Bot |
82df69 |
#include <ifunc-strncat.h>
|
|
Packit Bot |
82df69 |
#if HAVE_STRNCAT_Z13
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
# include "sysdep.h"
|
|
Packit |
6c4009 |
# include "asm-syntax.h"
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
.text
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* char * strncat (const char *dest, const char *src, size_t n)
|
|
Packit |
6c4009 |
Concatenate two strings - at most n characters of src.
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
Register usage:
|
|
Packit |
6c4009 |
-r0=saved dest pointer for return
|
|
Packit |
6c4009 |
-r1=tmp
|
|
Packit |
6c4009 |
-r2=dest
|
|
Packit |
6c4009 |
-r3=src
|
|
Packit |
6c4009 |
-r4=n
|
|
Packit |
6c4009 |
-r5=current_len
|
|
Packit |
6c4009 |
-r6=tmp
|
|
Packit |
6c4009 |
-r7=tmp
|
|
Packit |
6c4009 |
-v16=part of src
|
|
Packit |
6c4009 |
-v17=index of zero
|
|
Packit |
6c4009 |
-v18=part of src
|
|
Packit |
6c4009 |
-v31=register save area for r6, r7
|
|
Packit |
6c4009 |
*/
|
|
Packit Bot |
82df69 |
ENTRY(STRNCAT_Z13)
|
|
Packit |
6c4009 |
.machine "z13"
|
|
Packit |
6c4009 |
.machinemode "zarch_nohighgprs"
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
# if !defined __s390x__
|
|
Packit |
6c4009 |
llgfr %r4,%r4
|
|
Packit |
6c4009 |
# endif /* !defined __s390x__ */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
clgfi %r4,0
|
|
Packit |
6c4009 |
ber %r14 /* Nothing to do, if n == 0. */
|
|
Packit |
6c4009 |
lgr %r0,%r2 /* Save destination pointer for return. */
|
|
Packit |
6c4009 |
vlvgp %v31,%r6,%r7 /* Save registers. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* STRLEN
|
|
Packit |
6c4009 |
%r1 = loaded bytes (tmp)
|
|
Packit |
6c4009 |
%r6 = zero byte index (tmp)
|
|
Packit |
6c4009 |
%r2 = dst
|
|
Packit |
6c4009 |
*/
|
|
Packit |
6c4009 |
vlbb %v16,0(%r2),6 /* Load s until next 4k-byte boundary. */
|
|
Packit |
6c4009 |
lcbb %r1,0(%r2),6 /* Get bytes to 4k-byte boundary or 16. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
vfenezb %v16,%v16,%v16 /* Find element not equal with zero search. */
|
|
Packit |
6c4009 |
vlgvb %r5,%v16,7 /* Load zero index or 16 if not found. */
|
|
Packit |
6c4009 |
clrjl %r5,%r1,.Llen_end /* Found zero within loaded bytes, end. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* Align s to 16 byte. */
|
|
Packit |
6c4009 |
risbgn %r1,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */
|
|
Packit |
6c4009 |
lghi %r5,16 /* current_len = 16. */
|
|
Packit |
6c4009 |
slr %r5,%r1 /* Compute bytes to 16bytes boundary. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* Find zero in 16byte aligned loop. */
|
|
Packit |
6c4009 |
.Llen_loop:
|
|
Packit |
6c4009 |
vl %v16,0(%r5,%r2) /* Load s. */
|
|
Packit |
6c4009 |
vfenezbs %v16,%v16,%v16 /* Find element not equal with zero search. */
|
|
Packit |
6c4009 |
je .Llen_found /* Jump away if zero was found. */
|
|
Packit |
6c4009 |
vl %v16,16(%r5,%r2)
|
|
Packit |
6c4009 |
vfenezbs %v16,%v16,%v16
|
|
Packit |
6c4009 |
je .Llen_found16
|
|
Packit |
6c4009 |
vl %v16,32(%r5,%r2)
|
|
Packit |
6c4009 |
vfenezbs %v16,%v16,%v16
|
|
Packit |
6c4009 |
je .Llen_found32
|
|
Packit |
6c4009 |
vl %v16,48(%r5,%r2)
|
|
Packit |
6c4009 |
vfenezbs %v16,%v16,%v16
|
|
Packit |
6c4009 |
je .Llen_found48
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
aghi %r5,64
|
|
Packit |
6c4009 |
j .Llen_loop /* No zero -> loop. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
.Llen_found48:
|
|
Packit |
6c4009 |
aghi %r5,16
|
|
Packit |
6c4009 |
.Llen_found32:
|
|
Packit |
6c4009 |
aghi %r5,16
|
|
Packit |
6c4009 |
.Llen_found16:
|
|
Packit |
6c4009 |
aghi %r5,16
|
|
Packit |
6c4009 |
.Llen_found:
|
|
Packit |
6c4009 |
vlgvb %r1,%v16,7 /* Load byte index of zero. */
|
|
Packit |
6c4009 |
algr %r5,%r1
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
.Llen_end:
|
|
Packit |
6c4009 |
/* STRCPY
|
|
Packit |
6c4009 |
%r1 = zero byte index (tmp)
|
|
Packit |
6c4009 |
%r6 = loaded bytes (tmp)
|
|
Packit |
6c4009 |
%r3 = curr src pointer
|
|
Packit |
6c4009 |
%r2 = curr dst pointer
|
|
Packit |
6c4009 |
%r7 = border, tmp
|
|
Packit |
6c4009 |
*/
|
|
Packit |
6c4009 |
la %r2,0(%r5,%r2) /* strcpy at end of dst-string. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
vlbb %v16,0(%r3),6 /* Load s until next 4k-byte boundary. */
|
|
Packit |
6c4009 |
lcbb %r6,0(%r3),6 /* Get bytes to 4k-byte boundary or 16. */
|
|
Packit |
6c4009 |
llgfr %r6,%r6 /* Convert 32bit to 64bit. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
lghi %r5,0 /* current_len = 0. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
clgrjle %r4,%r6,.Lcpy_remaining_v16 /* If n <= loaded-bytes
|
|
Packit |
6c4009 |
-> process remaining. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* n > loaded-byte-count. */
|
|
Packit |
6c4009 |
vfenezb %v17,%v16,%v16 /* Find element not equal with zero search. */
|
|
Packit |
6c4009 |
vlgvb %r1,%v17,7 /* Load zero index or 16 if not found. */
|
|
Packit |
6c4009 |
clrjl %r1,%r6,.Lcpy_found_v16_store /* Found zero within loaded
|
|
Packit |
6c4009 |
bytes, copy and return. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* Align s to 16 byte. */
|
|
Packit |
6c4009 |
risbgn %r7,%r3,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */
|
|
Packit |
6c4009 |
lghi %r5,15 /* current_len = 15. */
|
|
Packit |
6c4009 |
slr %r5,%r7 /* Compute highest index to 16byte boundary. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* Zero not found and n > loaded-byte-count. */
|
|
Packit |
6c4009 |
vstl %v16,%r5,0(%r2) /* Copy loaded characters - no zero. */
|
|
Packit |
6c4009 |
ahi %r5,1 /* Start loop at next character. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/*
|
|
Packit |
6c4009 |
Now we are 16byte aligned, so we can load a full vreg
|
|
Packit |
6c4009 |
without page fault.
|
|
Packit |
6c4009 |
*/
|
|
Packit |
6c4009 |
lgr %r1,%r5 /* If %r5 + 64 < maxlen? -> loop64. */
|
|
Packit |
6c4009 |
aghi %r1,64
|
|
Packit |
6c4009 |
clgrjl %r1,%r4,.Lcpy_loop64
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
vl %v16,0(%r5,%r3) /* Load s. */
|
|
Packit |
6c4009 |
clgijl %r4,17,.Lcpy_remaining_v16 /* If n <=16,
|
|
Packit |
6c4009 |
process remaining bytes. */
|
|
Packit |
6c4009 |
.Lcpy_lt64:
|
|
Packit |
6c4009 |
lgr %r7,%r4
|
|
Packit |
6c4009 |
slgfi %r7,16 /* border_len = n - 16. */
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* If current_len >= border then process remaining bytes. */
|
|
Packit |
6c4009 |
clgrjhe %r5,%r7,.Lcpy_remaining_v16
|
|
Packit |
6c4009 |
vfenezbs %v17,%v16,%v16 /* Find element not equal with zero search. */
|
|
Packit |
6c4009 |
je .Lcpy_found_v16 /* Jump away if zero was found. */
|
|
Packit |
6c4009 |
vl %v18,16(%r5,%r3) /* Load next part of s. */
|
|
Packit |
6c4009 |
vst %v16,0(%r5,%r2) /* Store previous part without zero to dst. */
|
|
Packit |
6c4009 |
aghi %r5,16
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
clgrjhe %r5,%r7,.Lcpy_remaining_v18
|
|
Packit |
6c4009 |
vfenezbs %v17,%v18,%v18
|
|
Packit |
6c4009 |
je .Lcpy_found_v18
|
|
Packit |
6c4009 |
vl %v16,16(%r5,%r3)
|
|
Packit |
6c4009 |
vst %v18,0(%r5,%r2)
|
|
Packit |
6c4009 |
aghi %r5,16
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
clgrjhe %r5,%r7,.Lcpy_remaining_v16
|
|
Packit |
6c4009 |
vfenezbs %v17,%v16,%v16
|
|
Packit |
6c4009 |
je .Lcpy_found_v16
|
|
Packit |
6c4009 |
vl %v18,16(%r5,%r3)
|
|
Packit |
6c4009 |
vst %v16,0(%r5,%r2)
|
|
Packit |
6c4009 |
aghi %r5,16
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
.Lcpy_remaining_v18:
|
|
Packit |
6c4009 |
vlr %v16,%v18
|
|
Packit |
6c4009 |
.Lcpy_remaining_v16:
|
|
Packit |
6c4009 |
/* v16 contains the remaining bytes [1...16].
|
|
Packit |
6c4009 |
Store remaining bytes and append string-termination. */
|
|
Packit |
6c4009 |
vfenezb %v17,%v16,%v16 /* Find element not equal with zero search. */
|
|
Packit |
6c4009 |
slgrk %r7,%r4,%r5 /* Remaining bytes = maxlen - current_len. */
|
|
Packit |
6c4009 |
aghi %r7,-1 /* vstl needs highest index. */
|
|
Packit |
6c4009 |
vlgvb %r1,%v17,7 /* Load zero index or 16 if not found. */
|
|
Packit |
6c4009 |
la %r2,0(%r5,%r2) /* vstl has no index register. */
|
|
Packit |
6c4009 |
/* Zero-index within remaining-bytes, store up to zero and end. */
|
|
Packit |
6c4009 |
clgrjle %r1,%r7,.Lcpy_found_v16_store
|
|
Packit |
6c4009 |
vstl %v16,%r7,0(%r2) /* Store remaining bytes. */
|
|
Packit |
6c4009 |
lghi %r1,0
|
|
Packit |
6c4009 |
stc %r1,1(%r7,%r2) /* Store string-null-termination beyond n. */
|
|
Packit |
6c4009 |
.Lcpy_end:
|
|
Packit |
6c4009 |
/* Restore saved registers. */
|
|
Packit |
6c4009 |
vlgvg %r6,%v31,0
|
|
Packit |
6c4009 |
vlgvg %r7,%v31,1
|
|
Packit |
6c4009 |
lgr %r2,%r0 /* Load saved dest-ptr. */
|
|
Packit |
6c4009 |
br %r14
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
.Lcpy_found_v16_32:
|
|
Packit |
6c4009 |
aghi %r5,32
|
|
Packit |
6c4009 |
j .Lcpy_found_v16
|
|
Packit |
6c4009 |
.Lcpy_found_v18_48:
|
|
Packit |
6c4009 |
aghi %r5,32
|
|
Packit |
6c4009 |
.Lcpy_found_v18_16:
|
|
Packit |
6c4009 |
aghi %r5,16
|
|
Packit |
6c4009 |
.Lcpy_found_v18:
|
|
Packit |
6c4009 |
vlr %v16,%v18
|
|
Packit |
6c4009 |
.Lcpy_found_v16:
|
|
Packit |
6c4009 |
/* v16 contains a zero. Store remaining bytes to zero. current_len
|
|
Packit |
6c4009 |
has not reached border, thus checking for n is not needed! */
|
|
Packit |
6c4009 |
vlgvb %r1,%v17,7 /* Load byte index of zero. */
|
|
Packit |
6c4009 |
la %r2,0(%r5,%r2)
|
|
Packit |
6c4009 |
.Lcpy_found_v16_store:
|
|
Packit |
6c4009 |
vstl %v16,%r1,0(%r2) /* Copy characters including zero. */
|
|
Packit |
6c4009 |
j .Lcpy_end
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
/* Find zero in 16byte aligned loop. */
|
|
Packit |
6c4009 |
.Lcpy_loop64:
|
|
Packit |
6c4009 |
vl %v16,0(%r5,%r3) /* Load s. */
|
|
Packit |
6c4009 |
vfenezbs %v17,%v16,%v16 /* Find element not equal with zero search. */
|
|
Packit |
6c4009 |
je .Lcpy_found_v16 /* Jump away if zero was found. */
|
|
Packit |
6c4009 |
vl %v18,16(%r5,%r3) /* Load next part of s. */
|
|
Packit |
6c4009 |
vst %v16,0(%r5,%r2) /* Store previous part without zero to dst. */
|
|
Packit |
6c4009 |
vfenezbs %v17,%v18,%v18
|
|
Packit |
6c4009 |
je .Lcpy_found_v18_16
|
|
Packit |
6c4009 |
vl %v16,32(%r5,%r3)
|
|
Packit |
6c4009 |
vst %v18,16(%r5,%r2)
|
|
Packit |
6c4009 |
vfenezbs %v17,%v16,%v16
|
|
Packit |
6c4009 |
je .Lcpy_found_v16_32
|
|
Packit |
6c4009 |
vl %v18,48(%r5,%r3)
|
|
Packit |
6c4009 |
vst %v16,32(%r5,%r2)
|
|
Packit |
6c4009 |
vfenezbs %v17,%v18,%v18
|
|
Packit |
6c4009 |
je .Lcpy_found_v18_48
|
|
Packit |
6c4009 |
vst %v18,48(%r5,%r2)
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
aghi %r5,64
|
|
Packit |
6c4009 |
lgr %r1,%r5 /* If %r5 + 64 < maxlen? -> loop64. */
|
|
Packit |
6c4009 |
aghi %r1,64
|
|
Packit |
6c4009 |
clgrjl %r1,%r4,.Lcpy_loop64
|
|
Packit |
6c4009 |
|
|
Packit |
6c4009 |
vl %v16,0(%r5,%r3) /* Load s. */
|
|
Packit |
6c4009 |
j .Lcpy_lt64
|
|
Packit Bot |
82df69 |
END(STRNCAT_Z13)
|
|
Packit Bot |
82df69 |
|
|
Packit Bot |
82df69 |
# if ! HAVE_STRNCAT_IFUNC
|
|
Packit Bot |
82df69 |
strong_alias (STRNCAT_Z13, strncat)
|
|
Packit Bot |
82df69 |
# endif
|
|
Packit Bot |
82df69 |
|
|
Packit Bot |
82df69 |
# if ! HAVE_STRNCAT_C
|
|
Packit Bot |
82df69 |
/* See string/strncat.c and define STRNCAT_PRIMARY. */
|
|
Packit Bot |
82df69 |
strong_alias (STRNCAT_Z13, __strncat)
|
|
Packit Bot |
82df69 |
# if defined SHARED && IS_IN (libc)
|
|
Packit Bot |
82df69 |
strong_alias (__strncat, __GI___strncat)
|
|
Packit Bot |
82df69 |
# endif
|
|
Packit Bot |
82df69 |
# endif
|
|
Packit Bot |
82df69 |
#endif
|