project('glib', 'c', 'cpp',

  version : '2.56.4',

  meson_version : '>= 0.44.0',

  default_options : [

    'warning_level=1',

    'c_std=gnu89'

  ]

)

cc = meson.get_compiler('c')

cxx = meson.get_compiler('cpp')

if cc.get_id() == 'msvc'

  # Ignore several spurious warnings for things glib does very commonly

  # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it

  # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once

  # NOTE: Only add warnings here if you are sure they're spurious

  add_project_arguments('/wd4035', '/wd4715', '/wd4116',

    '/wd4046', '/wd4068', '/wo4090', '/FImsvc_recommended_pragmas.h',language : 'c')

  # Disable SAFESEH with MSVC for plugins and libs that use external deps that

  # are built with MinGW

  noseh_link_args = ['/SAFESEH:NO']

else

  noseh_link_args = []

  # -mms-bitfields vs -fnative-struct ?

endif

host_system = host_machine.system()

glib_version = meson.project_version()

glib_api_version = '2.0'

version_arr = glib_version.split('.')

major_version = version_arr[0].to_int()

minor_version = version_arr[1].to_int()

micro_version = version_arr[2].to_int()

interface_age = minor_version.is_odd() ? 0 : micro_version

binary_age = 100 * minor_version + micro_version

soversion = 0

# Maintain compatibility with previous libtool versioning

# current = minor * 100 + micro

library_version = '@0@.@1@.@2@'.format(soversion, binary_age - interface_age, interface_age)

configinc = include_directories('.')

glibinc = include_directories('glib')

gobjectinc = include_directories('gobject')

gmoduleinc = include_directories('gmodule')

gioinc = include_directories('gio')

glib_prefix = get_option('prefix')

glib_bindir = join_paths(glib_prefix, get_option('bindir'))

glib_libdir = join_paths(glib_prefix, get_option('libdir'))

glib_datadir = join_paths(glib_prefix, get_option('datadir'))

glib_pkgdatadir = join_paths(glib_datadir, 'glib-2.0')

glib_includedir = join_paths(glib_prefix, get_option('includedir'))

glib_giomodulesdir = get_option('gio_module_dir')

if glib_giomodulesdir == ''

  glib_giomodulesdir = join_paths(glib_libdir, 'gio', 'modules')

endif

glib_pkgconfigreldir = join_paths(glib_libdir, 'pkgconfig')

add_project_arguments('-D_GNU_SOURCE', language: 'c')

# Disable strict aliasing;

# see https://bugzilla.gnome.org/show_bug.cgi?id=791622

if cc.has_argument('-fno-strict-aliasing')

  add_project_arguments('-fno-strict-aliasing', language: 'c')

endif

########################

# Configuration begins #

########################

glib_conf = configuration_data()

glibconfig_conf = configuration_data()

# accumulated list of defines as we check for them, so we can easily

# use them later in test programs (autoconf does this automatically)

glib_conf_prefix = ''

glib_conf.set('GLIB_VERSION', glib_version)

glib_conf.set('GLIB_MAJOR_VERSION', major_version)

glib_conf.set('GLIB_MINOR_VERSION', minor_version)

glib_conf.set('GLIB_MICRO_VERSION', micro_version)

glib_conf.set('GLIB_INTERFACE_AGE', interface_age)

glib_conf.set('GLIB_BINARY_AGE', binary_age)

glib_conf.set_quoted('GETTEXT_PACKAGE', 'glib20')

glib_conf.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=glib')

glib_conf.set_quoted('PACKAGE_NAME', 'glib')

glib_conf.set_quoted('PACKAGE_STRING', 'glib @0@'.format(meson.project_version()))

glib_conf.set_quoted('PACKAGE_TARNAME', 'glib')

glib_conf.set_quoted('PACKAGE_URL', '')

glib_conf.set_quoted('PACKAGE_VERSION', meson.project_version())

glib_conf.set('ENABLE_NLS', 1)

# Variables used in glib-gettextize and pkg-config files

# These should not contain " quotes around the values

glib_conf.set('PACKAGE', 'glib')

glib_conf.set('VERSION', meson.project_version())

glib_conf.set('prefix', glib_prefix)

glib_conf.set('exec_prefix', glib_prefix)

glib_conf.set('libdir', glib_libdir)

glib_conf.set('includedir', glib_includedir)

glib_conf.set('datadir', glib_datadir)

glib_conf.set('datarootdir', glib_datadir)

glib_conf.set('_GNU_SOURCE', 1)

if host_system == 'windows'

  # Poll doesn't work on devices on Windows

  glib_conf.set('BROKEN_POLL', true)

endif

# Detect and set symbol visibility

glib_hidden_visibility_args = []

if get_option('default_library') != 'static'

  if host_system == 'windows'

    glib_conf.set('DLL_EXPORT', true)

    if cc.get_id() == 'msvc'

      glib_conf.set('_GLIB_EXTERN', '__declspec(dllexport) extern')

    elif cc.has_argument('-fvisibility=hidden')

      glib_conf.set('_GLIB_EXTERN', '__attribute__((visibility("default"))) __declspec(dllexport) extern')

      glib_hidden_visibility_args = ['-fvisibility=hidden']

    endif

  elif cc.has_argument('-fvisibility=hidden')

    glib_conf.set('_GLIB_EXTERN', '__attribute__((visibility("default"))) extern')

    glib_hidden_visibility_args = ['-fvisibility=hidden']

  endif

endif

if host_system == 'windows' and get_option('default_library') == 'static'

    glibconfig_conf.set('GLIB_STATIC_COMPILATION', '1')

    glibconfig_conf.set('GOBJECT_STATIC_COMPILATION', '1')

endif

# FIXME: what about Cygwin (G_WITH_CYGWIN)

if host_system == 'windows'

  glib_os = '''#define G_OS_WIN32

#define G_PLATFORM_WIN32'''

else

  glib_os = '#define G_OS_UNIX'

endif

glibconfig_conf.set('glib_os', glib_os)

# We need to know the build type to determine what .lib files we need on Visual Studio

# for dependencies that don't normally come with pkg-config files for Visual Studio builds

buildtype = get_option('buildtype')

# check for header files

headers = [

  'stdlib.h',

  'string.h',

  'strings.h',

  'memory.h',

  'alloca.h',

  'locale.h',

  'xlocale.h',

  'float.h',

  'limits.h',

  'pwd.h',

  'grp.h',

  'poll.h',

  'termios.h',

  'sys/param.h',

  'sys/resource.h',

  'mach/mach_time.h',

  'sys/select.h',

  'stdint.h',

  'inttypes.h',

  'sched.h',

  'malloc.h',

  'sys/vfs.h',

  'sys/vmount.h',

  'sys/statfs.h',

  'sys/statvfs.h',

  'sys/filio.h',

  'mntent.h',

  'sys/mnttab.h',

  'sys/vfstab.h',

  'sys/mntctl.h',

  'fstab.h',

  'linux/magic.h',

  'termios.h',

  'dirent.h', # MSC does not come with this by default

  'sys/time.h', # MSC does not come with this by default

  'sys/times.h',

  'sys/wait.h',

  'unistd.h',

  'values.h',

  'sys/types.h',

  'sys/uio.h',

  'sys/mkdev.h',

  'sys/mount.h',

  'sys/sysctl.h',

  'crt_externs.h',

  'sys/inotify.h',

  'sys/event.h',

  'sys/stat.h',

]

foreach h : headers

  if cc.has_header(h)

    define = 'HAVE_' + h.underscorify().to_upper()

    glib_conf.set(define, 1)

    glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)

  endif

endforeach

if cc.has_header('linux/netlink.h')

  glib_conf.set('HAVE_NETLINK', 1)

endif

if glib_conf.has('HAVE_LOCALE_H')

  if cc.has_header_symbol('locale.h', 'LC_MESSAGES')

    glib_conf.set('HAVE_LC_MESSAGES', 1)

  endif

endif

struct_stat_blkprefix = '''

#include <sys/types.h>

#include <sys/stat.h>

#ifdef HAVE_UNISTD_H

#include <unistd.h>

#endif

#ifdef HAVE_SYS_STATFS_H

#include <sys/statfs.h>

#endif

#ifdef HAVE_SYS_PARAM_H

#include <sys/param.h>

#endif

#ifdef HAVE_SYS_MOUNT_H

#include <sys/mount.h>

#endif

'''

struct_members = [

  [ 'stat', 'st_mtimensec' ],

  [ 'stat', 'st_mtim.tv_nsec' ],

  [ 'stat', 'st_atimensec' ],

  [ 'stat', 'st_atim.tv_nsec' ],

  [ 'stat', 'st_ctimensec' ],

  [ 'stat', 'st_ctim.tv_nsec' ],

  [ 'stat', 'st_birthtime' ],

  [ 'stat', 'st_birthtimensec' ],

  [ 'stat', 'st_birthtim' ],

  [ 'stat', 'st_birthtim.tv_nsec' ],

  [ 'stat', 'st_blksize', struct_stat_blkprefix ],

  [ 'stat', 'st_blocks', struct_stat_blkprefix ],

  [ 'statfs', 'f_fstypename', struct_stat_blkprefix ],

  [ 'statfs', 'f_bavail', struct_stat_blkprefix ],

  [ 'dirent', 'd_type', '''#include <sys/types.h>

                           #include <dirent.h>''' ],

]

foreach m : struct_members

  header_check_prefix = glib_conf_prefix

  if m.length() == 3

    header_check_prefix = header_check_prefix + m[2]

  else

    header_check_prefix = header_check_prefix + '#include <sys/stat.h>'

  endif

  if cc.has_member('struct ' + m[0], m[1], prefix : header_check_prefix)

    define = 'HAVE_STRUCT_@0@_@1@'.format(m[0].to_upper(), m[1].underscorify().to_upper())

    glib_conf.set(define, 1)

    glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)

  else

  endif

endforeach

# Compiler flags

if cc.get_id() == 'gcc' or cc.get_id() == 'clang'

  test_c_args = [

    '-Wall',

    '-Wduplicated-branches',

    '-Wstrict-prototypes',

    '-Werror=declaration-after-statement',

    '-Werror=format=2',

    '-Werror=format-security',

    '-Werror=implicit-function-declaration',

    '-Werror=init-self',

    '-Werror=missing-include-dirs',

    '-Werror=missing-prototypes',

    '-Werror=pointer-arith',

  ]

else

  test_c_args = []

endif

add_project_arguments(cc.get_supported_arguments(test_c_args), language: 'c')

# Windows Support (Vista+)

if host_system == 'windows'

  glib_conf.set('_WIN32_WINNT', '0x0601')

endif

functions = [

  'alloca',

  'mmap',

  'posix_memalign',

  'memalign',

  'valloc',

  'fsync',

  'pipe2',

  'issetugid',

  'timegm',

  'gmtime_r',

  'strerror_r',

  'lstat',

  'strsignal',

  'vsnprintf',

  'stpcpy',

  'poll',

  'vasprintf',

  'setenv',

  'unsetenv',

  'getc_unlocked',

  'readlink',

  'symlink',

  'fdwalk',

  'lchmod',

  'lchown',

  'fchmod',

  'fchown',

  'utimes',

  'getresuid',

  'getmntent_r',

  'setmntent',

  'endmntent',

  'hasmntopt',

  'getfsstat',

  'getvfsstat',

  'fallocate',

  'localtime_r',

  'gmtime_r',

  'getpwuid_r',

  'getgrgid_r',

  'prlimit',

  'strnlen',

  'wcslen',

  'wcsnlen',

  'mbrtowc',

  'wcrtomb',

  'newlocale',

  'uselocale',

  'strtod_l',

  'strtoll_l',

  'strtoull_l',

  'inotify_init1',

  'kqueue',

  'kevent',

  'endservent',

  'sendmmsg',

  'recvmmsg',

  'link',

]

if glib_conf.has('HAVE_SYS_STATVFS_H')

  functions += ['statvfs']

else

  have_func_statvfs = false

endif

if glib_conf.has('HAVE_SYS_STATFS_H') or glib_conf.has('HAVE_SYS_MOUNT_H')

  functions += ['statfs']

else

  have_func_statfs = false

endif

if host_system == 'windows'

  iphlpapi_dep = cc.find_library('iphlpapi')

  iphlpapi_funcs = ['if_nametoindex', 'if_indextoname']

  foreach ifunc : iphlpapi_funcs

    if cc.has_function(ifunc,

                       prefix : '#define _WIN32_WINNT 0x0601\n#include <winsock2.h>\n#include <iphlpapi.h>',

                       dependencies : iphlpapi_dep)

      idefine = 'HAVE_' + ifunc.underscorify().to_upper()

      glib_conf.set(idefine, 1)

      glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(idefine)

      set_variable('have_func_' + ifunc, true)

    else

      set_variable('have_func_' + ifunc, false)

    endif

  endforeach

else

  functions += ['if_indextoname', 'if_nametoindex']

endif

# AIX splice is something else

if host_system != 'aix'

  functions += ['splice']

endif

foreach f : functions

  if cc.has_function(f)

    define = 'HAVE_' + f.underscorify().to_upper()

    glib_conf.set(define, 1)

    glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)

    set_variable('have_func_' + f, true)

  else

    set_variable('have_func_' + f, false)

  endif

endforeach

# Check whether strerror_r returns char *

if have_func_strerror_r

  if cc.compiles('''#define _GNU_SOURCE

                    #include <string.h>

                    int func (void) {

                      char error_string[256];

                      char *ptr = strerror_r (-2, error_string, 256);

                      char c = *strerror_r (-2, error_string, 256);

                      return c != 0 && ptr != (void*) 0L;

                    }

                 ''',

                 name : 'strerror_r() returns char *')

    glib_conf.set('STRERROR_R_CHAR_P', 1,

                  description: 'Defined if strerror_r returns char *')

  endif

endif

# Special-case these functions that have alternative names on Windows/MSVC

if cc.has_function('snprintf') or cc.has_header_symbol('stdio.h', 'snprintf')

  glib_conf.set('HAVE_SNPRINTF', 1)

  glib_conf_prefix = glib_conf_prefix + '#define HAVE_SNPRINTF 1\n'

elif cc.has_function('_snprintf') or cc.has_header_symbol('stdio.h', '_snprintf')

  hack_define = '1\n#define snprintf _snprintf'

  glib_conf.set('HAVE_SNPRINTF', hack_define)

  glib_conf_prefix = glib_conf_prefix + '#define HAVE_SNPRINTF ' + hack_define

endif

if cc.has_function('strcasecmp')

  glib_conf.set('HAVE_STRCASECMP', 1)

  glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRCASECMP 1\n'

elif cc.has_function('_stricmp')

  hack_define = '1\n#define strcasecmp _stricmp'

  glib_conf.set('HAVE_STRCASECMP', hack_define)

  glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRCASECMP ' + hack_define

endif

if cc.has_function('strncasecmp')

  glib_conf.set('HAVE_STRNCASECMP', 1)

  glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRNCASECMP 1\n'

elif cc.has_function('_strnicmp')

  hack_define = '1\n#define strncasecmp _strnicmp'

  glib_conf.set('HAVE_STRNCASECMP', hack_define)

  glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRNCASECMP ' + hack_define

endif

if cc.has_header_symbol('sys/sysmacros.h', 'major')

  glib_conf.set('MAJOR_IN_SYSMACROS', 1)

elif cc.has_header_symbol('sys/mkdev.h', 'major')

  glib_conf.set('MAJOR_IN_MKDEV', 1)

endif

if cc.has_header_symbol('dlfcn.h', 'RTLD_LAZY')

  glib_conf.set('HAVE_RTLD_LAZY', 1)

endif

if cc.has_header_symbol('dlfcn.h', 'RTLD_NOW')

  glib_conf.set('HAVE_RTLD_NOW', 1)

endif

if cc.has_header_symbol('dlfcn.h', 'RTLD_GLOBAL')

  glib_conf.set('HAVE_RTLD_GLOBAL', 1)

endif

# Check whether to use statfs or statvfs

# Some systems have both statfs and statvfs, pick the most "native" for these

if have_func_statfs and have_func_statvfs

  # on solaris and irix, statfs doesn't even have the f_bavail field

  if not glib_conf.has('HAVE_STRUCT_STATFS_F_BAVAIL')

    have_func_statfs = false

  else

    # at least on linux, statfs is the actual syscall

    have_func_statvfs = false

  endif

endif

if have_func_statfs

  glib_conf.set('USE_STATFS', 1)

  stat_func_to_use = 'statfs'

elif have_func_statvfs

  glib_conf.set('USE_STATVFS', 1)

  stat_func_to_use = 'statvfs'

else

  stat_func_to_use = 'neither'

endif

message('Checking whether to use statfs or statvfs .. ' + stat_func_to_use)

if host_system == 'linux'

  if cc.has_function('mkostemp',

                     prefix: '''#define _GNU_SOURCE

                                #include <stdlib.h>''')

    glib_conf.set('HAVE_MKOSTEMP', 1)

  endif

endif

platform_ldflags=[]

# Mac OS X Carbon support

glib_have_carbon = cc.compiles('''#include <Carbon/Carbon.h>

                                  #include <CoreServices/CoreServices.h>''',

                               name : 'Mac OS X Carbon support')

glib_have_os_x_9_or_later = false

if glib_have_carbon

  glib_conf.set('HAVE_CARBON', true)

  CARBON_LIBS='-Wl,-framework,Carbon' # FIXME: propagate to .pc files as well

  platform_ldflags += [CARBON_LIBS]

  glib_have_os_x_9_or_later = cc.compiles('''#include <AvailabilityMacros.h>

                                             #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090

                                             #error Compiling for minimum OS X version before 10.9

                                             #endif''', name : 'OS X 9 or later')

else

  CARBON_LIBS=''

endif

# Mac OS X Cocoa support

glib_have_cocoa = cc.compiles('''#include <Cocoa/Cocoa.h>

                                 #ifdef GNUSTEP_BASE_VERSION

                                 #error "Detected GNUstep, not Cocoa"

                                 #endif''',

                              name : 'Mac OS X Cocoa support')

if glib_have_cocoa

  glib_conf.set('HAVE_COCOA', true)

  COCOA_LIBS='-Wl,-framework,Foundation -Wl,-framework,AppKit' # FIXME: propagate to .pc files as well

  platform_ldflags += [COCOA_LIBS]

else

  COCOA_LIBS=''

endif

# Check for futex(2)

if cc.links('''#include <linux/futex.h>

               #include <sys/syscall.h>

               #include <unistd.h>

               int main (int argc, char ** argv) {

                 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);

                 return 0;

               }''', name : 'futex(2) system call')

  glib_conf.set('HAVE_FUTEX', 1)

endif

# Check for eventfd(2)

if cc.links('''#include <sys/eventfd.h>

               #include <unistd.h>

               int main (int argc, char ** argv) {

                 eventfd (0, EFD_CLOEXEC);

                 return 0;

               }''', name : 'eventfd(2) system call')

  glib_conf.set('HAVE_EVENTFD', 1)

endif

clock_gettime_test_code = '''

  #include <time.h>

  struct timespec t;

  int main (int argc, char ** argv) {

    return clock_gettime(CLOCK_REALTIME, &t);

  }'''

librt = []

if cc.links(clock_gettime_test_code, name : 'clock_gettime')

  glib_conf.set('HAVE_CLOCK_GETTIME', 1)

elif cc.links(clock_gettime_test_code, args : '-lrt', name : 'clock_gettime in librt')

  glib_conf.set('HAVE_CLOCK_GETTIME', 1)

  librt = cc.find_library('rt')

endif

# if statfs() takes 2 arguments (Posix) or 4 (Solaris)

if have_func_statfs

  if cc.compiles(glib_conf_prefix + '''

                 #include <unistd.h>

                        #ifdef HAVE_SYS_PARAM_H

                        #include <sys/param.h>

                        #endif

                        #ifdef HAVE_SYS_VFS_H

                        #include <sys/vfs.h>

                        #endif

                        #ifdef HAVE_SYS_MOUNT_H

                        #include <sys/mount.h>

                        #endif

                        #ifdef HAVE_SYS_STATFS_H

                        #include <sys/statfs.h>

                        #endif

                        void some_func (void) {

                          struct statfs st;

                          statfs("/", &st);

                        }''', name : 'number of arguments to statfs() (n=2)')

    glib_conf.set('STATFS_ARGS', 2)

  elif cc.compiles(glib_conf_prefix + '''

                   #include <unistd.h>

                          #ifdef HAVE_SYS_PARAM_H

                          #include <sys/param.h>

                          #endif

                          #ifdef HAVE_SYS_VFS_H

                          #include <sys/vfs.h>

                          #endif

                          #ifdef HAVE_SYS_MOUNT_H

                          #include <sys/mount.h>

                          #endif

                          #ifdef HAVE_SYS_STATFS_H

                          #include <sys/statfs.h>

                          #endif

                          void some_func (void) {

                            struct statfs st;

                            statfs("/", &st, sizeof (st), 0);

                          }''', name : 'number of arguments to statfs() (n=4)')

    glib_conf.set('STATFS_ARGS', 4)

  else

    error('Unable to determine number of arguments to statfs()')

  endif

endif

# open takes O_DIRECTORY as an option

#AC_MSG_CHECKING([])

if cc.compiles('''#include <fcntl.h>

                  #include <sys/types.h>

                  #include <sys/stat.h>],

                  void some_func (void) {

                    open(0, O_DIRECTORY, 0);

                  }''', name : 'open() option O_DIRECTORY')

  glib_conf.set('HAVE_OPEN_O_DIRECTORY', 1)

endif

# Check whether there is a vsnprintf() function with C99 semantics installed.

# AC_FUNC_VSNPRINTF_C99

# Check whether there is a snprintf() function with C99 semantics installed.

# AC_FUNC_SNPRINTF_C99

have_good_vsnprintf = false

have_good_snprintf = false

if host_system == 'windows'

  # Unfortunately the mingw and Visual Studio 2015+ implementations of C99-style

  # snprintf and vsnprintf don't seem to be quite good enough, at least not in

  # mingw-runtime-3.14.  (Sorry, I don't know exactly what is the problem,

  # but it is related to floating point formatting and decimal point vs. comma.)

  # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't

  # rigorous enough to notice, though.

  glib_conf.set('HAVE_C99_SNPRINTF', false)

  glib_conf.set('HAVE_C99_VSNPRINTF', false)

else

  vsnprintf_c99_test_code = '''

#include <stdio.h>

#include <stdarg.h>

int

doit(char * s, ...)

{

  char buffer[32];

  va_list args;

  int r;

  va_start(args, s);

  r = vsnprintf(buffer, 5, s, args);

  va_end(args);

  if (r != 7)

    exit(1);

  /* AIX 5.1 and Solaris seems to have a half-baked vsnprintf()

     implementation. The above will return 7 but if you replace

     the size of the buffer with 0, it borks! */

  va_start(args, s);

  r = vsnprintf(buffer, 0, s, args);

  va_end(args);

  if (r != 7)

    exit(1);

  exit(0);

}

int

main(void)

{

  doit("1234567");

  exit(1);

}'''

  rres = cc.run(vsnprintf_c99_test_code, name : 'C99 vsnprintf')

  if rres.compiled() and rres.returncode() == 0

    glib_conf.set('HAVE_C99_VSNPRINTF', 1)

    have_good_vsnprintf = true

  endif

  snprintf_c99_test_code = '''

#include <stdio.h>

#include <stdarg.h>

int

doit()

{

  char buffer[32];

  va_list args;

  int r;

  r = snprintf(buffer, 5, "1234567");

  if (r != 7)

    exit(1);

  r = snprintf(buffer, 0, "1234567");

  if (r != 7)

    exit(1);

  r = snprintf(NULL, 0, "1234567");

  if (r != 7)

    exit(1);

  exit(0);

}

int

main(void)

{

  doit();

  exit(1);

}'''

  rres = cc.run(snprintf_c99_test_code, name : 'C99 snprintf')

  if rres.compiled() and rres.returncode() == 0

    glib_conf.set('HAVE_C99_SNPRINTF', 1)

    have_good_snprintf = true

  endif

endif

if host_system == 'windows'

  glib_conf.set_quoted('EXEEXT', '.exe')

else

  glib_conf.set('EXEEXT', '')

endif

if have_good_vsnprintf and have_good_snprintf

  # Our printf is 'good' only if vsnpintf()/snprintf() supports C99 well enough

  glib_conf.set('HAVE_GOOD_PRINTF', 1) # FIXME: Check for HAVE_UNIX98_PRINTF?

else

  glib_conf.set('HAVE_VASPRINTF', 1)

endif

# Check whether the printf() family supports Unix98 %n$ positional parameters

# AC_FUNC_PRINTF_UNIX98

# Nothing uses HAVE_UNIX98_PRINTF

# Check for nl_langinfo and CODESET

# FIXME: Check for HAVE_BIND_TEXTDOMAIN_CODESET

if cc.links('''#include <langinfo.h>

               int main (int argc, char ** argv) {

                 char *codeset = nl_langinfo (CODESET);

                 return 0;

               }''', name : 'nl_langinfo and CODESET')

  glib_conf.set('HAVE_LANGINFO_CODESET', 1)

  glib_conf.set('HAVE_CODESET', 1)

endif

# Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c

if cc.links('''#include <langinfo.h>

               int main (int argc, char ** argv) {

                 char *str;

                 str = nl_langinfo (PM_STR);

                 str = nl_langinfo (D_T_FMT);

                 str = nl_langinfo (D_FMT);

                 str = nl_langinfo (T_FMT);

                 str = nl_langinfo (T_FMT_AMPM);

                 str = nl_langinfo (MON_1);

                 str = nl_langinfo (ABMON_12);

                 str = nl_langinfo (DAY_1);

                 str = nl_langinfo (ABDAY_7);

                 return 0;

               }''', name : 'nl_langinfo (PM_STR)')

  glib_conf.set('HAVE_LANGINFO_TIME', 1)

endif

if cc.links('''#include <langinfo.h>

               int main (int argc, char ** argv) {

                 char *str;

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);

                 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);

                 return 0;

               }''', name : 'nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)')

  glib_conf.set('HAVE_LANGINFO_OUTDIGIT', 1)

endif

# Check for nl_langinfo and alternative month names

if cc.links('''#ifndef _GNU_SOURCE

              # define _GNU_SOURCE

              #endif

              #include <langinfo.h>

               int main (int argc, char ** argv) {

                 char *str;

                 str = nl_langinfo (ALTMON_1);

                 str = nl_langinfo (ALTMON_2);

                 str = nl_langinfo (ALTMON_3);

                 str = nl_langinfo (ALTMON_4);

                 str = nl_langinfo (ALTMON_5);

                 str = nl_langinfo (ALTMON_6);

                 str = nl_langinfo (ALTMON_7);

                 str = nl_langinfo (ALTMON_8);

                 str = nl_langinfo (ALTMON_9);

                 str = nl_langinfo (ALTMON_10);

                 str = nl_langinfo (ALTMON_11);

                 str = nl_langinfo (ALTMON_12);

                 return 0;

               }''', name : 'nl_langinfo (ALTMON_n)')

  glib_conf.set('HAVE_LANGINFO_ALTMON', 1)

endif

# Check for nl_langinfo and abbreviated alternative month names

if cc.links('''#ifndef _GNU_SOURCE

              # define _GNU_SOURCE

              #endif

              #include <langinfo.h>

               int main (int argc, char ** argv) {

                 char *str;

                 str = nl_langinfo (_NL_ALTMON_1);

                 str = nl_langinfo (_NL_ALTMON_2);

                 str = nl_langinfo (_NL_ALTMON_3);

                 str = nl_langinfo (_NL_ALTMON_4);

                 str = nl_langinfo (_NL_ALTMON_5);

                 str = nl_langinfo (_NL_ALTMON_6);

                 str = nl_langinfo (_NL_ALTMON_7);

                 str = nl_langinfo (_NL_ALTMON_8);

                 str = nl_langinfo (_NL_ALTMON_9);

                 str = nl_langinfo (_NL_ALTMON_10);

                 str = nl_langinfo (_NL_ALTMON_11);

                 str = nl_langinfo (_NL_ALTMON_12);

                 return 0;

               }''', name : 'nl_langinfo (_NL_ALTMON_n)')

  glib_conf.set('HAVE_LANGINFO_ABALTMON', 1)

endif

# Check if C compiler supports the 'signed' keyword

if not cc.compiles('''signed char x;''', name : 'signed')

  glib_conf.set('signed', '/* NOOP */')

endif

# Check if the ptrdiff_t type exists

if cc.has_header_symbol('stddef.h', 'ptrdiff_t')

  glib_conf.set('HAVE_PTRDIFF_T', 1)

endif

# Check for sig_atomic_t type

if cc.links('''#include <signal.h>

               #include <sys/types.h>

               sig_atomic_t val = 42;

               int main (int argc, char ** argv) {

                 return val == 42 ? 0 : 1;

               }''', name : 'sig_atomic_t')

  glib_conf.set('HAVE_SIG_ATOMIC_T', 1)

endif

# Check if 'long long' works and what format can be used to print it

# jm_AC_TYPE_LONG_LONG

# Nothing uses HAVE_LONG_LONG_FORMAT and HAVE_INT64_AND_I64

if cc.compiles('''long long ll = 1LL;

                  int i = 63;

                  int some_func (void) {

                    long long llmax = (long long) -1;

                    return ll << i | ll >> i | llmax / ll | llmax % ll;

                  }''', name : 'long long')

  glib_conf.set('HAVE_LONG_LONG', 1)

  have_long_long = true

else

  have_long_long = false

endif

# Test whether the compiler supports the 'long double' type.

if cc.compiles('''/* The Stardent Vistra knows sizeof(long double), but does not support it.  */

                  long double foo = 0.0;

                  /* On Ultrix 4.3 cc, long double is 4 and double is 8.  */