dnl

dnl autoconf for Pacemaker

dnl

dnl Copyright 2009-2019 the Pacemaker project contributors

dnl

dnl The version control history for this file may have further details.

dnl

dnl This source code is licensed under the GNU General Public License version 2

dnl or later (GPLv2+) WITHOUT ANY WARRANTY.

dnl ===============================================

dnl Bootstrap

dnl ===============================================

AC_PREREQ(2.64)

AC_CONFIG_MACRO_DIR([m4])

AC_DEFUN([AC_DATAROOTDIR_CHECKED])

dnl Suggested structure:

dnl     information on the package

dnl     checks for programs

dnl     checks for libraries

dnl     checks for header files

dnl     checks for types

dnl     checks for structures

dnl     checks for compiler characteristics

dnl     checks for library functions

dnl     checks for system services

m4_include([version.m4])

AC_INIT([pacemaker], VERSION_NUMBER, [users@clusterlabs.org], [pacemaker],

        PCMK_URL)

PCMK_FEATURES=""

AC_CONFIG_AUX_DIR(.)

AC_CANONICAL_HOST

dnl Where #defines go (e.g. `AC_CHECK_HEADERS' below)

dnl

dnl Internal header: include/config.h

dnl   - Contains ALL defines

dnl   - include/config.h.in is generated automatically by autoheader

dnl   - NOT to be included in any header files except crm_internal.h

dnl     (which is also not to be included in any other header files)

dnl

dnl External header: include/crm_config.h

dnl   - Contains a subset of defines checked here

dnl   - Manually edit include/crm_config.h.in to have configure include

dnl     new defines

dnl   - Should not include HAVE_* defines

dnl   - Safe to include anywhere

AC_CONFIG_HEADERS([include/config.h include/crm_config.h])

dnl 1.11:           minimum automake version required

dnl foreign:        don't require GNU-standard top-level files

dnl tar-ustar:      use (older) POSIX variant of generated tar rather than v7

dnl silent-rules:   allow "--enable-silent-rules" (no-op in 1.13+)

dnl subdir-objects: keep .o's with their .c's (no-op in 2.0+)

AM_INIT_AUTOMAKE([1.11 foreign tar-ustar silent-rules subdir-objects])

dnl Example 2.4. Silent Custom Rule to Generate a File

dnl %-bar.pc: %.pc

dnl	$(AM_V_GEN)$(LN_S) $(notdir $^) $@

dnl Versioned attributes implementation is not yet production-ready

AC_DEFINE_UNQUOTED(ENABLE_VERSIONED_ATTRS, 0, [Enable versioned attributes])

CC_IN_CONFIGURE=yes

export CC_IN_CONFIGURE

LDD=ldd

dnl ========================================================================

dnl Compiler characteristics

dnl ========================================================================

AC_PROG_CC dnl Can force other with environment variable "CC".

AC_PROG_CC_STDC

AC_PROG_CXX dnl C++ is not needed for build, just maintainer utilities

gl_EARLY

# We expressly don't want to introduce OpenSSL dependency by default.

gl_SET_CRYPTO_CHECK_DEFAULT([no])

gl_INIT

LT_INIT([dlopen])

LTDL_INIT([convenience])

AC_TYPE_SIZE_T

AC_CHECK_SIZEOF(char)

AC_CHECK_SIZEOF(short)

AC_CHECK_SIZEOF(int)

AC_CHECK_SIZEOF(long)

AC_CHECK_SIZEOF(long long)

dnl ===============================================

dnl Helpers

dnl ===============================================

cc_supports_flag() {

    local CFLAGS="-Werror $@"

    AC_MSG_CHECKING(whether $CC supports "$@")

    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[ ]])],

                      [RC=0; AC_MSG_RESULT(yes)],

                      [RC=1; AC_MSG_RESULT(no)])

    return $RC

}

# Some tests need to use their own CFLAGS

cc_temp_flags() {

    ac_save_CFLAGS="$CFLAGS"

    CFLAGS="$*"

}

cc_restore_flags() {

    CFLAGS=$ac_save_CFLAGS

}

dnl ===============================================

dnl Configure Options

dnl ===============================================

dnl --enable-* options

AC_ARG_ENABLE([ansi],

    [AS_HELP_STRING([--enable-ansi],

        [force GCC to compile to ANSI standard for older compilers. @<:@no@:>@])],

)

AC_ARG_ENABLE([fatal-warnings],

    [AS_HELP_STRING([--enable-fatal-warnings],

        [enable pedantic and fatal warnings for gcc @<:@yes@:>@])],

)

AC_ARG_ENABLE([quiet],

    [AS_HELP_STRING([--enable-quiet],

        [suppress make output unless there is an error @<:@no@:>@])],

)

AC_ARG_ENABLE([no-stack],

    [AS_HELP_STRING([--enable-no-stack],

        [build only the scheduler and its requirements @<:@no@:>@])],

)

AC_ARG_ENABLE([upstart],

    [AS_HELP_STRING([--enable-upstart],

        [enable support for managing resources via Upstart @<:@try@:>@])],

    [],

    [enable_upstart=try],

)

AC_ARG_ENABLE([systemd],

    [AS_HELP_STRING([--enable-systemd],

        [enable support for managing resources via systemd @<:@try@:>@])],

    [],

    [enable_systemd=try],

)

AC_ARG_ENABLE([hardening],

    [AS_HELP_STRING([--enable-hardening],

        [harden the resulting executables/libraries @<:@try@:>@])],

    [ HARDENING="${enableval}" ],

    [ HARDENING=try ],

)

# By default, we add symlinks at the pre-2.0.0 daemon name locations, so that:

# (1) tools that directly invoke those names for metadata etc. will still work

# (2) this installation can be used in a bundle container image used with

#     cluster hosts running Pacemaker 1.1.17+

# If you know your target systems will not have any need for it, you can

# disable this option. Once the above use cases are no longer in wide use, we

# can disable this option by default, and once we no longer want to support

# them at all, we can drop the option altogether.

AC_ARG_ENABLE([legacy-links],

    [AS_HELP_STRING([--enable-legacy-links],

        [add symlinks for old daemon names @<:@yes@:>@])],

    [ LEGACY_LINKS="${enableval}" ],

    [ LEGACY_LINKS=yes ],

)

AM_CONDITIONAL(BUILD_LEGACY_LINKS, test "x${LEGACY_LINKS}" = "xyes")

dnl --with-* options

AC_DEFUN([VERSION_ARG],

    [AC_ARG_WITH([version],

        [AS_HELP_STRING([--with-version=VERSION],

            [override package version @<:@$1@:>@])],

        [ PACKAGE_VERSION="$withval" ])]

)

VERSION_ARG(VERSION_NUMBER)

AC_ARG_WITH([corosync],

    [AS_HELP_STRING([--with-corosync],

        [support the Corosync messaging and membership layer])],

    [ SUPPORT_CS=$withval ],

    [ SUPPORT_CS=try ],

)

AC_ARG_WITH([nagios],

    [AS_HELP_STRING([--with-nagios],

        [support nagios remote monitoring])],

    [ SUPPORT_NAGIOS=$withval ],

    [ SUPPORT_NAGIOS=try ],

)

AC_ARG_WITH([nagios-plugin-dir],

    [AS_HELP_STRING([--with-nagios-plugin-dir=DIR],

        [directory for nagios plugins @<:@LIBEXECDIR/nagios/plugins@:>@])],

    [ NAGIOS_PLUGIN_DIR="$withval" ]

)

AC_ARG_WITH([nagios-metadata-dir],

    [AS_HELP_STRING([--with-nagios-metadata-dir=DIR],

        [directory for nagios plugins metadata @<:@DATADIR/nagios/plugins-metadata@:>@])],

    [ NAGIOS_METADATA_DIR="$withval" ]

)

AC_ARG_WITH([acl],

    [AS_HELP_STRING([--with-acl],

        [support CIB ACL])],

    [ SUPPORT_ACL=$withval ],

    [ SUPPORT_ACL=yes ],

)

AC_ARG_WITH([cibsecrets],

    [AS_HELP_STRING([--with-cibsecrets],

        [support separate file for CIB secrets])],

    [ SUPPORT_CIBSECRETS=$withval ],

    [ SUPPORT_CIBSECRETS=no ],

)

PCMK_GNUTLS_PRIORITIES="NORMAL"

AC_ARG_WITH([gnutls-priorities],

    [AS_HELP_STRING([--with-gnutls-priorities],

        [default GnuTLS cipher priorities @<:@NORMAL@:>@])],

    [ test x"$withval" = x"no" || PCMK_GNUTLS_PRIORITIES="$withval" ]

)

INITDIR=""

AC_ARG_WITH([initdir],

    [AS_HELP_STRING([--with-initdir=DIR],

        [directory for init (rc) scripts])],

    [ INITDIR="$withval" ]

)

systemdsystemunitdir="${systemdsystemunitdir-}"

AC_ARG_WITH([systemdsystemunitdir],

    [AS_HELP_STRING([--with-systemdsystemunitdir=DIR],

        [directory for systemd unit files (advanced option: must match what systemd uses)])],

    [ systemdsystemunitdir="$withval" ]

)

SUPPORT_PROFILING=0

AC_ARG_WITH([profiling],

    [AS_HELP_STRING([--with-profiling],

        [disable optimizations for effective profiling])],

    [ SUPPORT_PROFILING=$withval ]

)

AC_ARG_WITH([coverage],

    [AS_HELP_STRING([--with-coverage],

        [disable optimizations for effective profiling])],

    [ SUPPORT_COVERAGE=$withval ]

)

PUBLICAN_BRAND="common"

AC_ARG_WITH([brand],

    [AS_HELP_STRING([--with-brand=brand],

        [brand to use for generated documentation (set empty for no docs) @<:@common@:>@])],

    [ test x"$withval" = x"no" || PUBLICAN_BRAND="$withval" ]

)

AC_SUBST(PUBLICAN_BRAND)

BUG_URL=""

AC_ARG_WITH([bug-url],

    [AS_HELP_STRING([--with-bug-url=DIR],

        [address where users should submit bug reports @<:@https://bugs.clusterlabs.org/enter_bug.cgi?product=Pacemaker@:>@])],

    [ BUG_URL="$withval" ]

)

CONFIGDIR=""

AC_ARG_WITH([configdir],

    [AS_HELP_STRING([--with-configdir=DIR],

        [directory for Pacemaker configuration file @<:@SYSCONFDIR/sysconfig@:>@])],

    [ CONFIGDIR="$withval" ]

)

CRM_LOG_DIR=""

AC_ARG_WITH([logdir],

    [AS_HELP_STRING([--with-logdir=DIR],

        [directory for Pacemaker log file @<:@LOCALSTATEDIR/log/pacemaker@:>@])],

    [ CRM_LOG_DIR="$withval" ]

)

CRM_BUNDLE_DIR=""

AC_ARG_WITH([bundledir],

    [AS_HELP_STRING([--with-bundledir=DIR],

        [directory for Pacemaker bundle logs @<:@LOCALSTATEDIR/log/pacemaker/bundles@:>@])],

    [ CRM_BUNDLE_DIR="$withval" ]

)

dnl The not-yet-released autoconf 2.70 will have a --runstatedir option.

dnl Until that's available, emulate it with our own --with-runstatedir.

pcmk_runstatedir=""

AC_ARG_WITH([runstatedir],

    [AS_HELP_STRING([--with-runstatedir=DIR],

        [modifiable per-process data @<:@LOCALSTATEDIR/run@:>@ (ignored if --runstatedir is available)])],

    [ pcmk_runstatedir="$withval" ]

)

dnl This defaults to /usr/lib rather than libdir because it's determined by the

dnl OCF project and not pacemaker. Even if a user wants to install pacemaker to

dnl /usr/local or such, the OCF agents will be expected in their usual

dnl location. However, we do give the user the option to override it.

OCF_ROOT_DIR="/usr/lib/ocf"

AC_ARG_WITH([ocfdir],

    [AS_HELP_STRING([--with-ocfdir=DIR],

        [OCF resource agent root directory (advanced option: changing this may break other cluster components unless similarly configured) @<:@/usr/lib/ocf@:>@])],

    [ OCF_ROOT_DIR="$withval" ]

)

AC_SUBST(OCF_ROOT_DIR)

CRM_DAEMON_USER=""

AC_ARG_WITH([daemon-user],

    [AS_HELP_STRING([--with-daemon-user=USER],

        [user to run unprivileged Pacemaker daemons as (advanced option: changing this may break other cluster components unless similarly configured) @<:@hacluster@:>@])],

    [ CRM_DAEMON_USER="$withval" ]

)

CRM_DAEMON_GROUP=""

AC_ARG_WITH([daemon-group],

    [AS_HELP_STRING([--with-daemon-group=GROUP],

        [group to run unprivileged Pacemaker daemons as (advanced option: changing this may break other cluster components unless similarly configured) @<:@haclient@:>@])],

    [ CRM_DAEMON_GROUP="$withval" ]

)

dnl Deprecated options

AC_ARG_WITH([pkg-name],

    [AS_HELP_STRING([--with-pkg-name=name],

        [deprecated and unused (will be removed in a future release)])],

)

AC_ARG_WITH([pkgname],

    [AS_HELP_STRING([--with-pkgname=name],

        [deprecated and unused (will be removed in a future release)])],

)

dnl ===============================================

dnl General Processing

dnl ===============================================

AC_DEFINE_UNQUOTED(PACEMAKER_VERSION, "$PACKAGE_VERSION",

                   [Current pacemaker version])

PACKAGE_SERIES=`echo $PACKAGE_VERSION | awk -F. '{ print $1"."$2 }'`

AC_SUBST(PACKAGE_SERIES)

AC_SUBST(PACKAGE_VERSION)

AC_PROG_LN_S

AC_PROG_MKDIR_P

if cc_supports_flag -Werror; then

    WERROR="-Werror"

else

    WERROR=""

fi

# Normalize enable_fatal_warnings (defaulting to yes, when compiler supports it)

if test "x${enable_fatal_warnings}" != "xno" ; then

    if test "$GCC" = "yes" && test "x${WERROR}" != "x" ; then

        enable_fatal_warnings=yes

    else

        AC_MSG_NOTICE(Compiler does not support fatal warnings)

        enable_fatal_warnings=no

    fi

fi

INIT_EXT=""

echo Our Host OS: $host_os/$host

AC_MSG_NOTICE(Sanitizing prefix: ${prefix})

case $prefix in

    NONE)

        prefix=/usr

        dnl Fix default variables - "prefix" variable if not specified

        if test "$localstatedir" = "\${prefix}/var"; then

            localstatedir="/var"

        fi

        if test "$sysconfdir" = "\${prefix}/etc"; then

            sysconfdir="/etc"

        fi

        ;;

esac

AC_MSG_NOTICE(Sanitizing exec_prefix: ${exec_prefix})

case $exec_prefix in

    prefix|NONE)

        exec_prefix=$prefix

        ;;

esac

AC_MSG_NOTICE(Sanitizing INITDIR: ${INITDIR})

case $INITDIR in

    prefix) INITDIR=$prefix;;

    "")

        AC_MSG_CHECKING(which init (rc) directory to use)

        for initdir in /etc/init.d /etc/rc.d/init.d /sbin/init.d \

            /usr/local/etc/rc.d /etc/rc.d

        do

            if

                test -d $initdir

            then

                INITDIR=$initdir

                break

            fi

        done

        AC_MSG_RESULT($INITDIR)

        ;;

esac

AC_SUBST(INITDIR)

AC_MSG_NOTICE(Sanitizing libdir: ${libdir})

case $libdir in

    prefix|NONE)

        AC_MSG_CHECKING(which lib directory to use)

        for aDir in lib64 lib

        do

            trydir="${exec_prefix}/${aDir}"

            if

                test -d ${trydir}

            then

                libdir=${trydir}

                break

            fi

        done

        AC_MSG_RESULT($libdir);

        ;;

esac

dnl Expand autoconf variables so that we don't end up with '${prefix}'

dnl in #defines and python scripts

dnl NOTE: Autoconf deliberately leaves them unexpanded to allow

dnl    make exec_prefix=/foo install

dnl No longer being able to do this seems like no great loss to me...

eval prefix="`eval echo ${prefix}`"

eval exec_prefix="`eval echo ${exec_prefix}`"

eval bindir="`eval echo ${bindir}`"

eval sbindir="`eval echo ${sbindir}`"

eval libexecdir="`eval echo ${libexecdir}`"

eval datadir="`eval echo ${datadir}`"

eval sysconfdir="`eval echo ${sysconfdir}`"

eval sharedstatedir="`eval echo ${sharedstatedir}`"

eval localstatedir="`eval echo ${localstatedir}`"

eval libdir="`eval echo ${libdir}`"

eval includedir="`eval echo ${includedir}`"

eval oldincludedir="`eval echo ${oldincludedir}`"

eval infodir="`eval echo ${infodir}`"

eval mandir="`eval echo ${mandir}`"

dnl Home-grown variables

if [ test "x${runstatedir}" = "x" ]; then

    if [ test "x${pcmk_runstatedir}" = "x" ]; then

        runstatedir="${localstatedir}/run"

    else

        runstatedir="${pcmk_runstatedir}"

    fi

fi

eval runstatedir="$(eval echo ${runstatedir})"

AC_DEFINE_UNQUOTED([PCMK_RUN_DIR], ["$runstatedir"],

		   [Location for modifiable per-process data])

AC_SUBST(runstatedir)

eval INITDIR="${INITDIR}"

eval docdir="`eval echo ${docdir}`"

if test x"${docdir}" = x""; then

    docdir=${datadir}/doc/${PACKAGE}-${VERSION}

fi

AC_SUBST(docdir)

if test x"${CONFIGDIR}" = x""; then

    CONFIGDIR="${sysconfdir}/sysconfig"

fi

AC_SUBST(CONFIGDIR)

if test x"${CRM_LOG_DIR}" = x""; then

    CRM_LOG_DIR="${localstatedir}/log/pacemaker"

fi

AC_DEFINE_UNQUOTED(CRM_LOG_DIR,"$CRM_LOG_DIR", Location for Pacemaker log file)

AC_SUBST(CRM_LOG_DIR)

if test x"${CRM_BUNDLE_DIR}" = x""; then

    CRM_BUNDLE_DIR="${localstatedir}/log/pacemaker/bundles"

fi

AC_DEFINE_UNQUOTED(CRM_BUNDLE_DIR,"$CRM_BUNDLE_DIR", Location for Pacemaker bundle logs)

AC_SUBST(CRM_BUNDLE_DIR)

if test x"${PCMK_GNUTLS_PRIORITIES}" = x""; then

    AC_MSG_ERROR([Empty string not applicable with --with-gnutls-priorities])

fi

AC_DEFINE_UNQUOTED([PCMK_GNUTLS_PRIORITIES], ["$PCMK_GNUTLS_PRIORITIES"],

                   [GnuTLS cipher priorities])

if test x"${BUG_URL}" = x""; then

    BUG_URL="https://bugs.clusterlabs.org/enter_bug.cgi?product=Pacemaker"

fi

AC_SUBST(BUG_URL)

for j in prefix exec_prefix bindir sbindir libexecdir datadir sysconfdir \

    sharedstatedir localstatedir libdir includedir oldincludedir infodir \

    mandir INITDIR docdir CONFIGDIR

do

    dirname=`eval echo '${'${j}'}'`

    if

        test ! -d "$dirname"

    then

        AC_MSG_WARN([$j directory ($dirname) does not exist!])

    fi

done

us_auth=

AC_CHECK_HEADER([sys/socket.h], [

    AC_CHECK_DECL([SO_PEERCRED], [

        # Linux

        AC_CHECK_TYPE([struct ucred], [

            us_auth=peercred_ucred;

            AC_DEFINE([US_AUTH_PEERCRED_UCRED], [1],

                      [Define if Unix socket auth method is

                       getsockopt(s, SO_PEERCRED, &ucred, ...)])

        ], [

            # OpenBSD

            AC_CHECK_TYPE([struct sockpeercred], [

                us_auth=localpeercred_sockepeercred;

                AC_DEFINE([US_AUTH_PEERCRED_SOCKPEERCRED], [1],

                          [Define if Unix socket auth method is

                           getsockopt(s, SO_PEERCRED, &sockpeercred, ...)])

            ], [], [[#include <sys/socket.h>]])

        ], [[#define _GNU_SOURCE

             #include <sys/socket.h>]])

    ], [], [[#include <sys/socket.h>]])

])

if test -z "${us_auth}"; then

    # FreeBSD

    AC_CHECK_DECL([getpeereid], [

        us_auth=getpeereid;

        AC_DEFINE([US_AUTH_GETPEEREID], [1],

                  [Define if Unix socket auth method is

                   getpeereid(s, &uid, &gid)])

    ], [

        # Solaris/OpenIndiana

        AC_CHECK_DECL([getpeerucred], [

            us_auth=getpeerucred;

            AC_DEFINE([US_AUTH_GETPEERUCRED], [1],

                      [Define if Unix socket auth method is

                       getpeercred(s, &ucred)])

        ], [

            AC_MSG_ERROR([No way to authenticate a Unix socket peer])

        ], [[#include <ucred.h>]])

    ])

fi

dnl This OS-based decision-making is poor autotools practice;

dnl feature-based mechanisms are strongly preferred.

dnl

dnl So keep this section to a bare minimum; regard as a "necessary evil".

case "$host_os" in

    *bsd*)

        AC_DEFINE_UNQUOTED(ON_BSD, 1, Compiling for BSD platform)

        LIBS="-L/usr/local/lib"

        CPPFLAGS="$CPPFLAGS -I/usr/local/include"

        INIT_EXT=".sh"

        ;;

    *solaris*)

        AC_DEFINE_UNQUOTED(ON_SOLARIS, 1, Compiling for Solaris platform)

        ;;

    *linux*)

        AC_DEFINE_UNQUOTED(ON_LINUX, 1, Compiling for Linux platform)

        ;;

    darwin*)

        AC_DEFINE_UNQUOTED(ON_DARWIN, 1, Compiling for Darwin platform)

        LIBS="$LIBS -L${prefix}/lib"

        CFLAGS="$CFLAGS -I${prefix}/include"

        ;;

esac

AC_SUBST(INIT_EXT)

AC_MSG_NOTICE(Host CPU: $host_cpu)

case "$host_cpu" in

    ppc64|powerpc64)

        case $CFLAGS in

         *powerpc64*)

             ;;

         *)

             if test "$GCC" = yes; then

                 CFLAGS="$CFLAGS -m64"

             fi

             ;;

        esac

        ;;

esac

# C99 doesn't guarantee uint64_t type and related format specifiers, but

# prerequisites, corosync + libqb, use that widely, so the target platforms

# are already pre-constrained to those "64bit-clean" (doesn't imply native

# bit width) and hence we deliberately refrain from artificial surrogates

# (sans manipulation through cached values).

AC_CACHE_VAL(

    [pcmk_cv_decl_inttypes],

    [

        AC_CHECK_DECLS(

            [PRIu64, PRIu32, PRIx32,

             SCNu64],

            [pcmk_cv_decl_inttypes="PRIu64 PRIu32 PRIx32 SCNu64"],

            [

                # test shall only react on "no" cached result & error out respectively

                if test "x$ac_cv_have_decl_PRIu64" = xno; then

                    AC_MSG_ERROR([lack of inttypes.h based specifier serving uint64_t (PRIu64)])

                elif test "x$ac_cv_have_decl_PRIu32" = xno; then

                    AC_MSG_ERROR([lack of inttypes.h based specifier serving uint32_t (PRIu32)])

                elif test "x$ac_cv_have_decl_PRIx32" = xno; then

                    AC_MSG_ERROR([lack of inttypes.h based hexa specifier serving uint32_t (PRIx32)])

                elif test "x$ac_cv_have_decl_SCNu64" = xno; then

                    AC_MSG_ERROR([lack of inttypes.h based specifier gathering uint64_t (SCNu64)])

                fi

            ],

            [[#include <inttypes.h>]]

        )

    ]

)

(

    set $pcmk_cv_decl_inttypes

    AC_DEFINE_UNQUOTED([U64T],  [$1], [Correct format specifier for U64T])

    AC_DEFINE_UNQUOTED([U32T],  [$2], [Correct format specifier for U32T])

    AC_DEFINE_UNQUOTED([X32T],  [$3], [Correct format specifier for X32T])

    AC_DEFINE_UNQUOTED([U64TS], [$4], [Correct format specifier for U64TS])

)

dnl ===============================================

dnl Program Paths

dnl ===============================================

PATH="$PATH:/sbin:/usr/sbin:/usr/local/sbin:/usr/local/bin"

export PATH

dnl Replacing AC_PROG_LIBTOOL with AC_CHECK_PROG because LIBTOOL

dnl was NOT being expanded all the time thus causing things to fail.

AC_CHECK_PROGS(LIBTOOL, glibtool libtool libtool15 libtool13)

dnl Pacemaker's executable python scripts will invoke the python specified by

dnl configure's PYTHON variable. If not specified, AM_PATH_PYTHON will check a

dnl built-in list with (unversioned) "python" having precedence. To configure

dnl Pacemaker to use a specific python interpreter version, define PYTHON

dnl when calling configure, for example: ./configure PYTHON=/usr/bin/python3.6

dnl Ensure PYTHON is an absolute path

AC_PATH_PROG([PYTHON], [$PYTHON])

case "x$PYTHON" in

    x*python3*|x*platform-python*)

        dnl When used with Python 3, Pacemaker requires a minimum of 3.2

        AM_PATH_PYTHON([3.2])

        ;;

    *)

        dnl Otherwise, Pacemaker requires a minimum of 2.7

        AM_PATH_PYTHON([2.7])

        ;;

esac

AC_PATH_PROGS([ASCIIDOC_CONV], [asciidoc asciidoctor])

AC_PATH_PROG([HELP2MAN], [help2man])

AC_PATH_PROG([PUBLICAN], [publican])

AC_PATH_PROG([INKSCAPE], [inkscape])

AC_PATH_PROG([XSLTPROC], [xsltproc])

AC_PATH_PROG([XMLCATALOG], [xmlcatalog])

dnl BASH is already an environment variable, so use something else

AC_PATH_PROG([BASH_PATH], [bash])

PKG_PROG_PKG_CONFIG

# PKG_NOARCH_INSTALLDIR not available prior to pkg-config 0.27 and

# pkgconf 0.8.10, respectively (next line is to mimic that scenario)

dnl m4_ifdef([PKG_NOARCH_INSTALLDIR], [m4_undefine([PKG_NOARCH_INSTALLDIR])])

m4_ifndef([PKG_NOARCH_INSTALLDIR], [

    AC_DEFUN([PKG_NOARCH_INSTALLDIR], [

        AC_SUBST([noarch_pkgconfigdir], ['${datadir}/pkgconfig'])

    ])

])

PKG_NOARCH_INSTALLDIR

AC_PATH_PROGS(VALGRIND_BIN, valgrind, /usr/bin/valgrind)

AC_DEFINE_UNQUOTED(VALGRIND_BIN, "$VALGRIND_BIN", Valgrind command)

if test x"${LIBTOOL}" = x""; then

    AC_MSG_ERROR(You need (g)libtool installed in order to build ${PACKAGE})

fi

dnl Bash is needed for building man pages and running regression tests

if test x"${BASH_PATH}" = x""; then

    AC_MSG_ERROR(bash must be installed in order to build ${PACKAGE})

fi

AM_CONDITIONAL(BUILD_HELP, test x"${HELP2MAN}" != x"")

if test x"${HELP2MAN}" != x""; then

    PCMK_FEATURES="$PCMK_FEATURES generated-manpages"

fi

MANPAGE_XSLT=""

if test x"${XSLTPROC}" != x""; then

    AC_MSG_CHECKING(docbook to manpage transform)

    # first try to figure out correct template using xmlcatalog query,

    # resort to extensive (semi-deterministic) file search if that fails

    DOCBOOK_XSL_URI='http://docbook.sourceforge.net/release/xsl/current'

    DOCBOOK_XSL_PATH='manpages/docbook.xsl'

    MANPAGE_XSLT=$(${XMLCATALOG} "" ${DOCBOOK_XSL_URI}/${DOCBOOK_XSL_PATH} \

                   | sed -n 's|^file://||p;q')

    if test x"${MANPAGE_XSLT}" = x""; then

        DIRS=$(find "${datadir}" -name $(basename $(dirname ${DOCBOOK_XSL_PATH})) \

               -type d | LC_ALL=C sort)

        XSLT=$(basename ${DOCBOOK_XSL_PATH})

        for d in ${DIRS}; do

            if test -f "${d}/${XSLT}"; then

                 MANPAGE_XSLT="${d}/${XSLT}"

                 break

            fi

        done

    fi

fi

AC_MSG_RESULT($MANPAGE_XSLT)

AC_SUBST(MANPAGE_XSLT)

AM_CONDITIONAL(BUILD_XML_HELP, test x"${MANPAGE_XSLT}" != x"")

if test x"${MANPAGE_XSLT}" != x""; then

    PCMK_FEATURES="$PCMK_FEATURES agent-manpages"

fi

AM_CONDITIONAL([IS_ASCIIDOC], [echo "${ASCIIDOC_CONV}" | grep -Eq 'asciidoc$'])

AM_CONDITIONAL([BUILD_ASCIIDOC], [test "x${ASCIIDOC_CONV}" != x])

if test "x${ASCIIDOC_CONV}" != x; then

    PCMK_FEATURES="$PCMK_FEATURES ascii-docs"

fi

publican_intree_brand=no

if test x"${PUBLICAN_BRAND}" != x"" \

   && test x"${PUBLICAN}" != x"" \

   && test x"${INKSCAPE}" != x""; then

    dnl special handling for clusterlabs brand (possibly in-tree version used)

    test "${PUBLICAN_BRAND}" != "clusterlabs" \

        || test -d /usr/share/publican/Common_Content/clusterlabs

    if test $? -ne 0; then

        dnl Unknown option: brand_dir vs. Option brand_dir requires an argument

        if ${PUBLICAN} build --brand_dir 2>&1 | grep -Eq 'brand_dir$'; then

            AC_MSG_WARN([Cannot use in-tree clusterlabs brand, resorting to common])

            PUBLICAN_BRAND=common

        else

            publican_intree_brand=yes

        fi

    fi

    AC_MSG_NOTICE([Enabling Publican-generated documentation using ${PUBLICAN_BRAND} brand])

    PCMK_FEATURES="$PCMK_FEATURES publican-docs"

fi

AM_CONDITIONAL([BUILD_DOCBOOK],

               [test x"${PUBLICAN_BRAND}" != x"" \

                && test x"${PUBLICAN}" != x"" \

                && test x"${INKSCAPE}" != x""])

AM_CONDITIONAL([PUBLICAN_INTREE_BRAND],

               [test x"${publican_intree_brand}" = x"yes"])

dnl Pacemaker's shell scripts (and thus man page builders) rely on GNU getopt

AC_MSG_CHECKING([for GNU-compatible getopt])

IFS_orig=$IFS

IFS=:

for PATH_DIR in $PATH; do

    IFS=$IFS_orig

    GETOPT_PATH="${PATH_DIR}/getopt"

    if test -f "$GETOPT_PATH" && test -x "$GETOPT_PATH" ; then

        $GETOPT_PATH -T >/dev/null 2>/dev/null

        if test $? -eq 4; then

            break

        fi

    fi

    GETOPT_PATH=""

done

IFS=$IFS_orig

if test -n "$GETOPT_PATH"; then

  AC_MSG_RESULT([$GETOPT_PATH])

else

  AC_MSG_RESULT([no])

  AC_MSG_ERROR(Pacemaker build requires a GNU-compatible getopt)

fi

AC_SUBST([GETOPT_PATH])

dnl ========================================================================

dnl checks for library functions to replace them

dnl

dnl     NoSuchFunctionName:

dnl             is a dummy function which no system supplies.  It is here to make

dnl             the system compile semi-correctly on OpenBSD which doesn't know

dnl             how to create an empty archive

dnl

dnl     scandir: Only on BSD.

dnl             System-V systems may have it, but hidden and/or deprecated.

dnl             A replacement function is supplied for it.

dnl

dnl     setenv: is some bsdish function that should also be avoided (use

dnl             putenv instead)

dnl             On the other hand, putenv doesn't provide the right API for the

dnl             code and has memory leaks designed in (sigh...)  Fortunately this

dnl             A replacement function is supplied for it.

dnl

dnl     strerror: returns a string that corresponds to an errno.

dnl             A replacement function is supplied for it.

dnl

dnl     strnlen: is a gnu function similar to strlen, but safer.

dnl            We wrote a tolerably-fast replacement function for it.

dnl

dnl     strndup: is a gnu function similar to strdup, but safer.

dnl            We wrote a tolerably-fast replacement function for it.

AC_REPLACE_FUNCS(alphasort NoSuchFunctionName scandir setenv strerror strchrnul unsetenv strnlen strndup)

dnl ===============================================

dnl Libraries

dnl ===============================================

AC_CHECK_LIB(socket, socket)                    dnl -lsocket

AC_CHECK_LIB(c, dlopen)                         dnl if dlopen is in libc...

AC_CHECK_LIB(dl, dlopen)                        dnl -ldl (for Linux)

AC_CHECK_LIB(rt, sched_getscheduler)            dnl -lrt (for Tru64)

AC_CHECK_LIB(gnugetopt, getopt_long)            dnl -lgnugetopt ( if available )

AC_CHECK_LIB(pam, pam_start)                    dnl -lpam (if available)

AC_CHECK_FUNCS([sched_setscheduler])

if test "$ac_cv_func_sched_setscheduler" != yes; then

	PC_LIBS_RT=""

else

	PC_LIBS_RT="-lrt"

fi

AC_SUBST(PC_LIBS_RT)

AC_CHECK_LIB(uuid, uuid_parse)                  dnl load the library if necessary

AC_CHECK_FUNCS(uuid_unparse)                    dnl OSX ships uuid_* as standard functions

AC_CHECK_HEADERS(uuid/uuid.h)

if test "x$ac_cv_func_uuid_unparse" != xyes; then

    AC_MSG_ERROR(You do not have the libuuid development package installed)

fi

if test x"${PKG_CONFIG}" = x""; then

    AC_MSG_ERROR(You need pkgconfig installed in order to build ${PACKAGE})

fi

# Require glib 2.16.0 (2008-03) or later for g_hash_table_iter_init() etc.

PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.16.0],

                  [CPPFLAGS="${CPPFLAGS} ${GLIB_CFLAGS}"

                   LIBS="${LIBS} ${GLIB_LIBS}"])

#

# Where is dlopen?

#

if test "$ac_cv_lib_c_dlopen" = yes; then

    LIBADD_DL=""

elif test "$ac_cv_lib_dl_dlopen" = yes; then

    LIBADD_DL=-ldl

else

    LIBADD_DL=${lt_cv_dlopen_libs}

fi

dnl FreeBSD needs -lcompat for ftime() used by lrmd.c

AC_CHECK_LIB([compat], [ftime], [COMPAT_LIBS='-lcompat'])

AC_SUBST(COMPAT_LIBS)