dnl Parameterized macros.

dnl Requires GNU m4.

dnl This file is part of Autoconf.

dnl Copyright (C) 1992, 93, 94, 95, 96, 1998 Free Software Foundation, Inc.

dnl

dnl This program is free software; you can redistribute it and/or modify

dnl it under the terms of the GNU General Public License as published by

dnl the Free Software Foundation; either version 2, or (at your option)

dnl any later version.

dnl

dnl This program is distributed in the hope that it will be useful,

dnl but WITHOUT ANY WARRANTY; without even the implied warranty of

dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

dnl GNU General Public License for more details.

dnl

dnl You should have received a copy of the GNU General Public License

dnl along with this program; if not, write to the Free Software

dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA

dnl 02111-1307, USA.

dnl

dnl As a special exception, the Free Software Foundation gives unlimited

dnl permission to copy, distribute and modify the configure scripts that

dnl are the output of Autoconf.  You need not follow the terms of the GNU

dnl General Public License when using or distributing such scripts, even

dnl though portions of the text of Autoconf appear in them.  The GNU

dnl General Public License (GPL) does govern all other use of the material

dnl that constitutes the Autoconf program.

dnl

dnl Certain portions of the Autoconf source text are designed to be copied

dnl (in certain cases, depending on the input) into the output of

dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf

dnl source text consists of comments plus executable code that decides which

dnl of the data portions to output in any given case.  We call these

dnl comments and executable code the "non-data" portions.  Autoconf never

dnl copies any of the non-data portions into its output.

dnl

dnl This special exception to the GPL applies to versions of Autoconf

dnl released by the Free Software Foundation.  When you make and

dnl distribute a modified version of Autoconf, you may extend this special

dnl exception to the GPL to apply to your modified version as well, *unless*

dnl your modified version has the potential to copy into its output some

dnl of the text that was the non-data portion of the version that you started

dnl with.  (In other words, unless your change moves or copies text from

dnl the non-data portions to the data portions.)  If your modification has

dnl such potential, you must delete any notice of this special exception

dnl to the GPL from your modified version.

dnl

dnl Written by David MacKenzie, with help from

dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,

dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.

dnl

divert(-1)dnl Throw away output until AC_INIT is called.

changequote([, ])

define(AC_ACVERSION, 2.13)

dnl Some old m4's don't support m4exit.  But they provide

dnl equivalent functionality by core dumping because of the

dnl long macros we define.

ifdef([__gnu__], , [errprint(Autoconf requires GNU m4.

Install it before installing Autoconf or set the

M4 environment variable to its path name.

)m4exit(2)])

undefine([eval])

undefine([include])

undefine([shift])

undefine([format])

dnl ### Defining macros

dnl m4 output diversions.  We let m4 output them all in order at the end,

dnl except that we explicitly undivert AC_DIVERSION_SED, AC_DIVERSION_CMDS,

dnl and AC_DIVERSION_ICMDS.

dnl AC_DIVERSION_NOTICE - 1 (= 0)	AC_REQUIRE'd #! /bin/sh line

define(AC_DIVERSION_NOTICE, 1)dnl	copyright notice & option help strings

define(AC_DIVERSION_INIT, 2)dnl		initialization code

define(AC_DIVERSION_NORMAL_4, 3)dnl	AC_REQUIRE'd code, 4 level deep

define(AC_DIVERSION_NORMAL_3, 4)dnl	AC_REQUIRE'd code, 3 level deep

define(AC_DIVERSION_NORMAL_2, 5)dnl	AC_REQUIRE'd code, 2 level deep

define(AC_DIVERSION_NORMAL_1, 6)dnl	AC_REQUIRE'd code, 1 level deep

define(AC_DIVERSION_NORMAL, 7)dnl	the tests and output code

define(AC_DIVERSION_SED, 8)dnl		variable substitutions in config.status

define(AC_DIVERSION_CMDS, 9)dnl		extra shell commands in config.status

define(AC_DIVERSION_ICMDS, 10)dnl	extra initialization in config.status

dnl Change the diversion stream to STREAM, while stacking old values.

dnl AC_DIVERT_PUSH(STREAM)

define(AC_DIVERT_PUSH,

[pushdef([AC_DIVERSION_CURRENT], $1)dnl

divert(AC_DIVERSION_CURRENT)dnl

])

dnl Change the diversion stream to its previous value, unstacking it.

dnl AC_DIVERT_POP()

define(AC_DIVERT_POP,

[popdef([AC_DIVERSION_CURRENT])dnl

divert(AC_DIVERSION_CURRENT)dnl

])

dnl Initialize the diversion setup.

define([AC_DIVERSION_CURRENT], AC_DIVERSION_NORMAL)

dnl This will be popped by AC_REQUIRE in AC_INIT.

pushdef([AC_DIVERSION_CURRENT], AC_DIVERSION_NOTICE)

dnl The prologue for Autoconf macros.

dnl AC_PRO(MACRO-NAME)

define(AC_PRO,

[define([AC_PROVIDE_$1], )dnl

ifelse(AC_DIVERSION_CURRENT, AC_DIVERSION_NORMAL,

[AC_DIVERT_PUSH(builtin(eval, AC_DIVERSION_CURRENT - 1))],

[pushdef([AC_DIVERSION_CURRENT], AC_DIVERSION_CURRENT)])dnl

])

dnl The Epilogue for Autoconf macros.

dnl AC_EPI()

define(AC_EPI,

[AC_DIVERT_POP()dnl

ifelse(AC_DIVERSION_CURRENT, AC_DIVERSION_NORMAL,

[undivert(AC_DIVERSION_NORMAL_4)dnl

undivert(AC_DIVERSION_NORMAL_3)dnl

undivert(AC_DIVERSION_NORMAL_2)dnl

undivert(AC_DIVERSION_NORMAL_1)dnl

])dnl

])

dnl Define a macro which automatically provides itself.  Add machinery

dnl so the macro automatically switches expansion to the diversion

dnl stack if it is not already using it.  In this case, once finished,

dnl it will bring back all the code accumulated in the diversion stack.

dnl This, combined with AC_REQUIRE, achieves the topological ordering of

dnl macros.  We don't use this macro to define some frequently called

dnl macros that are not involved in ordering constraints, to save m4

dnl processing.

dnl AC_DEFUN(NAME, EXPANSION)

define([AC_DEFUN],

[define($1, [AC_PRO([$1])$2[]AC_EPI()])])

dnl ### Initialization

dnl AC_INIT_NOTICE()

AC_DEFUN(AC_INIT_NOTICE,

[# Guess values for system-dependent variables and create Makefiles.

# Generated automatically using autoconf version] AC_ACVERSION [

# Copyright (C) 1992, 93, 94, 95, 96 Free Software Foundation, Inc.

#

# This configure script is free software; the Free Software Foundation

# gives unlimited permission to copy, distribute and modify it.

# Defaults:

ac_help=

ac_default_prefix=/usr/local

[#] Any additions from configure.in:])

dnl AC_PREFIX_DEFAULT(PREFIX)

AC_DEFUN(AC_PREFIX_DEFAULT,

[AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl

ac_default_prefix=$1

AC_DIVERT_POP()])

dnl AC_INIT_PARSE_ARGS()

AC_DEFUN(AC_INIT_PARSE_ARGS,

[

# Initialize some variables set by options.

# The variables have the same names as the options, with

# dashes changed to underlines.

build=NONE

cache_file=./config.cache

exec_prefix=NONE

host=NONE

no_create=

nonopt=NONE

no_recursion=

prefix=NONE

program_prefix=NONE

program_suffix=NONE

program_transform_name=s,x,x,

silent=

site=

srcdir=

target=NONE

verbose=

x_includes=NONE

x_libraries=NONE

dnl Installation directory options.

dnl These are left unexpanded so users can "make install exec_prefix=/foo"

dnl and all the variables that are supposed to be based on exec_prefix

dnl by default will actually change.

dnl Use braces instead of parens because sh, perl, etc. also accept them.

bindir='${exec_prefix}/bin'

sbindir='${exec_prefix}/sbin'

libexecdir='${exec_prefix}/libexec'

datadir='${prefix}/share'

sysconfdir='${prefix}/etc'

sharedstatedir='${prefix}/com'

localstatedir='${prefix}/var'

libdir='${exec_prefix}/lib'

includedir='${prefix}/include'

oldincludedir='/usr/include'

infodir='${prefix}/info'

mandir='${prefix}/man'

# Initialize some other variables.

subdirs=

MFLAGS= MAKEFLAGS=

SHELL=${CONFIG_SHELL-/bin/sh}

# Maximum number of lines to put in a shell here document.

ac_max_here_lines=12

ac_prev=

for ac_option

do

  # If the previous option needs an argument, assign it.

  if test -n "$ac_prev"; then

    eval "$ac_prev=\$ac_option"

    ac_prev=

    continue

  fi

  case "$ac_option" in

changequote(, )dnl

  -*=*) ac_optarg=`echo "$ac_option" | sed 's/[-_a-zA-Z0-9]*=//'` ;;

changequote([, ])dnl

  *) ac_optarg= ;;

  esac

  # Accept the important Cygnus configure options, so we can diagnose typos.

  case "$ac_option" in

  -bindir | --bindir | --bindi | --bind | --bin | --bi)

    ac_prev=bindir ;;

  -bindir=* | --bindir=* | --bindi=* | --bind=* | --bin=* | --bi=*)

    bindir="$ac_optarg" ;;

  -build | --build | --buil | --bui | --bu)

    ac_prev=build ;;

  -build=* | --build=* | --buil=* | --bui=* | --bu=*)

    build="$ac_optarg" ;;

  -cache-file | --cache-file | --cache-fil | --cache-fi \

  | --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)

    ac_prev=cache_file ;;

  -cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \

  | --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* | --c=*)

    cache_file="$ac_optarg" ;;

  -datadir | --datadir | --datadi | --datad | --data | --dat | --da)

    ac_prev=datadir ;;

  -datadir=* | --datadir=* | --datadi=* | --datad=* | --data=* | --dat=* \

  | --da=*)

    datadir="$ac_optarg" ;;

  -disable-* | --disable-*)

    ac_feature=`echo $ac_option|sed -e 's/-*disable-//'`

    # Reject names that are not valid shell variable names.

changequote(, )dnl

    if test -n "`echo $ac_feature| sed 's/[-a-zA-Z0-9_]//g'`"; then

changequote([, ])dnl

      AC_MSG_ERROR($ac_feature: invalid feature name)

    fi

    ac_feature=`echo $ac_feature| sed 's/-/_/g'`

    eval "enable_${ac_feature}=no" ;;

  -enable-* | --enable-*)

    ac_feature=`echo $ac_option|sed -e 's/-*enable-//' -e 's/=.*//'`

    # Reject names that are not valid shell variable names.

changequote(, )dnl

    if test -n "`echo $ac_feature| sed 's/[-_a-zA-Z0-9]//g'`"; then

changequote([, ])dnl

      AC_MSG_ERROR($ac_feature: invalid feature name)

    fi

    ac_feature=`echo $ac_feature| sed 's/-/_/g'`

    case "$ac_option" in

      *=*) ;;

      *) ac_optarg=yes ;;

    esac

    eval "enable_${ac_feature}='$ac_optarg'" ;;

  -exec-prefix | --exec_prefix | --exec-prefix | --exec-prefi \

  | --exec-pref | --exec-pre | --exec-pr | --exec-p | --exec- \

  | --exec | --exe | --ex)

    ac_prev=exec_prefix ;;

  -exec-prefix=* | --exec_prefix=* | --exec-prefix=* | --exec-prefi=* \

  | --exec-pref=* | --exec-pre=* | --exec-pr=* | --exec-p=* | --exec-=* \

  | --exec=* | --exe=* | --ex=*)

    exec_prefix="$ac_optarg" ;;

  -gas | --gas | --ga | --g)

    # Obsolete; use --with-gas.

    with_gas=yes ;;

  -help | --help | --hel | --he)

    # Omit some internal or obsolete options to make the list less imposing.

    # This message is too long to be a string in the A/UX 3.1 sh.

    cat << EOF

changequote(, )dnl

Usage: configure [options] [host]

Options: [defaults in brackets after descriptions]

Configuration:

  --cache-file=FILE       cache test results in FILE

  --help                  print this message

  --no-create             do not create output files

  --quiet, --silent       do not print \`checking...' messages

  --version               print the version of autoconf that created configure

Directory and file names:

  --prefix=PREFIX         install architecture-independent files in PREFIX

                          [$ac_default_prefix]

  --exec-prefix=EPREFIX   install architecture-dependent files in EPREFIX

                          [same as prefix]

  --bindir=DIR            user executables in DIR [EPREFIX/bin]

  --sbindir=DIR           system admin executables in DIR [EPREFIX/sbin]

  --libexecdir=DIR        program executables in DIR [EPREFIX/libexec]

  --datadir=DIR           read-only architecture-independent data in DIR

                          [PREFIX/share]

  --sysconfdir=DIR        read-only single-machine data in DIR [PREFIX/etc]

  --sharedstatedir=DIR    modifiable architecture-independent data in DIR

                          [PREFIX/com]

  --localstatedir=DIR     modifiable single-machine data in DIR [PREFIX/var]

  --libdir=DIR            object code libraries in DIR [EPREFIX/lib]

  --includedir=DIR        C header files in DIR [PREFIX/include]

  --oldincludedir=DIR     C header files for non-gcc in DIR [/usr/include]

  --infodir=DIR           info documentation in DIR [PREFIX/info]

  --mandir=DIR            man documentation in DIR [PREFIX/man]

  --srcdir=DIR            find the sources in DIR [configure dir or ..]

  --program-prefix=PREFIX prepend PREFIX to installed program names

  --program-suffix=SUFFIX append SUFFIX to installed program names

  --program-transform-name=PROGRAM

                          run sed PROGRAM on installed program names

EOF

    cat << EOF

Host type:

  --build=BUILD           configure for building on BUILD [BUILD=HOST]

  --host=HOST             configure for HOST [guessed]

  --target=TARGET         configure for TARGET [TARGET=HOST]

Features and packages:

  --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)

  --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]

  --with-PACKAGE[=ARG]    use PACKAGE [ARG=yes]

  --without-PACKAGE       do not use PACKAGE (same as --with-PACKAGE=no)

  --x-includes=DIR        X include files are in DIR

  --x-libraries=DIR       X library files are in DIR

changequote([, ])dnl

EOF

    if test -n "$ac_help"; then

      echo "--enable and --with options recognized:$ac_help"

    fi

    exit 0 ;;

  -host | --host | --hos | --ho)

    ac_prev=host ;;

  -host=* | --host=* | --hos=* | --ho=*)

    host="$ac_optarg" ;;

  -includedir | --includedir | --includedi | --included | --include \

  | --includ | --inclu | --incl | --inc)

    ac_prev=includedir ;;

  -includedir=* | --includedir=* | --includedi=* | --included=* | --include=* \

  | --includ=* | --inclu=* | --incl=* | --inc=*)

    includedir="$ac_optarg" ;;

  -infodir | --infodir | --infodi | --infod | --info | --inf)

    ac_prev=infodir ;;

  -infodir=* | --infodir=* | --infodi=* | --infod=* | --info=* | --inf=*)

    infodir="$ac_optarg" ;;

  -libdir | --libdir | --libdi | --libd)

    ac_prev=libdir ;;

  -libdir=* | --libdir=* | --libdi=* | --libd=*)

    libdir="$ac_optarg" ;;

  -libexecdir | --libexecdir | --libexecdi | --libexecd | --libexec \

  | --libexe | --libex | --libe)

    ac_prev=libexecdir ;;

  -libexecdir=* | --libexecdir=* | --libexecdi=* | --libexecd=* | --libexec=* \

  | --libexe=* | --libex=* | --libe=*)

    libexecdir="$ac_optarg" ;;

  -localstatedir | --localstatedir | --localstatedi | --localstated \

  | --localstate | --localstat | --localsta | --localst \

  | --locals | --local | --loca | --loc | --lo)

    ac_prev=localstatedir ;;

  -localstatedir=* | --localstatedir=* | --localstatedi=* | --localstated=* \

  | --localstate=* | --localstat=* | --localsta=* | --localst=* \

  | --locals=* | --local=* | --loca=* | --loc=* | --lo=*)

    localstatedir="$ac_optarg" ;;

  -mandir | --mandir | --mandi | --mand | --man | --ma | --m)

    ac_prev=mandir ;;

  -mandir=* | --mandir=* | --mandi=* | --mand=* | --man=* | --ma=* | --m=*)

    mandir="$ac_optarg" ;;

  -nfp | --nfp | --nf)

    # Obsolete; use --without-fp.

    with_fp=no ;;

  -no-create | --no-create | --no-creat | --no-crea | --no-cre \

  | --no-cr | --no-c)

    no_create=yes ;;

  -no-recursion | --no-recursion | --no-recursio | --no-recursi \

  | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r)

    no_recursion=yes ;;

  -oldincludedir | --oldincludedir | --oldincludedi | --oldincluded \

  | --oldinclude | --oldinclud | --oldinclu | --oldincl | --oldinc \

  | --oldin | --oldi | --old | --ol | --o)

    ac_prev=oldincludedir ;;

  -oldincludedir=* | --oldincludedir=* | --oldincludedi=* | --oldincluded=* \

  | --oldinclude=* | --oldinclud=* | --oldinclu=* | --oldincl=* | --oldinc=* \

  | --oldin=* | --oldi=* | --old=* | --ol=* | --o=*)

    oldincludedir="$ac_optarg" ;;

  -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)

    ac_prev=prefix ;;

  -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)

    prefix="$ac_optarg" ;;

  -program-prefix | --program-prefix | --program-prefi | --program-pref \

  | --program-pre | --program-pr | --program-p)

    ac_prev=program_prefix ;;

  -program-prefix=* | --program-prefix=* | --program-prefi=* \

  | --program-pref=* | --program-pre=* | --program-pr=* | --program-p=*)

    program_prefix="$ac_optarg" ;;

  -program-suffix | --program-suffix | --program-suffi | --program-suff \

  | --program-suf | --program-su | --program-s)

    ac_prev=program_suffix ;;

  -program-suffix=* | --program-suffix=* | --program-suffi=* \

  | --program-suff=* | --program-suf=* | --program-su=* | --program-s=*)

    program_suffix="$ac_optarg" ;;

  -program-transform-name | --program-transform-name \

  | --program-transform-nam | --program-transform-na \

  | --program-transform-n | --program-transform- \

  | --program-transform | --program-transfor \

  | --program-transfo | --program-transf \

  | --program-trans | --program-tran \

  | --progr-tra | --program-tr | --program-t)

    ac_prev=program_transform_name ;;

  -program-transform-name=* | --program-transform-name=* \

  | --program-transform-nam=* | --program-transform-na=* \

  | --program-transform-n=* | --program-transform-=* \

  | --program-transform=* | --program-transfor=* \

  | --program-transfo=* | --program-transf=* \

  | --program-trans=* | --program-tran=* \

  | --progr-tra=* | --program-tr=* | --program-t=*)

    program_transform_name="$ac_optarg" ;;

  -q | -quiet | --quiet | --quie | --qui | --qu | --q \

  | -silent | --silent | --silen | --sile | --sil)

    silent=yes ;;

  -sbindir | --sbindir | --sbindi | --sbind | --sbin | --sbi | --sb)

    ac_prev=sbindir ;;

  -sbindir=* | --sbindir=* | --sbindi=* | --sbind=* | --sbin=* \

  | --sbi=* | --sb=*)

    sbindir="$ac_optarg" ;;

  -sharedstatedir | --sharedstatedir | --sharedstatedi \

  | --sharedstated | --sharedstate | --sharedstat | --sharedsta \

  | --sharedst | --shareds | --shared | --share | --shar \

  | --sha | --sh)

    ac_prev=sharedstatedir ;;

  -sharedstatedir=* | --sharedstatedir=* | --sharedstatedi=* \

  | --sharedstated=* | --sharedstate=* | --sharedstat=* | --sharedsta=* \

  | --sharedst=* | --shareds=* | --shared=* | --share=* | --shar=* \

  | --sha=* | --sh=*)

    sharedstatedir="$ac_optarg" ;;

  -site | --site | --sit)

    ac_prev=site ;;

  -site=* | --site=* | --sit=*)

    site="$ac_optarg" ;;

  -srcdir | --srcdir | --srcdi | --srcd | --src | --sr)

    ac_prev=srcdir ;;

  -srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)

    srcdir="$ac_optarg" ;;

  -sysconfdir | --sysconfdir | --sysconfdi | --sysconfd | --sysconf \

  | --syscon | --sysco | --sysc | --sys | --sy)

    ac_prev=sysconfdir ;;

  -sysconfdir=* | --sysconfdir=* | --sysconfdi=* | --sysconfd=* | --sysconf=* \

  | --syscon=* | --sysco=* | --sysc=* | --sys=* | --sy=*)

    sysconfdir="$ac_optarg" ;;

  -target | --target | --targe | --targ | --tar | --ta | --t)

    ac_prev=target ;;

  -target=* | --target=* | --targe=* | --targ=* | --tar=* | --ta=* | --t=*)

    target="$ac_optarg" ;;

  -v | -verbose | --verbose | --verbos | --verbo | --verb)

    verbose=yes ;;

  -version | --version | --versio | --versi | --vers)

    echo "configure generated by autoconf version AC_ACVERSION"

    exit 0 ;;

  -with-* | --with-*)

    ac_package=`echo $ac_option|sed -e 's/-*with-//' -e 's/=.*//'`

    # Reject names that are not valid shell variable names.

changequote(, )dnl

    if test -n "`echo $ac_package| sed 's/[-_a-zA-Z0-9]//g'`"; then

changequote([, ])dnl

      AC_MSG_ERROR($ac_package: invalid package name)

    fi

    ac_package=`echo $ac_package| sed 's/-/_/g'`

    case "$ac_option" in

      *=*) ;;

      *) ac_optarg=yes ;;

    esac

    eval "with_${ac_package}='$ac_optarg'" ;;

  -without-* | --without-*)

    ac_package=`echo $ac_option|sed -e 's/-*without-//'`

    # Reject names that are not valid shell variable names.

changequote(, )dnl

    if test -n "`echo $ac_package| sed 's/[-a-zA-Z0-9_]//g'`"; then

changequote([, ])dnl

      AC_MSG_ERROR($ac_package: invalid package name)

    fi

    ac_package=`echo $ac_package| sed 's/-/_/g'`

    eval "with_${ac_package}=no" ;;

  --x)

    # Obsolete; use --with-x.

    with_x=yes ;;

  -x-includes | --x-includes | --x-include | --x-includ | --x-inclu \

  | --x-incl | --x-inc | --x-in | --x-i)

    ac_prev=x_includes ;;

  -x-includes=* | --x-includes=* | --x-include=* | --x-includ=* | --x-inclu=* \

  | --x-incl=* | --x-inc=* | --x-in=* | --x-i=*)

    x_includes="$ac_optarg" ;;

  -x-libraries | --x-libraries | --x-librarie | --x-librari \

  | --x-librar | --x-libra | --x-libr | --x-lib | --x-li | --x-l)

    ac_prev=x_libraries ;;

  -x-libraries=* | --x-libraries=* | --x-librarie=* | --x-librari=* \

  | --x-librar=* | --x-libra=* | --x-libr=* | --x-lib=* | --x-li=* | --x-l=*)

    x_libraries="$ac_optarg" ;;

  -*) AC_MSG_ERROR([$ac_option: invalid option; use --help to show usage])

    ;;

  *)

changequote(, )dnl

    if test -n "`echo $ac_option| sed 's/[-a-z0-9.]//g'`"; then

changequote([, ])dnl

      AC_MSG_WARN($ac_option: invalid host type)

    fi

    if test "x$nonopt" != xNONE; then

      AC_MSG_ERROR(can only configure for one host and one target at a time)

    fi

    nonopt="$ac_option"

    ;;

  esac

done

if test -n "$ac_prev"; then

  AC_MSG_ERROR(missing argument to --`echo $ac_prev | sed 's/_/-/g'`)

fi

])

dnl Try to have only one #! line, so the script doesn't look funny

dnl for users of AC_REVISION.

dnl AC_INIT_BINSH()

AC_DEFUN(AC_INIT_BINSH,

[#! /bin/sh

])

dnl AC_INIT(UNIQUE-FILE-IN-SOURCE-DIR)

AC_DEFUN(AC_INIT,

[sinclude(acsite.m4)dnl

sinclude(./aclocal.m4)dnl

AC_REQUIRE([AC_INIT_BINSH])dnl

AC_INIT_NOTICE

AC_DIVERT_POP()dnl to NORMAL

AC_DIVERT_PUSH(AC_DIVERSION_INIT)dnl

AC_INIT_PARSE_ARGS

AC_INIT_PREPARE($1)dnl

AC_DIVERT_POP()dnl to NORMAL

])

dnl AC_INIT_PREPARE(UNIQUE-FILE-IN-SOURCE-DIR)

AC_DEFUN(AC_INIT_PREPARE,

[trap 'rm -fr conftest* confdefs* core core.* *.core $ac_clean_files; exit 1' 1 2 15

# File descriptor usage:

# 0 standard input

# 1 file creation

# 2 errors and warnings

# 3 some systems may open it to /dev/tty

# 4 used on the Kubota Titan

define(AC_FD_MSG, 6)dnl

[#] AC_FD_MSG checking for... messages and results

define(AC_FD_CC, 5)dnl

[#] AC_FD_CC compiler messages saved in config.log

if test "$silent" = yes; then

  exec AC_FD_MSG>/dev/null

else

  exec AC_FD_MSG>&1

fi

exec AC_FD_CC>./config.log

echo "\

This file contains any messages produced by compilers while

running configure, to aid debugging if configure makes a mistake.

" 1>&AC_FD_CC

# Strip out --no-create and --no-recursion so they do not pile up.

# Also quote any args containing shell metacharacters.

ac_configure_args=

for ac_arg

do

  case "$ac_arg" in

  -no-create | --no-create | --no-creat | --no-crea | --no-cre \

  | --no-cr | --no-c) ;;

  -no-recursion | --no-recursion | --no-recursio | --no-recursi \

  | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;

changequote(<<, >>)dnl

dnl If you change this globbing pattern, test it on an old shell --

dnl it's sensitive.  Putting any kind of quote in it causes syntax errors.

  *" "*|*"	"*|*[\[\]\~\<<#>>\$\^\&\*\(\)\{\}\\\|\;\<\>\?]*)

  ac_configure_args="$ac_configure_args '$ac_arg'" ;;

changequote([, ])dnl

  *) ac_configure_args="$ac_configure_args $ac_arg" ;;

  esac

done

# NLS nuisances.

# Only set these to C if already set.  These must not be set unconditionally

# because not all systems understand e.g. LANG=C (notably SCO).

# Fixing LC_MESSAGES prevents Solaris sh from translating var values in `set'!

# Non-C LC_CTYPE values break the ctype check.

if test "${LANG+set}"   = set; then LANG=C;   export LANG;   fi

if test "${LC_ALL+set}" = set; then LC_ALL=C; export LC_ALL; fi

if test "${LC_MESSAGES+set}" = set; then LC_MESSAGES=C; export LC_MESSAGES; fi

if test "${LC_CTYPE+set}"    = set; then LC_CTYPE=C;    export LC_CTYPE;    fi

# confdefs.h avoids OS command line length limits that DEFS can exceed.

rm -rf conftest* confdefs.h

# AIX cpp loses on an empty file, so make sure it contains at least a newline.

echo > confdefs.h

# A filename unique to this package, relative to the directory that

# configure is in, which we can look for to find out if srcdir is correct.

ac_unique_file=$1

# Find the source files, if location was not specified.

if test -z "$srcdir"; then

  ac_srcdir_defaulted=yes

  # Try the directory containing this script, then its parent.

  ac_prog=[$]0

changequote(, )dnl

  ac_confdir=`echo $ac_prog|sed 's%/[^/][^/]*$%%'`

changequote([, ])dnl

  test "x$ac_confdir" = "x$ac_prog" && ac_confdir=.

  srcdir=$ac_confdir

  if test ! -r $srcdir/$ac_unique_file; then

    srcdir=..

  fi

else

  ac_srcdir_defaulted=no

fi

if test ! -r $srcdir/$ac_unique_file; then

  if test "$ac_srcdir_defaulted" = yes; then

    AC_MSG_ERROR(can not find sources in $ac_confdir or ..)

  else

    AC_MSG_ERROR(can not find sources in $srcdir)

  fi

fi

dnl Double slashes in pathnames in object file debugging info

dnl mess up M-x gdb in Emacs.

changequote(, )dnl

srcdir=`echo "${srcdir}" | sed 's%\([^/]\)/*$%\1%'`

changequote([, ])dnl

dnl Let the site file select an alternate cache file if it wants to.

AC_SITE_LOAD

AC_CACHE_LOAD

AC_LANG_C

dnl By default always use an empty string as the executable

dnl extension.  Only change it if the script calls AC_EXEEXT.

ac_exeext=

dnl By default assume that objects files use an extension of .o.  Only

dnl change it if the script calls AC_OBJEXT.

ac_objext=o

AC_PROG_ECHO_N

dnl Substitute for predefined variables.

AC_SUBST(SHELL)dnl

AC_SUBST(CFLAGS)dnl

AC_SUBST(CPPFLAGS)dnl

AC_SUBST(CXXFLAGS)dnl

AC_SUBST(FFLAGS)dnl

AC_SUBST(DEFS)dnl

AC_SUBST(LDFLAGS)dnl

AC_SUBST(LIBS)dnl

AC_SUBST(exec_prefix)dnl

AC_SUBST(prefix)dnl

AC_SUBST(program_transform_name)dnl

dnl Installation directory options.

AC_SUBST(bindir)dnl

AC_SUBST(sbindir)dnl

AC_SUBST(libexecdir)dnl

AC_SUBST(datadir)dnl

AC_SUBST(sysconfdir)dnl

AC_SUBST(sharedstatedir)dnl

AC_SUBST(localstatedir)dnl

AC_SUBST(libdir)dnl

AC_SUBST(includedir)dnl

AC_SUBST(oldincludedir)dnl

AC_SUBST(infodir)dnl

AC_SUBST(mandir)dnl

])

dnl ### Selecting optional features

dnl AC_ARG_ENABLE(FEATURE, HELP-STRING, ACTION-IF-TRUE [, ACTION-IF-FALSE])

AC_DEFUN(AC_ARG_ENABLE,

[AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl

ac_help="$ac_help

[$2]"

AC_DIVERT_POP()dnl

[#] Check whether --enable-[$1] or --disable-[$1] was given.

if test "[${enable_]patsubst([$1], -, _)+set}" = set; then

  enableval="[$enable_]patsubst([$1], -, _)"

  ifelse([$3], , :, [$3])

ifelse([$4], , , [else

  $4

])dnl

fi

])

AC_DEFUN(AC_ENABLE,

[AC_OBSOLETE([$0], [; instead use AC_ARG_ENABLE])dnl

AC_ARG_ENABLE([$1], [  --enable-$1], [$2], [$3])dnl

])

dnl ### Working with optional software

dnl AC_ARG_WITH(PACKAGE, HELP-STRING, ACTION-IF-TRUE [, ACTION-IF-FALSE])

AC_DEFUN(AC_ARG_WITH,

[AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl

ac_help="$ac_help

[$2]"

AC_DIVERT_POP()dnl

[#] Check whether --with-[$1] or --without-[$1] was given.

if test "[${with_]patsubst([$1], -, _)+set}" = set; then

  withval="[$with_]patsubst([$1], -, _)"

  ifelse([$3], , :, [$3])

ifelse([$4], , , [else

  $4

])dnl

fi

])

AC_DEFUN(AC_WITH,

[AC_OBSOLETE([$0], [; instead use AC_ARG_WITH])dnl

AC_ARG_WITH([$1], [  --with-$1], [$2], [$3])dnl

])

dnl ### Transforming program names.

dnl AC_ARG_PROGRAM()

AC_DEFUN(AC_ARG_PROGRAM,

[if test "$program_transform_name" = s,x,x,; then

  program_transform_name=

else

  # Double any \ or $.  echo might interpret backslashes.

  cat <<\EOF_SED > conftestsed

s,\\,\\\\,g; s,\$,$$,g

EOF_SED

  program_transform_name="`echo $program_transform_name|sed -f conftestsed`"

  rm -f conftestsed

fi

test "$program_prefix" != NONE &&

  program_transform_name="s,^,${program_prefix},; $program_transform_name"

# Use a double $ so make ignores it.

test "$program_suffix" != NONE &&

  program_transform_name="s,\$\$,${program_suffix},; $program_transform_name"

# sed with no file args requires a program.

test "$program_transform_name" = "" && program_transform_name="s,x,x,"

])

dnl ### Version numbers

dnl AC_REVISION(REVISION-INFO)

AC_DEFUN(AC_REVISION,

[AC_REQUIRE([AC_INIT_BINSH])dnl

[# From configure.in] translit([$1], $")])

dnl Subroutines of AC_PREREQ.

dnl Change the dots in NUMBER into commas.

dnl AC_PREREQ_SPLIT(NUMBER)

define(AC_PREREQ_SPLIT,

[translit($1, ., [, ])])

dnl Default the ternary version number to 0 (e.g., 1, 7 -> 1, 7, 0).

dnl AC_PREREQ_CANON(MAJOR, MINOR [,TERNARY])

define(AC_PREREQ_CANON,

[$1, $2, ifelse([$3], , 0, [$3])])

dnl Complain and exit if version number 1 is less than version number 2.

dnl PRINTABLE2 is the printable version of version number 2.

dnl AC_PREREQ_COMPARE(MAJOR1, MINOR1, TERNARY1, MAJOR2, MINOR2, TERNARY2,

dnl                   PRINTABLE2)

define(AC_PREREQ_COMPARE,

[ifelse(builtin([eval],

[$3 + $2 * 1000 + $1 * 1000000 < $6 + $5 * 1000 + $4 * 1000000]), 1,

[errprint(dnl

FATAL ERROR: Autoconf version $7 or higher is required for this script

)m4exit(3)])])

dnl Complain and exit if the Autoconf version is less than VERSION.

dnl AC_PREREQ(VERSION)

define(AC_PREREQ,

[AC_PREREQ_COMPARE(AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)),

AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])), [$1])])

dnl ### Getting the canonical system type

dnl Find install-sh, config.sub, config.guess, and Cygnus configure

dnl in directory DIR.  These are auxiliary files used in configuration.

dnl DIR can be either absolute or relative to $srcdir.

dnl AC_CONFIG_AUX_DIR(DIR)

AC_DEFUN(AC_CONFIG_AUX_DIR,

[AC_CONFIG_AUX_DIRS($1 $srcdir/$1)])

dnl The default is `$srcdir' or `$srcdir/..' or `$srcdir/../..'.

dnl There's no need to call this macro explicitly; just AC_REQUIRE it.

AC_DEFUN(AC_CONFIG_AUX_DIR_DEFAULT,

[AC_CONFIG_AUX_DIRS($srcdir $srcdir/.. $srcdir/../..)])

dnl Internal subroutine.

dnl Search for the configuration auxiliary files in directory list $1.

dnl We look only for install-sh, so users of AC_PROG_INSTALL

dnl do not automatically need to distribute the other auxiliary files.

dnl AC_CONFIG_AUX_DIRS(DIR ...)

AC_DEFUN(AC_CONFIG_AUX_DIRS,

[ac_aux_dir=

for ac_dir in $1; do

  if test -f $ac_dir/install-sh; then

    ac_aux_dir=$ac_dir

    ac_install_sh="$ac_aux_dir/install-sh -c"

    break

  elif test -f $ac_dir/install.sh; then

    ac_aux_dir=$ac_dir

    ac_install_sh="$ac_aux_dir/install.sh -c"

    break

  fi

done

if test -z "$ac_aux_dir"; then

  AC_MSG_ERROR([can not find install-sh or install.sh in $1])

fi

ac_config_guess=$ac_aux_dir/config.guess

ac_config_sub=$ac_aux_dir/config.sub

ac_configure=$ac_aux_dir/configure # This should be Cygnus configure.

AC_PROVIDE([AC_CONFIG_AUX_DIR_DEFAULT])dnl

])