|
Packit Service |
8bbac7 |
/* Vector Optimized 32/64 bit S/390 version of wmemset.
|
|
Packit Service |
8bbac7 |
Copyright (C) 2015-2018 Free Software Foundation, Inc.
|
|
Packit Service |
8bbac7 |
This file is part of the GNU C Library.
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
The GNU C Library is free software; you can redistribute it and/or
|
|
Packit Service |
8bbac7 |
modify it under the terms of the GNU Lesser General Public
|
|
Packit Service |
8bbac7 |
License as published by the Free Software Foundation; either
|
|
Packit Service |
8bbac7 |
version 2.1 of the License, or (at your option) any later version.
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
The GNU C Library is distributed in the hope that it will be useful,
|
|
Packit Service |
8bbac7 |
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
Packit Service |
8bbac7 |
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Packit Service |
8bbac7 |
Lesser General Public License for more details.
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
You should have received a copy of the GNU Lesser General Public
|
|
Packit Service |
8bbac7 |
License along with the GNU C Library; if not, see
|
|
Packit Service |
8bbac7 |
<http://www.gnu.org/licenses/>. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
#if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
# include "sysdep.h"
|
|
Packit Service |
8bbac7 |
# include "asm-syntax.h"
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.text
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
/* wchar_t *wmemset(wchar_t *dest, wchar_t wc, size_t n)
|
|
Packit Service |
8bbac7 |
Fill an array of wide-characters with a constant wide character
|
|
Packit Service |
8bbac7 |
and returns dest.
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
Register usage:
|
|
Packit Service |
8bbac7 |
-r0=tmp
|
|
Packit Service |
8bbac7 |
-r1=tmp
|
|
Packit Service |
8bbac7 |
-r2=dest or current-pointer
|
|
Packit Service |
8bbac7 |
-r3=wc
|
|
Packit Service |
8bbac7 |
-r4=n
|
|
Packit Service |
8bbac7 |
-r5=tmp
|
|
Packit Service |
8bbac7 |
-v16=replicated wc
|
|
Packit Service |
8bbac7 |
-v17,v18,v19=copy of v16 for vstm
|
|
Packit Service |
8bbac7 |
-v31=saved dest for return
|
|
Packit Service |
8bbac7 |
*/
|
|
Packit Service |
8bbac7 |
ENTRY(__wmemset_vx)
|
|
Packit Service |
8bbac7 |
.machine "z13"
|
|
Packit Service |
8bbac7 |
.machinemode "zarch_nohighgprs"
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
# if !defined __s390x__
|
|
Packit Service |
8bbac7 |
llgfr %r4,%r4
|
|
Packit Service |
8bbac7 |
# endif /* !defined __s390x__ */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
vlvgg %v31,%r2,0 /* Save destination pointer for return. */
|
|
Packit Service |
8bbac7 |
clgije %r4,0,.Lend
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
vlvgf %v16,%r3,0 /* Generate vector with wchar_t wc. */
|
|
Packit Service |
8bbac7 |
vrepf %v16,%v16,0
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
/* Check range of maxlen and convert to byte-count. */
|
|
Packit Service |
8bbac7 |
# ifdef __s390x__
|
|
Packit Service |
8bbac7 |
tmhh %r4,49152 /* Test bit 0 or 1 of maxlen. */
|
|
Packit Service |
8bbac7 |
lghi %r5,-4 /* Max byte-count is 18446744073709551612. */
|
|
Packit Service |
8bbac7 |
# else
|
|
Packit Service |
8bbac7 |
tmlh %r4,49152 /* Test bit 0 or 1 of maxlen. */
|
|
Packit Service |
8bbac7 |
llilf %r5,4294967292 /* Max byte-count is 4294967292. */
|
|
Packit Service |
8bbac7 |
# endif /* !__s390x__ */
|
|
Packit Service |
8bbac7 |
sllg %r4,%r4,2 /* Convert character-count to byte-count. */
|
|
Packit Service |
8bbac7 |
locgrne %r4,%r5 /* Use max byte-count, if bit 0/1 was one. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
/* Align dest to 16 byte. */
|
|
Packit Service |
8bbac7 |
risbg %r0,%r2,60,128+63,0 /* Test if s is aligned and
|
|
Packit Service |
8bbac7 |
%r3 = bits 60-63 'and' 15. */
|
|
Packit Service |
8bbac7 |
je .Lpreloop /* If s is aligned, loop aligned. */
|
|
Packit Service |
8bbac7 |
tmll %r2,3 /* Test if s is 4-byte aligned? */
|
|
Packit Service |
8bbac7 |
jne .Lfallback /* And use common-code variant if not. */
|
|
Packit Service |
8bbac7 |
lghi %r1,16
|
|
Packit Service |
8bbac7 |
slr %r1,%r0 /* Compute byte count to load (16-x). */
|
|
Packit Service |
8bbac7 |
clgr %r1,%r4
|
|
Packit Service |
8bbac7 |
locgrh %r1,%r4 /* min (byte count, n) */
|
|
Packit Service |
8bbac7 |
aghik %r5,%r1,-1 /* vstl needs highest index. */
|
|
Packit Service |
8bbac7 |
vstl %v16,%r5,0(%r2) /* Store remaining bytes. */
|
|
Packit Service |
8bbac7 |
clgrje %r1,%r4,.Lend /* Return if n bytes where set. */
|
|
Packit Service |
8bbac7 |
slgr %r4,%r1 /* Compute remaining byte count. */
|
|
Packit Service |
8bbac7 |
la %r2,0(%r1,%r2)
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lpreloop:
|
|
Packit Service |
8bbac7 |
/* Now we are 16-byte aligned. */
|
|
Packit Service |
8bbac7 |
clgijl %r4,17,.Lremaining
|
|
Packit Service |
8bbac7 |
srlg %r1,%r4,8 /* Split into 256byte blocks */
|
|
Packit Service |
8bbac7 |
clgije %r1,0,.Lpreloop64
|
|
Packit Service |
8bbac7 |
vlr %v17,%v16
|
|
Packit Service |
8bbac7 |
vlr %v18,%v16
|
|
Packit Service |
8bbac7 |
vlr %v19,%v16
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lloop256:
|
|
Packit Service |
8bbac7 |
vstm %v16,%v19,0(%r2)
|
|
Packit Service |
8bbac7 |
vstm %v16,%v19,64(%r2)
|
|
Packit Service |
8bbac7 |
vstm %v16,%v19,128(%r2)
|
|
Packit Service |
8bbac7 |
vstm %v16,%v19,192(%r2)
|
|
Packit Service |
8bbac7 |
la %r2,256(%r2)
|
|
Packit Service |
8bbac7 |
brctg %r1,.Lloop256 /* Loop until all blocks are processed. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
llgfr %r4,%r4
|
|
Packit Service |
8bbac7 |
nilf %r4,255 /* Get remaining bytes */
|
|
Packit Service |
8bbac7 |
je .Lend /* Skip store remaining bytes if zero. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lpreloop64:
|
|
Packit Service |
8bbac7 |
clgijl %r4,17,.Lremaining
|
|
Packit Service |
8bbac7 |
clgijl %r4,33,.Lpreloop16
|
|
Packit Service |
8bbac7 |
srlg %r1,%r4,5 /* Split into 32byte blocks */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lloop32:
|
|
Packit Service |
8bbac7 |
vst %v16,0(%r2)
|
|
Packit Service |
8bbac7 |
vst %v16,16(%r2)
|
|
Packit Service |
8bbac7 |
la %r2,32(%r2)
|
|
Packit Service |
8bbac7 |
brctg %r1,.Lloop32 /* Loop until all blocks are processed. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
llgfr %r4,%r4
|
|
Packit Service |
8bbac7 |
nilf %r4,31 /* Get remaining bytes */
|
|
Packit Service |
8bbac7 |
je .Lend /* Skip store remaining bytes if zero. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lpreloop16:
|
|
Packit Service |
8bbac7 |
clgijl %r4,17,.Lremaining
|
|
Packit Service |
8bbac7 |
srlg %r1,%r4,4 /* Split into 16byte blocks */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lloop16:
|
|
Packit Service |
8bbac7 |
vst %v16,0(%r2)
|
|
Packit Service |
8bbac7 |
la %r2,16(%r2)
|
|
Packit Service |
8bbac7 |
brctg %r1,.Lloop16 /* Loop until all blocks are processed. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
llgfr %r4,%r4
|
|
Packit Service |
8bbac7 |
nilf %r4,15 /* Get remaining bytes */
|
|
Packit Service |
8bbac7 |
je .Lend /* Skip store remaining bytes if zero. */
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lremaining:
|
|
Packit Service |
8bbac7 |
aghi %r4,-1 /* vstl needs highest index. */
|
|
Packit Service |
8bbac7 |
vstl %v16,%r4,0(%r2)
|
|
Packit Service |
8bbac7 |
|
|
Packit Service |
8bbac7 |
.Lend:
|
|
Packit Service |
8bbac7 |
vlgvg %r2,%v31,0 /* Load saved dest for return value. */
|
|
Packit Service |
8bbac7 |
br %r14
|
|
Packit Service |
8bbac7 |
.Lfallback:
|
|
Packit Service |
8bbac7 |
srlg %r4,%r4,2 /* Convert byte-count to character-count. */
|
|
Packit Service |
8bbac7 |
jg __wmemset_c
|
|
Packit Service |
8bbac7 |
END(__wmemset_vx)
|
|
Packit Service |
8bbac7 |
#endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */
|