# clutter package version number, (as distinct from shared library version)

# An odd micro number indicates in-progress development from Git

# An even micro number indicates a released version

#

# Making a point release:

# - increase clutter_micro_version to the next even number

# - increase clutter_interface_age to the next even number

# After the release:

# - increase clutter_micro_version to the next odd number

# - increase clutter_interface_version to the next odd number

m4_define([clutter_major_version], [1])

m4_define([clutter_minor_version], [26])

m4_define([clutter_micro_version], [2])

# • for stable releases: increase the interface age by 1 for each release

# • for development releases: keep clutter_interface_age to 0

m4_define([clutter_interface_age],

          [m4_if(m4_eval(clutter_minor_version % 2), [1],

                 [0],

                 [clutter_micro_version])])

m4_define([clutter_binary_age], [m4_eval(100 * clutter_minor_version + clutter_micro_version)])

m4_define([clutter_release_status],

          [m4_if(m4_eval(clutter_micro_version % 2), [1], [git],

                 [m4_if(m4_eval(clutter_minor_version % 2), [1], [snapshot],

                                                                 [release])])])

m4_define([clutter_version], [clutter_major_version.clutter_minor_version.clutter_micro_version])

# change this only when breaking the API

m4_define([clutter_api_version], [1.0])

AC_PREREQ([2.63])

AC_INIT([clutter],

        [clutter_version],

        [http://bugzilla.gnome.org/enter_bug.cgi?product=clutter],

        [clutter],

        [http://www.clutter-project.org])

AC_CONFIG_SRCDIR([clutter/clutter.h])

AC_CONFIG_HEADERS([clutter/config.h])

AC_CONFIG_AUX_DIR([build])

AC_CONFIG_MACRO_DIR([build/autotools])

AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])

AM_SILENT_RULES([yes])

AC_SUBST([CLUTTER_MAJOR_VERSION],  [clutter_major_version])

AC_SUBST([CLUTTER_MINOR_VERSION],  [clutter_minor_version])

AC_SUBST([CLUTTER_MICRO_VERSION],  [clutter_micro_version])

AC_SUBST([CLUTTER_VERSION],        [clutter_version])

AC_SUBST([CLUTTER_API_VERSION],    [clutter_api_version])

AC_SUBST([CLUTTER_API_VERSION_AM], [$CLUTTER_MAJOR_VERSION\_0])

AC_SUBST([CLUTTER_RELEASE_STATUS], [clutter_release_status])

m4_define([lt_current],  [m4_eval(100 * clutter_minor_version + clutter_micro_version - clutter_interface_age)])

m4_define([lt_revision], [clutter_interface_age])

m4_define([lt_age],      [m4_eval(clutter_binary_age - clutter_interface_age)])

CLUTTER_LT_CURRENT=lt_current

CLUTTER_LT_REV=lt_revision

CLUTTER_LT_AGE=lt_age

CLUTTER_LT_VERSION="$CLUTTER_LT_CURRENT:$CLUTTER_LT_REV:$CLUTTER_LT_AGE"

CLUTTER_LT_LDFLAGS="-version-info $CLUTTER_LT_VERSION"

AC_SUBST([CLUTTER_LT_CURRENT],  [lt_current])

AC_SUBST([CLUTTER_LT_REVISION], [lt_revision])

AC_SUBST([CLUTTER_LT_VERSION],  [$CLUTTER_LT_VERSION])

AC_PROG_SED

dnl = Preliminary platform checks =============================================

AC_CANONICAL_HOST

platform_win32=no

platform_quartz=no

platform_linux=no

AC_MSG_CHECKING([if building for some Win32 platform])

AS_CASE([$host],

        [*-*-mingw*|*-*-cygwin*],

        [

          CLUTTER_LT_LDFLAGS="$CLUTTER_LT_LDFLAGS -no-undefined"

          platform_win32=yes

        ],

        [*-*-linux*],

        [

          platform_linux=yes

        ],

        []

)

AC_MSG_RESULT([$platform_win32])

AM_CONDITIONAL(OS_WIN32, [test "$platform_win32" = "yes"])

AC_CHECK_HEADER([OpenGL/gl.h], [platform_quartz=yes], [platform_quartz=no])

AM_CONDITIONAL(OS_QUARTZ, [test "$platform_quartz" = "yes"])

AM_CONDITIONAL(OS_LINUX, [test "$platform_linux" = "yes"])

AC_SUBST(CLUTTER_LT_LDFLAGS)

AC_CACHE_SAVE

dnl = Dependencies =========================================================

# Checks for programs.

AM_PROG_CC_C_O

# require libtool >= 2.2

LT_PREREQ([2.2.6])

LT_INIT([disable-static])

LT_LIB_M

# Checks for header files.

AC_HEADER_STDC

# required versions for dependencies

m4_define([glib_req_version],           [2.44.0])

m4_define([cogl_req_version],           [1.21.2])

m4_define([json_glib_req_version],      [0.12.0])

m4_define([atk_req_version],            [2.5.3])

m4_define([cairo_req_version],          [1.14.0])

m4_define([pango_req_version],          [1.30])

m4_define([gi_req_version],             [1.39.0])

m4_define([gtk_doc_req_version],        [1.20])

m4_define([xcomposite_req_version],     [0.4])

m4_define([gdk_req_version],            [3.22.6])

m4_define([libinput_req_version],       [0.19.0])

m4_define([libudev_req_version],        [136])

AC_SUBST([GLIB_REQ_VERSION],       [glib_req_version])

AC_SUBST([COGL_REQ_VERSION],       [cogl_req_version])

AC_SUBST([JSON_GLIB_REQ_VERSION],  [json_glib_req_version])

AC_SUBST([ATK_REQ_VERSION],        [atk_req_version])

AC_SUBST([CAIRO_REQ_VERSION],      [cairo_req_version])

AC_SUBST([PANGO_REQ_VERSION],      [pango_req_version])

AC_SUBST([GI_REQ_VERSION],         [gi_req_version])

AC_SUBST([GTK_DOC_REQ_VERSION],    [gtk_doc_req_version])

AC_SUBST([XCOMPOSITE_REQ_VERSION], [xcomposite_req_version])

AC_SUBST([GDK_REQ_VERSION],        [gdk_req_version])

AC_SUBST([LIBINPUT_REQ_VERSION],   [libinput_req_version])

AC_SUBST([LIBUDEV_REQ_VERSION],    [libudev_req_version])

# Checks for typedefs, structures, and compiler characteristics.

AM_PATH_GLIB_2_0([glib_req_version],

                 [],

                 [AC_MSG_ERROR([glib-2.0 is required])],

                 [gobject gio gthread gmodule-no-export])

# Check for -Bsymbolic-functions to avoid intra-library PLT jumps

AC_ARG_ENABLE([Bsymbolic],

              [AS_HELP_STRING([--disable-Bsymbolic],

                              [Avoid linking with -Bsymbolic])],

              [],

              [

                saved_LDFLAGS="${LDFLAGS}"

                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])

                LDFLAGS=-Wl,-Bsymbolic-functions

                AC_TRY_LINK([], [int main (void) { return 0; }],

                            [

                              AC_MSG_RESULT([yes])

                              enable_Bsymbolic=yes

                            ],

                            [

                              AC_MSG_RESULT([no])

                              enable_Bsymbolic=no

                            ])

                LDFLAGS="${saved_LDFLAGS}"

              ])

AS_IF([test "x$enable_Bsymbolic" = "xyes"], [CLUTTER_LINK_FLAGS=-Wl[,]-Bsymbolic-functions])

AC_SUBST(CLUTTER_LINK_FLAGS)

# Check for the visibility flags

CLUTTER_HIDDEN_VISIBILITY_CFLAGS=""

case "$host" in

  *-*-mingw*)

    dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)

    AC_DEFINE([_CLUTTER_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],

              [defines how to decorate public symbols while building])

    CFLAGS="${CFLAGS} -fvisibility=hidden"

    ;;

  *)

    dnl on other compilers, check if we can do -fvisibility=hidden

    SAVED_CFLAGS="${CFLAGS}"

    CFLAGS="-fvisibility=hidden"

    AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])

    AC_TRY_COMPILE([], [int main (void) { return 0; }],

                   AC_MSG_RESULT(yes)

                   enable_fvisibility_hidden=yes,

                   AC_MSG_RESULT(no)

                   enable_fvisibility_hidden=no)

    CFLAGS="${SAVED_CFLAGS}"

    AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [

      AC_DEFINE([_CLUTTER_EXTERN], [__attribute__((visibility("default"))) extern],

                [defines how to decorate public symbols while building])

      CLUTTER_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"

    ])

    ;;

esac

AC_SUBST(CLUTTER_HIDDEN_VISIBILITY_CFLAGS)

AC_CACHE_SAVE

dnl ========================================================================

FLAVOUR_LIBS=""

FLAVOUR_CFLAGS=""

CLUTTER_BACKENDS=""

CLUTTER_INPUT_BACKENDS=""

CLUTTER_CONFIG_DEFINES=

experimental_backend=no

experimental_input_backend=no

# base dependencies for core

CLUTTER_BASE_PC_FILES="cogl-1.0 >= $COGL_REQ_VERSION cogl-path-1.0 cairo-gobject >= $CAIRO_REQ_VERSION gio-2.0 >= glib_req_version atk >= $ATK_REQ_VERSION pangocairo >= $PANGO_REQ_VERSION cogl-pango-1.0 json-glib-1.0 >= $JSON_GLIB_REQ_VERSION"

# private base dependencies

CLUTTER_BASE_PC_FILES_PRIVATE=""

# backend specific pkg-config files

BACKEND_PC_FILES=""

# private backend specific dependencies

BACKEND_PC_FILES_PRIVATE=""

dnl === Clutter windowing system backend ======================================

AC_ARG_ENABLE([x11-backend],

              [AS_HELP_STRING([--enable-x11-backend=@<:@yes/no@:>@], [Enable the X11 backend (default=check)])],

              [enable_x11=$enableval],

              [enable_x11=check])

AC_ARG_ENABLE([win32-backend],

              [AS_HELP_STRING([--enable-win32-backend=@<:@yes/no@:>@], [Enable the Windows backend (default=check)])],

              [enable_win32=$enableval],

              [enable_win32=check])

AC_ARG_ENABLE([quartz-backend],

              [AS_HELP_STRING([--enable-quartz-backend=@<:@yes/no@:>@], [Enable the OS X backend (default=check)])],

              [enable_osx=$enableval],

              [enable_osx=check])

AC_ARG_ENABLE([gdk-backend],

              [AS_HELP_STRING([--enable-gdk-backend=@<:@yes/no@:>@], [Enable the GDK backend (default=check)])],

              [enable_gdk=$enableval],

              [enable_gdk=check])

AC_ARG_ENABLE([wayland-backend],

              [AS_HELP_STRING([--enable-wayland-backend=@<:@yes/no@:>@], [Enable the Wayland client backend (default=check)])],

              [enable_wayland=$enableval],

              [enable_wayland=check])

AC_ARG_ENABLE([egl-backend],

              [AS_HELP_STRING([--enable-egl-backend=@<:@yes/no@:>@], [Enable the EGL framebuffer backend (default=no)])],

              [enable_egl=$enableval],

              [enable_egl=check])

AC_ARG_ENABLE([mir-backend],

              [AS_HELP_STRING([--enable-mir-backend=@<:@yes/no@:>@], [Enable the Mir client backend (default=no)])],

              [enable_mir=$enableval],

              [enable_mir=no])

AC_ARG_ENABLE([cex100-backend],

              [AS_HELP_STRING([--enable-cex100-backend=@<:@yes/no@:>@], [Enable the CEx100 backend (default=no)])],

              [enable_cex100=$enableval],

              [enable_cex100=no])

dnl Additional input backends

AC_ARG_ENABLE([tslib-input],

              [AS_HELP_STRING([--enable-tslib-input=@<:@yes/no@:>@], [Enable TSLib for input events (default=no)])],

              [enable_tslib=$enableval],

              [enable_tslib=no])

AC_ARG_ENABLE([evdev-input],

              [AS_HELP_STRING([--enable-evdev-input=@<:@yes/no@:>@], [Enable evdev for input events (default=check)])],

              [enable_evdev=$enableval],

              [enable_evdev=check])

dnl Define default values

AS_IF([test "x$enable_x11" = xcheck], [

  PKG_CHECK_EXISTS([x11], [enable_x11=yes], [enable_x11=no])

])

AS_IF([test "x$enable_win32" = xcheck], [

  AS_IF([test "x$platform_win32" = "xyes"], [enable_win32=yes], [enable_win32=no])

])

AS_IF([test "x$enable_osx" = xcheck], [

  AS_IF([test "x$platform_quartz" = "xyes"], [enable_osx=yes], [enable_osx=no])

])

AS_IF([test "x$enable_gdk" = xcheck], [

  PKG_CHECK_EXISTS([gdk-3.0 >= gdk_req_version], [enable_gdk=yes], [enable_gdk=no])

])

AS_IF([test "x$enable_egl" = xcheck], [

  PKG_CHECK_EXISTS([egl], [enable_egl=yes], [enable_egl=no])

  PKG_CHECK_EXISTS([libinput], [enable_evdev=yes], [enable_evdev=no])

])

dnl Per-backend rules

AS_IF([test "x$enable_x11" = "xyes"],

      [

        CLUTTER_BACKENDS="$CLUTTER_BACKENDS x11"

        CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS x11"

        SUPPORT_X11=1

        SUPPORT_GLX=1

        SUPPORT_COGL=1

        # we use fontconfig API and pango-ft2 when the fontconfig

        # configuration changes; we don't expose any API for this

        # so we add pango-ft2 to the private Requires.

        PKG_CHECK_EXISTS([pangoft2],

                         [

                           AC_DEFINE([HAVE_PANGO_FT2], [1], [Supports PangoFt2])

                           BACKEND_PC_FILES_PRIVATE="$BACKEND_PC_FILES_PRIVATE pangoft2"

                         ],

                         [])

      ])

AS_IF([test "x$enable_gdk" = "xyes"],

      [

        CLUTTER_BACKENDS="$CLUTTER_BACKENDS gdk"

        CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS gdk"

	SUPPORT_GDK=1

        SUPPORT_COGL=1

	BACKEND_PC_FILES="$BACKEND_PC_FILES gdk-3.0"

      ])

AS_IF([test "x$enable_wayland" != xno],

      [

        # We need to manually check for Wayland support in Cogl because

        # the windowing systems are not exposed in the pkg-config file

        saved_CFLAGS="${CFLAGS}"

        CFLAGS="`$PKG_CONFIG --cflags cogl-1.0`"

        AC_MSG_CHECKING([for Wayland Cogl backend])

        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[

#include <cogl/cogl.h>

]],

[[

#ifndef COGL_HAS_EGL_PLATFORM_WAYLAND_SUPPORT

#error Cogl compiled without Wayland support

#endif

]])], [

          AC_MSG_RESULT(yes)

          have_cogl_wayland=yes

        ], [

          AC_MSG_RESULT(no)

          have_cogl_wayland=no

        ])

        CFLAGS="${saved_CFLAGS}"

        AS_IF([test "x$have_cogl_wayland" = xyes],

              [

                PKG_CHECK_EXISTS([wayland-client wayland-cursor xkbcommon gdk-pixbuf-2.0],

                                 [

                                   BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-cursor wayland-client xkbcommon"

                                   BACKEND_PC_FILES_PRIVATE="$BACKEND_PC_FILES_PRIVATE gdk-pixbuf-2.0"

                                   CLUTTER_BACKENDS="$CLUTTER_BACKENDS wayland"

                                   CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS wayland"

                                   SUPPORT_WAYLAND=1

                                   SUPPORT_COGL=1

                                 ],

                                 [

                                   AS_IF([test "x$enable_wayland" = xyes],

                                         [AC_MSG_ERROR(["*** Missing dependencies for Wayland support ***"])],

                                         [enable_wayland=no])

                                 ])

              ],

              [

                AS_IF([test "x$enable_wayland" = xyes],

                      [AC_MSG_ERROR("*** Cogl is missing Wayland support ***")],

                      [enable_wayland=no])

              ])

      ])

dnl Note this is orthogonal to the client side support and you can

dnl use the Wayland compositor features with any of the clutter

dnl backends with corresponding Cogl support.

AC_ARG_ENABLE([wayland-compositor],

              [AS_HELP_STRING([--enable-wayland-compositor=@<:@yes/no@:>@],

                              [Enable Wayland compositor features (default=no)])],

              [],

              [AS_IF([test "x$SUPPORT_EGL" = "x1"],

                     [enable_wayland_compositor=yes],

                     [enable_wayland_compositor=no])

              ])

AS_IF([test "x$enable_wayland_compositor" = "xyes"],

      [

        PKG_CHECK_EXISTS([wayland-server],

			 [BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-server"], [])

        SUPPORT_WAYLAND_COMPOSITOR=1

        SUPPORT_COGL=1

	CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_HAS_WAYLAND_COMPOSITOR_SUPPORT 1"

      ])

AM_CONDITIONAL(SUPPORT_WAYLAND_COMPOSITOR, [test "x$SUPPORT_WAYLAND_COMPOSITOR" = "x1"])

AS_IF([test "x$enable_cex100" = "xyes"],

      [

        CLUTTER_BACKENDS="$CLUTTER_BACKENDS cex100"

        experimental_backend="yes"

        SUPPORT_CEX100=1

        SUPPORT_COGL=1

        have_gdl=no

        AC_CHECK_HEADERS([libgdl.h], [have_gdl=yes])

        AS_IF([test "x$have_gdl" = "xno"],

              [

                AC_CHECK_HEADERS([CE4100/libgdl.h],

                                 [

                                   FLAVOUR_CFLAGS="-I/usr/include/CE4100"

                                   have_gdl=yes

                                   CLUTTER_CEX100_LIBGDL_PREFIX=CE4100/

                                 ])

              ])

        AS_IF([test "x$have_gdl" = "xno"],

              [AC_MSG_ERROR([libgdl.h not found but the CEx100 backend has been explicitly enabled])])

        AC_SUBST(CLUTTER_CEX100_LIBGDL_PREFIX)

        FLAVOUR_LIBS="$FLAVOUR_LIBS -lgdl"

        AC_DEFINE([CLUTTER_EGL_BACKEND_CEX100], [1], [Use CEX100 EGL backend])

        AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])

      ])

AS_IF([test "x$enable_egl" = "xyes"],

      [

        CLUTTER_BACKENDS="$CLUTTER_BACKENDS egl"

        SUPPORT_EGL=1

        SUPPORT_COGL=1

        FLAVOUR_LIBS="$FLAVOUR_LIBS $TSLIB_LIBS $EVDEV_LIBS"

        FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $TSLIB_CFLAGS $EVDEV_CFLAGS"

        AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])

      ])

AS_IF([test "x$enable_osx" = "xyes"],

      [

        CLUTTER_BACKENDS="$CLUTTER_BACKENDS osx"

        CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS osx"

        FLAVOUR_LIBS="$FLAVOUR_LIBS -framework Cocoa -framework OpenGL"

        SUPPORT_OSX=1

      ])

AS_IF([test "x$enable_win32" = "xyes"],

      [

        CLUTTER_BACKENDS="$CLUTTER_BACKENDS win32"

        CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS win32"

        FLAVOUR_LIBS="$FLAVOUR_LIBS -lopengl32 -lgdi32 -lwinmm"

        FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS -D_WIN32_WINNT=0x0500"

        AC_CHECK_TOOL(WINDRES, [windres], [AC_MSG_ERROR([*** windres is required])])

        SUPPORT_WIN32=1

      ])

AS_IF([test "x$enable_mir" = "xyes"],

      [

        CLUTTER_BACKENDS="$CLUTTER_BACKENDS mir"

        CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS mir"

        SUPPORT_MIR=1

        SUPPORT_COGL=1

        # We need to manually check for Mir support in Cogl because

        # the windowing systems are not exposed in the pkg-config file

        saved_CFLAGS="${CFLAGS}"

        CFLAGS="`$PKG_CONFIG --cflags cogl-1.0`"

        AC_MSG_CHECKING([for Mir Cogl backend])

        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[

#include <cogl/cogl.h>

]],

[[

#ifndef COGL_HAS_EGL_PLATFORM_MIR_SUPPORT

#error Cogl compiled without Mir support

#endif

]])], [

          AC_MSG_RESULT(yes)

          have_cogl_mir=yes

        ], [

          AC_MSG_RESULT(no)

          have_cogl_mir=no

        ])

        AS_IF([test "x$have_cogl_mir" = xno], [AC_MSG_ERROR("*** Cogl is missing Mir support.")])

        PKG_CHECK_EXISTS([mirclient],

                         [BACKEND_PC_FILES="$BACKEND_PC_FILES mirclient"],

                         [])

      ])

AS_IF([test "x$CLUTTER_BACKENDS" = "x"],

      [

        AC_MSG_ERROR([No backend enabled. You need to enable at least one backend.])

      ])

AS_IF([test "x$platform_linux" = "xyes"],

      [

        AC_DEFINE([OS_LINUX], [1], [Define to 1 if building for Linux])

      ])

AS_IF([test "x$enable_tslib" = xyes], [

  PKG_CHECK_EXISTS([tslib-1.0], [have_tslib=yes], [have_tslib=no])

  AS_IF([test "x$have_tslib" = xyes], [

    CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS tslib"

    experimental_input_backend="yes"

    AC_DEFINE([HAVE_TSLIB], [1], [Have tslib for touchscreen handling])

    SUPPORT_TSLIB=1

  ])

])

AS_IF([test "x$enable_evdev" = xyes], [

  PKG_CHECK_EXISTS([libinput gudev-1.0 xkbcommon], [have_evdev=yes], [have_evdev=no])

  AS_IF([test "x$have_evdev" = "xyes"], [

    CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS evdev"

    BACKEND_PC_FILES_PRIVATE="$BACKEND_PC_FILES_PRIVATE libudev >= $LIBUDEV_REQ_VERSION libinput >= $LIBINPUT_REQ_VERSION xkbcommon"

    AC_DEFINE([HAVE_EVDEV], [1], [Have evdev support for input handling])

    SUPPORT_EVDEV=1

  ])

])

# conditionals for use in automake files...

AM_CONDITIONAL(SUPPORT_GLX,     [test "x$SUPPORT_GLX" = "x1"])

AM_CONDITIONAL(SUPPORT_X11,     [test "x$SUPPORT_X11" = "x1"])

AM_CONDITIONAL(SUPPORT_GDK,     [test "x$SUPPORT_GDK" = "x1"])

AM_CONDITIONAL(SUPPORT_EGL,     [test "x$SUPPORT_EGL" = "x1"])

AM_CONDITIONAL(SUPPORT_OSX,     [test "x$SUPPORT_OSX" = "x1"])

AM_CONDITIONAL(SUPPORT_WIN32,   [test "x$SUPPORT_WIN32" = "x1"])

AM_CONDITIONAL(SUPPORT_CEX100,  [test "x$SUPPORT_CEX100" = "x1"])

AM_CONDITIONAL(SUPPORT_WAYLAND, [test "x$SUPPORT_WAYLAND" = "x1"])

AM_CONDITIONAL(SUPPORT_MIR,     [test "x$SUPPORT_MIR" = "x1"])

AM_CONDITIONAL(USE_COGL,  [test "x$SUPPORT_COGL" = "x1"])

AM_CONDITIONAL(USE_TSLIB, [test "x$have_tslib" = "xyes"])

AM_CONDITIONAL(USE_EVDEV, [test "x$have_evdev" = "xyes"])

AM_CONDITIONAL(USE_GLD,   [test "x$have_gdl" = "xyes"])

AM_CONDITIONAL(NEED_XKB_UTILS, [test "x$have_evdev" = "xyes" -o "x$SUPPORT_WAYLAND" = "x1"])

dnl Instead of using AM_CFLAGS to ensure

dnl COGL_ENABLE_EXPERIMENTAL_2_0_API is defined while compiling clutter

dnl and cogl code we use a define in config.h instead. This helps ensure

dnl other tools such as glib-mkenums and gir-scanner don't end up

dnl using the define also.

AC_DEFINE([COGL_ENABLE_EXPERIMENTAL_2_0_API], [1], [Can use Cogl 2.0 API internally])

AC_ARG_WITH([default-drivers],

            [AS_HELP_STRING([--with-default-drivers=DRIVER], [Comma-separated list of Cogl drivers to use])],

            [clutter_drivers=$withval],

            [clutter_drivers="*"])

AC_DEFINE_UNQUOTED([CLUTTER_DRIVERS], ["$clutter_drivers"], [List of Cogl drivers])

dnl strip leading spaces

CLUTTER_BACKENDS=${CLUTTER_BACKENDS#* }

AC_SUBST(CLUTTER_BACKENDS)

CLUTTER_INPUT_BACKENDS=${CLUTTER_INPUT_BACKENDS#* }

AC_SUBST(CLUTTER_INPUT_BACKENDS)

AC_CACHE_SAVE

dnl === Clutter configuration =================================================

# windowing systems

AS_IF([test "x$SUPPORT_X11" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_X11 \"x11\"

#define CLUTTER_INPUT_X11 \"x11\""])

AS_IF([test "x$SUPPORT_GDK" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_GDK \"gdk\"

#define CLUTTER_INPUT_GDK \"gdk\""])

AS_IF([test "x$SUPPORT_GLX" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_GLX \"glx\""])

AS_IF([test "x$SUPPORT_EGL" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_EGL \"eglnative\""])

AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_WAYLAND \"wayland\""])

AS_IF([test "x$SUPPORT_MIR" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_MIR \"mir\"

#define CLUTTER_INPUT_MIR \"mir\""])

AS_IF([test "x$SUPPORT_OSX" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_OSX \"osx\"

#define CLUTTER_INPUT_OSX \"osx\""])

AS_IF([test "x$SUPPORT_WIN32" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_WIN32 \"win32\"

#define CLUTTER_INPUT_WIN32 \"win32\""])

AS_IF([test "x$SUPPORT_CEX100" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_WINDOWING_CEX100 \"cex100\""])

AS_IF([test "x$SUPPORT_EVDEV" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_INPUT_EVDEV \"evdev\""])

AS_IF([test "x$SUPPORT_TSLIB" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_INPUT_TSLIB \"tslib\""])

AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],

      [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_INPUT_WAYLAND \"wayland\""])

# the 'null' input backend is special

CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES

#define CLUTTER_INPUT_NULL \"null\""

AC_SUBST([CLUTTER_CONFIG_DEFINES])

dnl === Clutter substitutions kept for backwards compatibility ================

AC_SUBST([CLUTTER_WINSYS],       [deprecated])

AC_SUBST([CLUTTER_WINSYS_BASE],  [deprecated])

AC_SUBST([CLUTTER_STAGE_TYPE],   [deprecated])

AC_SUBST([CLUTTER_SONAME_INFIX], [deprecated])

AC_SUBST([CLUTTER_FLAVOUR],      [deprecated])

AC_SUBST([CLUTTER_COGL],         [deprecated])

AC_SUBST([COGL_DRIVER],          [deprecated])

dnl === X11 checks, only for X11-based backends ===============================

X11_PC_FILES=""

X11_EXTS=""

x11_tests=no

AS_IF([test "x$SUPPORT_X11" = "x1"],

      [

        # base X11 includes and libraries

        AC_MSG_CHECKING([for X11])

        # start with pkg-config

        PKG_CHECK_EXISTS([x11], [have_x11=yes], [have_x11=no])

        AS_IF([test "x$have_x11" = "xyes"],

              [

                X11_PC_FILES="x11"

                # we actually need to ask for CFLAGS and LIBS

                X11_CFLAGS=`$PKG_CONFIG --cflags $X11_PC_FILES`

                X11_LIBS=`$PKG_CONFIG --libs $X11_PC_FILES`

                AC_MSG_RESULT([found])

              ],

              [

                # no pkg-config, let's go old school

                AC_PATH_X

                AS_IF([test "x$no_x" = "xyes"],

                      [AC_MSG_ERROR([No X11 Libraries found])],

                      [

                        AS_IF([test "x$x_includes" != "xNONE" && test -n "$x_includes"],

                              [X11_CFLAGS=-I`echo $x_includes | sed -e "s/:/ -I/g"`])

                        AS_IF([test "x$x_libraries" != "xNONE" && test -n "$x_libraries"],

                              [X11_LIBS=-L`echo $x_libraries | sed -e "s/:/ -L/g"`])

                        AC_MSG_RESULT([found])

                      ]

                )

              ]

        )

        # XEXT (required)

        AC_MSG_CHECKING([for XEXT extension])

        PKG_CHECK_EXISTS([xext], [have_xext=yes], [have_xext=no])

        AS_IF([test "x$have_xext" = "xyes"],

              [

                AC_DEFINE(HAVE_XEXT, [1], [Define to 1 if we have the XEXT X extension])

                X11_LIBS="$X11_LIBS -lXext"

                X11_PC_FILES="$X11_PC_FILES xext"

                X11_EXTS="$X11_EXTS xext"

                AC_MSG_RESULT([found])

              ],

              [AC_MSG_ERROR([Not found])]

        )

        # XDAMAGE (required)

        AC_MSG_CHECKING([for XDAMAGE extension])

        PKG_CHECK_EXISTS([xdamage], [have_xdamage=yes], [have_xdamage=no])

        AS_IF([test "x$have_xdamage" = "xyes"],

              [

                AC_DEFINE(HAVE_XDAMAGE, [1], [Define to 1 if we have the XDAMAGE X extension])

                X11_LIBS="$X11_LIBS -lXdamage"

                X11_PC_FILES="$X11_PC_FILES xdamage"

                X11_EXTS="$X11_EXTS xdamage"

                AC_MSG_RESULT([found])

              ],

              [AC_MSG_ERROR([not found])]

        )

        # XCOMPOSITE (optional)

        AC_MSG_CHECKING([for XCOMPOSITE extension >= $XCOMPOSITE_REQ_VERSION])

        PKG_CHECK_EXISTS([xcomposite >= $XCOMPOSITE_REQ_VERSION], [have_xcomposite=yes], [have_xcomposite=no])

        AS_IF([test "x$have_xcomposite" = "xyes"],

              [

                AC_DEFINE(HAVE_XCOMPOSITE, [1], [Define to 1 if we have the XCOMPOSITE X extension])

                X11_LIBS="$X11_LIBS -lXcomposite"

                X11_PC_FILES="$X11_PC_FILES xcomposite >= $XCOMPOSITE_REQ_VERSION"

                X11_EXTS="$X11_EXTS xcomposite"

                AC_MSG_RESULT([found])

              ],

              [AC_MSG_ERROR([not found])]

        )

        # X Generic Extensions (optional)

        clutter_save_CPPFLAGS="$CPPFLAGS"

        CPPFLAGS="$CPPFLAGS $X11_CFLAGS"

        clutter_save_LIBS="$LIBS"

        LIBS="$LIBS $X11_LIBS"

        have_xge=no

        AC_CHECK_FUNC([XGetEventData],

                      [

                        AC_DEFINE([HAVE_XGE], [1], [Define to 1 if X Generic Extensions is available])

                        have_xge=yes

                        X11_EXTS="$X11_EXTS xge"

                      ])

        CPPFLAGS="$clutter_save_CPPFLAGS"

        LIBS="$clutter_save_LIBS"

        # XI (optional)

        AC_ARG_ENABLE([xinput],

                      [AS_HELP_STRING([--enable-xinput], [Use the XI X extension])],

                      [],

                      [enable_xinput=yes])

        AS_IF([test "x$enable_xinput" = "xyes"],

              [

                PKG_CHECK_EXISTS([xi], [have_xinput=yes], [have_xinput=no])

              ],

              [

                have_xinput=no

              ])

        AS_CASE([$have_xinput],

                [yes],

                [

                  AC_CHECK_HEADERS([X11/extensions/XInput2.h],

                                   [

                                     have_xinput2=yes

                                     AC_DEFINE([HAVE_XINPUT_2],

                                               [1],

                                               [Define to 1 if XI2 is available])

                                   ])

                  clutter_save_LIBS="$LIBS"

                  LIBS="$LIBS -lXi"

                  AC_CHECK_FUNC([XIAllowTouchEvents],

                                [

                                  AC_CHECK_MEMBER([XIScrollClassInfo.number],

                                                  [

                                                    have_xinput_2_2=yes

                                                    AC_DEFINE([HAVE_XINPUT_2_2], [1], [Define to 1 if XInput 2.2 is available])

                                                  ],

                                                  [have_xinput_2_2=no],

                                                  [[#include <X11/extensions/XInput2.h>]])])

                  LIBS="$clutter_save_LIBS"

                  X11_LIBS="$X11_LIBS $XINPUT_LIBS"

                  X11_PC_FILES="$X11_PC_FILES xi"

                  AS_IF([test "x$have_xinput_2_2" = "xyes"],

                        [X11_EXTS="$X11_EXTS xi2.2"],

                        [X11_EXTS="$X11_EXTS xi2.0"])

                ],

                [no],

                [have_xinput2=no],

                [*],

                [AC_MSG_ERROR([Invalid argument for --enable-xinput])]

        )

        # XKB

        clutter_save_CPPFLAGS="$CPPFLAGS"

        CPPFLAGS="$CPPFLAGS $X11_CFLAGS"

        clutter_save_LIBS="$LIBS"

        LIBS="$LIBS $X11_LIBS"

        have_xkb=no

        AC_CHECK_FUNC([XkbQueryExtension],

                      [

                        AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])

                        have_xkb=yes

                        X11_EXTS="$X11_EXTS xkb"

                      ])

        CPPFLAGS="$clutter_save_CPPFLAGS"

        LIBS="$clutter_save_LIBS"

        x11_tests=yes

        BACKEND_PC_FILES="$BACKEND_PC_FILES $X11_PC_FILES"

        FLAVOUR_LIBS="$FLAVOUR_LIBS $X11_LIBS"

        FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $X11_CFLAGS"

      ]

)

AM_CONDITIONAL([BUILD_XI2], [test "x$have_xinput2" = "xyes"])

AM_CONDITIONAL([X11_TESTS], [test "x$x11_tests" = "xyes"])

X11_EXTS=${X11_EXTS#* }

AC_CACHE_SAVE

dnl === Enable GDK-Pixbuf in tests ============================================

m4_define([pixbuf_default], [yes])

AC_ARG_ENABLE([gdk-pixbuf],

              [AS_HELP_STRING([--enable-gdk-pixbuf=@<:@no/yes@:>@],

                              [Enable tests using GDK-Pixbuf @<:@default=]pixbuf_default[@:>@])],

              [enable_pixbuf=$enable_val],

              [enable_pixbuf=pixbuf_default])

AS_CASE([$enable_pixbuf],

        [yes],

        [

          PKG_CHECK_MODULES([GDK_PIXBUF], [gdk-pixbuf-2.0])

          AC_SUBST(GDK_PIXBUF_CFLAGS)

          AC_SUBST(GDK_PIXBUF_LIBS)

          pixbuf_tests=yes

        ],

        [no],

        [

          pixbuf_tests=no

        ]

)

AM_CONDITIONAL([PIXBUF_TESTS], [test "x$pixbuf_tests" = "xyes"])

dnl === Enable debug level ====================================================

m4_define([debug_default], [m4_if(m4_eval(clutter_minor_version % 2), [1], [yes], [minimum])])

AC_ARG_ENABLE([debug],

              [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],

                              [Control Clutter debugging level @<:@default=]debug_default[@:>@])],

              [],

              [enable_debug=debug_default])

AS_CASE([$enable_debug],

        [yes],